sql - 如何将存储过程的输出返回到sql server中的变量中

Question

我想在 SQL Server 中执行一个存储过程并将输出分配给一个变量（它返回一个值）？

Answer 1

这取决于您要返回的信息的性质。

如果是单个整数值，可以使用return语句

 create proc myproc
 as 
 begin
     return 1
 end
 go
 declare @i int
 exec @i = myproc

如果你有一个非整数值，或者多个标量值，你可以使用输出参数

create proc myproc
  @a int output,
  @b varchar(50) output
as
begin
  select @a = 1, @b='hello'
end
go
declare @i int, @j varchar(50)
exec myproc @i output, @j output

如果要返回数据集，可以使用insert exec

create proc myproc
as 
begin
     select name from sysobjects
end
go

declare @t table (name varchar(100))
insert @t (name)
exec myproc

你甚至可以返回一个光标，但这太可怕了，所以我不会举个例子:)

Answer 2

您可以使用return存储过程中的语句来返回整数状态代码（并且仅是整数类型）。按照惯例，返回值为零表示成功。

如果return显式设置 no，则存储过程返回零。

   CREATE PROCEDURE GetImmediateManager
      @employeeID INT,
      @managerID INT OUTPUT
   AS
   BEGIN
     SELECT @managerID = ManagerID 
     FROM HumanResources.Employee 
     WHERE EmployeeID = @employeeID

     if @@rowcount = 0 -- manager not found?
       return 1;
   END

你这样称呼它：

DECLARE @return_status int;
DECLARE @managerID int;

EXEC @return_status = GetImmediateManager 2, @managerID output;
if @return_status = 1
  print N'Immediate manager not found!';
else 
  print N'ManagerID is ' + @managerID;
go

您应该仅将返回值用于状态代码。要返回数据，您应该使用输出参数。

如果要返回数据集，请使用类型的输出参数cursor。

更多关于 RETURN 声明

Answer 3

使用此代码，正常工作

CREATE PROCEDURE [dbo].[sp_delete_item]
@ItemId int = 0
@status bit OUT

AS
Begin
 DECLARE @cnt int;
 DECLARE @status int =0;
 SET NOCOUNT OFF
 SELECT @cnt =COUNT(Id) from ItemTransaction where ItemId = @ItemId
 if(@cnt = 1)
   Begin
     return @status;
   End
 else
  Begin
   SET @status =1;
    return @status;
 End
END

执行 SP

DECLARE @statuss bit;
EXECUTE  [dbo].[sp_delete_item] 6, @statuss output;
PRINT @statuss;

Answer 4

使用 proc 中的 Return 语句，我需要分配 temp 变量并将其传递给另一个存储过程。该值被正确分配，但是当将其作为参数传递时，它丢失了该值。我必须创建一个临时表并从表中设置变量（SQL 2008）

From this: 
declare @anID int
exec @anID = dbo.StoredProc_Fetch @ID, @anotherID, @finalID
exec dbo.ADifferentStoredProc @anID (no value here)

To this:
declare @t table(id int) 
declare @anID int
insert into @t exec dbo.StoredProc_Fetch @ID, @anotherID, @finalID
set @anID= (select Top 1 * from @t)