13

这是我遇到问题的一些代码，我处理了一些 XML，并在 OO 类中的一个方法中从文档中重复的几个节点中的每个节点中提取一个元素。每个节点的子树中应该只有一个这样的元素，但我的代码获取所有元素，就好像它对整个文档进行操作一样。

因为我只希望得到 oine 元素，所以我只使用数组的第零个元素，这会导致我的函数输出错误的值（文档中的所有项目都相同）

这是一些说明问题的简化代码

$ cat t4.pl
#!/usr/bin/perl
use strict;
use warnings;
use XML::LibXML;

my $xml = <<EndXML;
<Envelope>
  <Body>
    <Reply>
      <List>
        <Item>
          <Id>8b9a</Id>
          <Message>
            <Response>
              <Identifier>55D</Identifier>
            </Response>
          </Message>
        </Item>
        <Item>
          <Id>5350</Id>
          <Message>
            <Response>
              <Identifier>56D</Identifier>
            </Response>
          </Message>
        </Item>
      </List>
    </Reply>
  </Body>
</Envelope>
EndXML

my $foo = Foo->new();

my $parser = XML::LibXML->new();
my $doc    = $parser->parse_string( $xml );
my @list   = $doc->getElementsByTagName( 'Item' );

for my $item ( @list ) {

    my $id = get( $item, 'Id' );
    my @messages = $item->getElementsByLocalName( 'Message' );

    for my $message ( @messages ) {

        my @children = $message->getChildNodes();

        for my $child ( @children ) {

            my $name = $child->nodeName;

            if ( $name eq 'Response' ) {
                print "child is a Response\n";
                $foo->do( $child, $id );
            }
            elsif ( $name eq 'text' ) {

                # ignore whitespace between elements
            }
            else {
                print "child name is '$name'\n";
            }
        }    # child
    }    # Message
}    # Item

# ..............................................

sub get {
    my ( $node, $name ) = @_;

    my $value   = "(Element $name not found)";
    my @targets = $node->getElementsByTagName( $name );

    if ( @targets ) {
        my $target = $targets[0];
        $value = $target->textContent;
    }

    return $value;
}

# ..............................................

package Foo;

sub new {
    my $self = {};
    bless $self;
    return $self;
}

sub do {
    my $self = shift;
    my ( $node, $id ) = @_;

    print '-' x 70, "\n", ' ' x 12, $node->toString( 1 ), "\n", '-' x 70, "\n";

    my @identifiers = $node->findnodes( '//Identifier' );
    print "do() found ", scalar @identifiers, " Identifiers\n";

    print "$id, ", $identifiers[0]->textContent, "\n\n";
}

这是输出

$ perl t4.pl
child is a Response
----------------------------------------------------------------------
            <Response>
              <Identifier>55D</Identifier>
            </Response>
----------------------------------------------------------------------
do() found 2 Identifiers
8b9a, 55D

child is a Response
----------------------------------------------------------------------
            <Response>
              <Identifier>56D</Identifier>
            </Response>
----------------------------------------------------------------------
do() found 2 Identifiers
5350, 55D

我期待

do() found 1 Identifiers

我期待最后一行是

5350, 56D

由于平台问题，我正在使用旧版本的 XML::LibXML。

Q：以后的版本是否存在这个问题，还是我做错了什么？

4

2 回答 2

22

来自XPath 1.0 的文档

//para 选择文档根的所有 para 后代

（强调我自己的）。所以你的电话

$node->findnodes( '//Identifier' )

忽略上下文节点$node并搜索Identifier文档中任何位置的所有元素

要获取Identifier上下文节点的所有后代，您必须添加一个点，如下所示

$node->findnodes('.//Identifier');

但是因为$node它总是一个Response元素并且Identifier是你的直接孩子，Response你可以写

$node->findnodes('Identifier');


你似乎把自己写得有点累了。我知道您已将代码缩减为示例，但是您真的需要单独的包吗？明智地应用 XPath 可以做很多事情。

最明显的变化是你不需要遍历所有的孩子——你可以简单地挑选出你感兴趣的孩子。

这个重构的代码可能值得一读

use strict;
use warnings;

use XML::LibXML;

my $parser = XML::LibXML->new;
my $doc    = $parser->parse_fh(*DATA);

for my $item ( $doc->findnodes('//Item') ) {

    print "\n";

    my ($id) = $item->findvalue('Id');
    printf "Item Id: %s\n", $item->findvalue('Id');

    my @messages = $item->findnodes('Message');

    for my $message (@messages) {
        my ($response) = $message->findnodes('Response');
        printf "Response Identifier: %s\n", $response->findvalue('Identifier');
    }
}

__DATA__
<Envelope>
  <Body>
    <Reply>
      <List>
        <Item>
          <Id>8b9a</Id>
          <Message>
            <Response>
              <Identifier>55D</Identifier>
            </Response>
          </Message>
        </Item>
        <Item>
          <Id>5350</Id>
          <Message>
            <Response>
              <Identifier>56D</Identifier>
            </Response>
          </Message>
        </Item>
      </List>
    </Reply>
  </Body>
</Envelope>

输出

Item Id: 8b9a
Response Identifier: 55D

Item Id: 5350
Response Identifier: 56D
于 2012-08-14T15:23:03.397 回答
0

我对代码的质量没有评论，但是XML::DOM在我使用之前学会了使用，我XML::LibXML倾向于使用一些 DOM 语法。我一直在努力改掉这个习惯:)。
我提到这一点的原因是因为我看到您已经使用等效的->item(0)方法从节点列表中获取第一个位置，就像在 DOM 中一样。
XML::LibXML支持使用，->item()但从 cpan 我可以看到 xpath 创建的节点列表1不是从0DOM 开始的。我很确定，如果您将代码保持原样并寻找第一个数组位置而不是第 0 个，您将得到您想要的结果。
不清楚的是为什么->item(0)给你最后一个结果，就像我的测试一样（它是否可能从一个数组值偏移，所以你实际上返回了第 -1 个数组值）

于 2014-04-08T15:59:27.487 回答