sql - SAS：选择多列值的频率

Question

我有这个问题，但是在 SAS 中。要使用此问题中提供的示例，我有 5 列名称（name_1、name_2 等），并希望输出一个列表，其中名称按频率降序排列：

John     502
Robert   388
William  387
...
...       1

我回答了上面提到的问题，并用“proc sql;”包围了它。和“退出；”：

proc sql;
create table freqs as
SELECT name, COUNT(1)
FROM (           SELECT name_1 AS name FROM mytable
     UNION ALL SELECT name_2 AS name FROM mytable
     UNION ALL SELECT name_3 AS name FROM mytable
     UNION ALL SELECT name_4 AS name FROM mytable
     UNION ALL SELECT name_5 AS name FROM mytable
   ) AS myunion
 GROUP BY name
 ORDER BY COUNT(1) DESC
;
quit;

但我得到：

ERROR: Summary functions are restricted to the SELECT and HAVING clauses only.

我正在使用 SAS 9.2。

想法？谢谢您的帮助！

Answer 1

您只需要更改 ORDER BY 表达式即可引用第二列。我还建议您将 COUNT 表达式结果分配给 SAS 变量名（可能是“freq”）：

proc sql; 
   create table freqs as 
   SELECT name
        , COUNT(*) as freq
   FROM (
      SELECT           name_1 AS name FROM mytable
      UNION ALL SELECT name_2 AS name FROM mytable
      UNION ALL SELECT name_3 AS name FROM mytable
      UNION ALL SELECT name_4 AS name FROM mytable
      UNION ALL SELECT name_5 AS name FROM mytable
      ) AS myunion  
   GROUP BY name
   ORDER BY freq DESC;
quit; 

仅供参考：你也可以说ORDER BY 2 DESC给出一个相对的参考。

Answer 2

Proc SQL 不允许在 order by 中使用 count(1)。试试这个：

proc sql;
    create table freqs as
        SELECT name, COUNT(1) as freqs
        FROM (SELECT name_1 AS name FROM mytable UNION ALL
              SELECT name_2 AS name FROM mytable UNION ALL
              SELECT name_3 AS name FROM mytable UNION ALL
              SELECT name_4 AS name FROM mytable UNION ALL
              SELECT name_5 AS name FROM mytable
             ) AS myunion
         GROUP BY name
         ORDER BY 2 DESC ;
 quit;

我认为它允许列引用。

Answer 3

如果数据集不是太大，以下方法也可以工作：

data mytable;
 input (name1-name5) (: $17.) @@;
 cards;
 john henry bob jerry james gary bill john mark gabe
 ;
run;

proc sql;
select 'do name = '
||catq("A2SC", name1,name2,name3,name4,name5)
||'; output; end;' into : nlist separated by ' ' from mytable
 ;
quit;

data test;
&nlist
Run;

proc freq order = freq;
tables name;
run;