3

我有 2 个表 -student并且studLoad都有 2 个字段studID和studName. 我想将数据从student表加载到stuLoad表中。如果数据已经存在于studLoad表中，那么应该更新它，否则应该插入它。以下是我这样做的代码：

    create or replace procedure studentLoad is
v_id student.studID%type;
v_name student.studName%type;
v_sn studLoad.studName%type;
cursor cur_load is
select * from student;


begin
  open cur_load;
  loop
   fetch cur_load into v_id,v_name;

   exit when cur_load%notfound;
   select studName into v_sn from studLoad where studID = v_id;
   if(v_sn!= v_name) then
      update studLoad set studName= v_name where studID= v_id;
   else
      insert into studLoad values(v_id,v_name);
   dbms_output.put_line(v_id || ' ' || v_name);
   end if;
  end loop;
      close cur_load;
end;

它不工作。studLoad 表中的行未更新。我该如何解决这个问题？IF EXISTS(select...from stuLoad..)在我们用来检查表中是否存在记录的SQL Server中，有没有办法在 Oracle 中做同样的事情？如果是，那么请让我知道。

4

2 回答 2

16

这是一种非常低效的方法。您可以使用该merge语句，然后就不需要游标、循环或（如果可以不用的话）PL/SQL。

MERGE INTO studLoad l
USING ( SELECT studId, studName FROM student ) s
ON (l.studId = s.studId)
WHEN MATCHED THEN
  UPDATE SET l.studName = s.studName
   WHERE l.studName != s.studName
WHEN NOT MATCHED THEN 
INSERT (l.studID, l.studName)
VALUES (s.studId, s.studName)

确保您commit在完成后能够在数据库中看到它。

要真正回答你的问题，我会这样做如下。这样做的好处是可以在 SQL 中完成大部分工作，并且仅基于 rowid（表中的唯一地址）进行更新。

它声明了一种类型，您可以将数据批量放置在其中，一次 10,000 行。然后单独处理这些行。

但是，正如我所说，这不会像merge.

declare

   cursor c_data is
    select b.rowid as rid, a.studId, a.studName
      from student a
      left outer join studLoad b
        on a.studId = b.studId
       and a.studName <> b.studName
           ;

   type t__data is table of c_data%rowtype index by binary_integer;
   t_data t__data;

begin

   open c_data;
   loop
      fetch c_data bulk collect into t_data limit 10000;

      exit when t_data.count = 0;

      for idx in t_data.first .. t_data.last loop
         if t_data(idx).rid is null then
            insert into studLoad (studId, studName)
            values (t_data(idx).studId, t_data(idx).studName);
         else
            update studLoad
               set studName = t_data(idx).studName
             where rowid = t_data(idx).rid
                   ;
         end if;
      end loop;

   end loop;
   close c_data;

end;
/
于 2012-08-12T11:50:07.717 回答
0

如果您想使用您的过程，请考虑更改一些行：

create or replace procedure studentLoad is
v_id student.studID%type;
v_name student.studName%type;
v_sn studLoad.studName%type;
cursor cur_load is
       select * from student;
begin
    open cur_load;
    loop
        fetch cur_load into v_id,v_name;
        exit when cur_load%notfound;
        begin
           select studName into v_sn from studLoad where studID = v_id;
           if(v_sn!= v_name) then
               update studLoad set studName= v_name where studID= v_id;
           end if;
        exception
           when no_data_found then
                insert into studLoad values(v_id,v_name);
        end;
        dbms_output.put_line(v_id || ' ' || v_name);
    end loop;
    close cur_load;
end;

我认为它应该工作，没有测试它。

于 2021-10-22T13:56:33.743 回答