2

我想检查对我的对象方法的每次调用一些值（在这种情况下：令牌的年龄）。是否可以一次将其设置为所有方法？就像在构造函数中一样？我有这样简单的构造函数：

sub new {
    my $class = shift;
    my %args = @_;
    my $self  = {};

    $self->{key} = $args{key};
    bless($self, $class);

    ($self->{token}, $self->{token_start}) = $self->_get_authorized_token(); 
    return $self;
}

还有一堆方法，取决于令牌的年龄，如下所示：

sub add_item {
    my $self = shift;
    my %args = @_;
    ...
}

我想避免在每种方法中都包含年龄检查，所以我寻找更通用的方法来实现它。有吗？

4

3 回答 3

3

我能想到的就是隐藏你所有的“真实”方法——要么以带有前下划线的经典方式，要么以子例程的散列方式——并用于AUTOLOAD正确引导调用。

下面的例子说明了这个想法

模块MyClass.pm

package MyClass;

use strict;
use warnings;

sub new {
  bless {}, __PACKAGE__;
}

sub _method1 {
  print "In method1\n";
}

sub _method2 {
  print "In method2\n";
}

sub AUTOLOAD {

  our $AUTOLOAD;

  my ($class, $method) = $AUTOLOAD =~ /(.+)::(.+)/;
  return if $method eq 'DESTROY';

  my $newmethod = "${class}::_$method";
  unless (exists &$newmethod) {
    die qq(Can't locate object method "$method" via package "$class");
  }

  print "Preprocessing...\n";
  goto &$newmethod 
}

1;

程序

use strict;
use warnings;

use MyClass;

my $thing = MyClass->new;

$thing->method1;
$thing->method2;
$thing->method3;

输出

Preprocessing...
In method1
Preprocessing...
In method2
Can't locate object method "method3" via package "MyClass" at MyClass.pm line 23.
于 2012-08-10T15:23:05.643 回答
1

请参阅Class::Method::Modifiers或Class::Method::Modifiers::Fast模块。

于 2012-08-10T21:12:33.967 回答
1

老实说，如果你在 Perl 中做 OO 并且你想在没有样板的情况下处理属性、方法修饰符和延迟资源加载等事情，那么学习Moose是值得的。为了说明，这是使用 Moose 编写所需内容的一种方法：

use Moose;
has key => (isa => 'Str', is => 'ro');
has token => (isa => 'HashRef', is => 'ro', lazy_build => 1);

before [qw(add_item method2 method3)] => sub {
    my $self = shift;
    if (do something with $self->token) {
         # return, die, etc.
    }
};

sub _build_token {
    my $self = shift;
    my $key = $self->key;
    return { token => 'foo', token_start => time };
}

这些可能会有所帮助：

于 2012-08-11T09:34:16.743 回答