1

我需要将输入参数字符串（如“1-410000 54-420987 63-32000”）转换为 xslt 内部的结构（如下所示），以便稍后在 xslt 中使用其数据：

<config:categories>
  <category>
    <value>410000</value>
    <label>1</label>
  </category>
  <category>
    <value>420987</value>
    <label>54</label>
  </category>
  <category>
    <value>32000</value>
    <label>63</label>
  </category>
</config:categories>

PS是否有任何其他选项来解析字符串，如“1-410000 54-420987 63-32000”，以便在输入文档中找到左侧部分时，使用 xslt 中的数据提取右侧部分（在“-”之后） ?

4

3 回答 3

2

这种转变：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:config="some:config" exclude-result-prefixes="config">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pData" select="'1-410000 54-420987 63-32000'"/>

 <xsl:template match="/*">
     <config:categories>
       <xsl:call-template name="gen"/>
     </config:categories>
 </xsl:template>

 <xsl:template name="gen">
  <xsl:param name="pGen" select="$pData"/>

  <xsl:if test="$pGen">
   <xsl:variable name="vChunk" select=
    "substring-before(concat($pGen, ' '), ' ')"/>
      <category>
        <value><xsl:value-of select="substring-after($vChunk,'-')"/></value>
        <label><xsl:value-of select="substring-before($vChunk,'-')"/></label>
      </category>
      <xsl:call-template name="gen">
       <xsl:with-param name="pGen" select="substring-after($pGen, ' ')"/>
      </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当应用于任何 XML 文档（未使用）时，会产生所需的正确结果：

<config:categories xmlns:config="some:config">
   <category>
      <value>410000</value>
      <label>1</label>
   </category>
   <category>
      <value>420987</value>
      <label>54</label>
   </category>
   <category>
      <value>32000</value>
      <label>63</label>
   </category>
</config:categories>

说明：

正确使用substring-before()和substring-after()加上递归。

于 2012-08-09T12:27:12.250 回答
2

正如 Dimitre 所示，在 XSLT 1.0 中解析字符串非常麻烦。这是 XSLT 2.0 更胜一筹的领域。可以这样做：

<categories>
  <xsl:for-each select="tokenize($param, '\s+')">
    <category>
      <label><xsl:value-of select="substring-after(., '-')"/></label>
      <value><xsl:value-of select="substring-before(., '-')"/></value>
    </category>
  </xsl:for-each>
</categories>

当然，在 XSLT 2.0 中，您可以将类别结构用作一流的节点值，而无需使用 node-set() 扩展来进入它。

于 2012-08-09T14:54:47.470 回答
0

从字符串生成 XML 我认为你必须使用 Java。我不知道实现这一点的 XSLT 功能。

对于您的第二个问题：有 substring()、string-length()、substring-before() 和 substring-after() 可能有助于您的请求。请参考：http ://www.w3schools.com/xpath/xpath_functions.asp

于 2012-08-09T11:58:10.363 回答