0

我编写了一个触发器，将帐户所有者名称放在为该帐户创建的案例上。它在我的 200 批量测试中也可以工作和执行。这是代码：

trigger CaseBeforeInsertUpdate on Case (before insert, before update) {

   Set<Id> accountIds = new Set<Id>();
   Set<Id> accountOwnerIds = new Set<Id>(); 

   for (Case c : Trigger.new) {
        if(c.AccountId != null) {
            accountIds.add(c.AccountId);
        }       
   }
   Map<Id,Account> accountMap = new Map<Id, Account>([select Id, OwnerId from Account where Id IN :accountIds]);

   for (Account a : accountMap.values()) {
        if(a.OwnerId != null) {
            accountOwnerIds.add(a.OwnerId);
        }
   }

   Map<Id, User> userMap = new Map<Id,User>([select Name from User where Id IN :accountOwnerIds]);

   if(userMap.size() > 0) {
        for(Case c: Trigger.new) {  
            c.MerchantOwner__c = userMap.get(accountMap.get(c.AccountId).OwnerId).name;
        }
   }

}

偶然我发现了一个错误，我无法弄清楚出了什么问题。如果我转到案例列表视图（即我的打开案例）并选择多个案例并关闭它们，我会收到错误：System.NullPointerException：尝试取消引用更新 MerchantOwner 字段的行的空对象。当我在我的测试类中批量关闭案例时，一切正常..

我最好的猜测是我正在尝试为没有附加帐户的案例执行此操作，但据我所知，我试图通过不首先将这些案例添加到 accountIds Set 来不更新这些案例。

有谁知道我做错了什么？任何帮助将不胜感激。

4

1 回答 1

1

我将更改以下 For 循环：

   for(Case c: Trigger.new) {  
        c.MerchantOwner__c = userMap.get(accountMap.get(c.AccountId).OwnerId).name;
    }

至

    for(Case c: Trigger.new) {  
        if (c.AccountId != null                                        // Make sure there is an Account linked to the Case
          && accountMap.ContainsKey(c.AccountId)                       // Make sure our Account query captured  it
          && accountMap.get(c.AccountId).OwnerId != null               // Make sure that account has an owner
          && usermap.ContainsKey(accountMap.get(c.AccountId).Ownerid)  // Finally make sure our User query found the owner
        ){
            c.MerchantOwner__c = userMap.get(accountMap.get(c.AccountId).OwnerId).name;
        }
    }
于 2012-08-08T20:27:56.663 回答