awk - 根据条件拆分文件

Question

我有一个包含以下数据的文件

.domain bag
.set bag1
bag1
abc1
.set bag2
bag2
abc2
.domain cat
.set bag1:cat
bag1:cat
abc1:cat
.set bag2:cat
bag2:cat
abc2:cat

我想根据设定值将此文件分成两个（bag1.txt 和 bag2.txt）。

bag1.txt 应该看起来像：

.domain bag
.set bag1
bag1
abc1
.domain cat
.set bag1:cat
bag1:cat
abc1:cat

bag2.txt 应该看起来像：

.domain bag
.set bag2
bag2
abc2
.domain cat
.set bag2:cat
bag2:cat
abc2:cat

.domain 行对这两个文件都是通用的。

我尝试了下面的命令，但它不起作用。

nawk '{if($0~/.set/){split($2,a,":");filename=a[1]".text"}if(filename=".text"){print|"tee *.text"}else{print >filename}}' file.txt

Answer 1

单程：

awk '
    BEGIN {
        ## Split fields with spaces and colon.
        FS = "[ :]+";

        ## Extension of output files.
        ext = ".txt";
    }

    ## Write lines that begin with ".domain" to all known output files (saved
    ## in "processed_bags"). Also save them in the "domain" array to copy them
    ## later to all files not processed yet.
    $1 == ".domain" {

        for ( b in processed_bags ) {
            print $0 >> sprintf( "%s%s", b, ext );
        }

        domain[ i++ ] = $0;

        next;
    }

    ## Select output file to write. If not found previously, copy all
    ## domains saved until now.
    $1 == ".set" {
        bag = $2;
        if ( ! (bag in processed_bags) ) {
            for ( j = 0; j < i; j++ ) {
                print domain[j] >> sprintf( "%s%s", bag, ext );
            }
            processed_bags[ bag ] = 1;            
        }
    }

    ## A normal line of data (neither ".domain" nor ".set"). Copy
    ## to the file saved in "bag" variable.
    bag {
        print $0 >> sprintf( "%s%s", bag, ext );
    }
' file.txt

运行以下命令检查输出：

head bag[12].txt

输出：

==> bag1.txt <==                                                                                                                                                                                                                             
.domain bag                                                                                                                                                                                                                                  
.set bag1                                                                                                                                                                                                                                    
bag1                                                                                                                                                                                                                                         
abc1                                                                                                                                                                                                                                         
.domain cat                                                                                                                                                                                                                                  
.set bag1:cat                                                                                                                                                                                                                                
bag1:cat
abc1:cat

==> bag2.txt <==
.domain bag
.set bag2
bag2
abc2
.domain cat
.set bag2:cat
bag2:cat
abc2:cat