0

我将 TextEdit 中的文本存储在 AppleScript 变量中，并且我想将其传递给 JavaScript。我以为我做得对，但我仍然无法获得要存储的价值。代码如下：

tell application "TextEdit"
    activate
    set docText to the text of the front document --This works. I've checked.
end tell

tell application "Google Chrome"
    tell window 1
        tell active tab
            execute javascript "function encryptDocument() {
                plainText = '" & docText & "';
                return plainText;
                } encryptDocument();"
                set skurp to the result
                display dialog skurp
            end tell
    end tell
end tell

我将 JavaScript 代码包含在tell application "Google Chrome"命令中的原因是，每次尝试在上一个tell application "TextEdit"命令中调用它时都会出错。错误总是说它期望行尾但发现"。不太清楚为什么，但我找不到解决这个问题的方法。

4

1 回答 1

3

您要赋予变量的值（我的意思是文本编辑器中的文本）是否可能包含单引号（'）？在文本编辑器中没有 ' 这似乎对我有用。

以下代码片段可用于转义单引号。（改编自此代码）

on escape(this_text)
    set AppleScript's text item delimiters to the "'"
    set the item_list to every text item of this_text
    set AppleScript's text item delimiters to the "\\'"
    set this_text to the item_list as string
    set AppleScript's text item delimiters to ""
    return this_text
end escape

tell application "TextEdit"
    activate
    set docText to the text of the front document --This works. I've checked.
end tell

set docText to escape(docText)

tell application "Google Chrome"
    tell window 1
        tell active tab
            execute javascript "function encryptDocument() {
                plainText = '" & docText & "';
                return plainText;
                } encryptDocument();"
            set skurp to the result
            display dialog skurp
        end tell
    end tell
end tell
于 2012-08-07T14:10:10.180 回答