4

我有一个文本文件 temp.txt，其中包含以下条目，

cinterim=3534
cstart=517
cstop=622
ointerim=47
ostart=19
ostop=20

注意：键值对可以换行排列，也可以同时排列在一行中，用空格隔开。

我正在尝试使用 Perl 将这些值打印并存储在数据库中以获取相应的键。但是我收到了很多错误和警告。现在我只是想打印这些值。

use strict;
use warnings;

open(FILE,"/root/temp.txt") or die "Unable to open file:$!\n";

while (my $line = <FILE>) {
  # optional whitespace, KEY, optional whitespace, required ':', 
  # optional whitespace, VALUE, required whitespace, required '.'
  $line =~ m/^\s*(\S+)\s*:\s*(.*)\s+\./;
  my @pairs = split(/\s+/,$line);
  my %hash = map { split(/=/, $_, 2) } @pairs;

  printf "%s,%s,%s\n", $hash{cinterim}, $hash{cstart}, $hash{cstop};

}
close(FILE);

有人可以提供帮助来完善我的程序。

4

3 回答 3

11 
use strict;
use warnings;

open my $fh, '<', '/root/temp.txt' or die "Unable to open file:$!\n";
my %hash = map { split /=|\s+/; } <$fh>;
close $fh;
print "$_ => $hash{$_}\n" for keys %hash;

这段代码的作用：

<$fh>从我们的文件中读取一行，或者在列表上下文中读取所有行并将它们作为数组返回。

在内部map，我们使用 regexp 将我们的行拆分为一个数组/= | \s+/x。这意味着：当您看到一个=或一系列空白字符时拆分。这只是原始代码的精简和美化形式。

然后，我们将产生的列表map转换为hash类型。我们可以这样做，因为列表的项目数是偶数。（此时输入类似key key=value或key=value=value将引发错误）。

之后，我们打印散列。printf在 Perl 中，我们可以直接在字符串中插入哈希值，除了特殊格式外，不必使用和朋友。

for循环遍历所有键（在特殊变量中返回）$_，并且$hash{$_}是相应的值。这也可以写成

while (my ($key, $val) = each %hash) {
  print "$key => $val\n";
}

whereeach遍历所有键值对。

于 2012-08-07T11:24:26.220 回答
5

试试这个

use warnings;

my %data = ();

open FILE, '<', 'file1.txt' or die $!;
while(<FILE>)
{
    chomp;
    $data{$1} = $2 while /\s*(\S+)=(\S+)/g;
}
close FILE;

print $_, '-', $data{$_}, $/ for keys %data;
于 2012-08-07T11:22:21.910 回答
4

最简单的方法是将整个文件放入内存并使用正则表达式将键/值对分配给散列。

该程序显示了该技术

use strict;
use warnings;

my %data = do {
  open my $fh, '<', '/root/temp.txt' or die $!;
  local $/;
  <$fh> =~ /(\w+)\s*=\s*(\w+)/g;
};

use Data::Dump;
dd \%data;

输出

{
  cinterim => 3534,
  cstart   => 517,
  cstop    => 622,
  ointerim => 47,
  ostart   => 19,
  ostop    => 20,
}
于 2012-08-07T12:36:10.823 回答