5

我有一个简单的基本问题，我正在尝试使用Insert语句将图像插入数据库，而其他列值也使用TADOQuery组件。

由于代码已经由某人编写，因此我想在此处放置一些虚拟示例代码，以便您通过相应的步骤进行澄清。

请注意，这与组件一起工作得很好TQuery，因为我正在用组件替换TQuery，TADOQuery所以我必须只使用组件来做同样的事情TADOQuery。

相同的代码应该适用于 SQL Server 和 Oracle 数据库。

我试图在其中插入图像的列的数据类型VarBinary是 SQL Server 数据库中的类型。

使用 TQuery 将图像插入表中

  1. 使用创建图像TImage。

    msBinImgStream := TMemoryStream.Create; 
imgCustom := TImage.Create(self); 
imgJpg := TJPEGImage.Create;

  2. 将图像转换为TJpegImage并保存为TMemoryStream.

    imgJpg.Assign(imgCustom.Picture.Bitmap); 
imgJpg.SaveToStream(msBinImgStream);

  3. SetBlobdata使用组件的属性插入数据库TQuery。

    sSql := 'INSERT INTO Table_Name(Column1, Column2, Column_Image) VALUES ( ''' + Value1 + ''', ''' + Value2 + ''', :pBlob)'; 
qryTQuery.SQL.Add(sSQL); 
qryTQuery.ParamByName('pBlob').SetBlobData(msBinImgStream.Memory, msBinImgStream.Size); 
qryTQuery.ExecSQL;

现在使用TADOQuery：

  1. 能够创建图像。
  2. 将其转换为 TJpeg 并保存为TMemoryStream.

  3. 尝试使用将图像插入数据库LoadFromStream(stream, ftBlob)但出现错误"String or binary value may be truncated"。

    sSql := 'INSERT INTO Table_Name(Column1, Column2, Column_Image) VALUES ( ''' + Value1 + ''', ''' + Value2 + ''', :pBlob)'; 
qryADOQuery.SQL.Add(sSQL); 
qryADOQuery.Parameters.ParamByName('pBlob').LoadFromStream(msBinImgStream, ftBlob); 
qryADOQuery.ExecSQL;

请让我知道，用这种方法我应该如何克服这个问题。

4

2 回答 2

15

保存：

var
  Field: TBlobField;
  Stream: TStream;
begin
  if ADOQuery.Active and (Image.Picture.Graphic <> nil) then
  begin
    ADOQuery.Insert;
    Field := TBlobField(ADOQuery.FieldByName('ImageData')); // ensure it ís a blob
    Stream := ADOQuery.CreateBlobStream(Field, bmWrite);
    try
      Image1.Picture.Graphic.SaveToStream(Stream);
    finally
      Stream.Free;
      ADOQuery.Post;
    end;
  end;
end;

或使用 aTADOBlobStream而不是 a TStream：

var
  ...
  Stream: TADOBlobStream;
begin
  ...
    Stream := TADOBlobStream.Create(Field, bmWrite);
    ...

加载：

var
  Field: TBlobField;
  Stream: TStream;
  Jpg: TJPEGImage;
begin
  if ADOQuery.Active then
  begin
    Field := TBlobField(ADOQuery.FieldByName('ImageData'));
    Stream := ADOQuery.CreateBlobStream(Field, bmRead);
    Jpg := TJPEGImage.Create;
    try
      Jpg.LoadFromStream(Stream);
      Image1.Picture.Graphic := Jpg;
    finally
      Jpg.Free;
      Stream.Free;
    end;
  end;
end;
于 2012-08-02T10:13:57.357 回答
3

像您一样使用参数时，我认为您必须为其提供额外的设置，例如Attributesand DataType，如下所示：

  sSql := 'INSERT INTO Table_Name (Column1, Column2, Column_Image) ' +
    'VALUES (''' + Value1 + ''', ''' + Value2 + ''', :pBlob)';

  qryADOQuery.SQL.Add(sSQL);
  qryADOQuery.Parameters[0].Attributes := [paLong];
  qryADOQuery.Parameters[0].DataType := ftBlob; // Or ftVarBytes
                                                // Or ftOraBlob (Oracle only)
  qryADOQuery.Parameters[0].LoadFromStream(msBinImgStream, ftBlob);
  qryADOQuery.ExecSQL;
于 2012-08-02T19:44:28.687 回答