3

需要每 5 秒运行一次子程序，但在系统时钟标记处测量。因此，需要每分钟在 0、5、10、15.... 45、50、55 秒（准确地说，以 0.1 秒的精度）启动它。

就像是：

for(;;) {
    do_sleep(); #time need to sleep to the next 5 second mark
    run_this();
}

run_this潜艇可以快也可以慢（它的运行时间在 0.2 - 120 秒之间）。当它运行超过 5 秒时 - 无论它的运行时间如何，下一次运行都必须在准确的 5 秒标记处。

例如，当run_this

  • 结束于 11:11:12.3 需要等待 2.7 秒才能在 11:11:15 进行下一次运行
  • 当在 11:11:59.2 结束时只需要等待 0.8 秒到下一个在 11:12:00，依此类推...

问题是：如何写do_sleep？

4

5 回答 5

5

对于 0.1s 精度，您需要使用 Time::HiRes 模块。就像是：

#!/usr/bin/perl
use 5.014;
use warnings;
use Time::HiRes qw(tv_interval usleep gettimeofday);

for(;;) {
    do_sleep();
    run_this();
}

sub do_sleep {
    my $t = [gettimeofday];
    my $next = (int($t->[0]/5) + 1) * 5;
    my $delta = tv_interval ($t, [$next, 0]);
    usleep($delta * 1_000_000);
    return;
}

sub run_this {
    my $t = [gettimeofday];
    printf "Start is at: %s.%s\n",
        scalar localtime  $t->[0],
        $t->[1];
    usleep( rand 10_000_000 );  #simulating the runtime between 0-10 seconds (in microseconds)
}
于 2012-07-30T19:52:51.610 回答
2

一个非常不同的方法是为此使用IO::Async。您可以在未来的特定时间安排活动。

于 2012-08-06T14:08:29.757 回答
2

如果您有信号处理程序，这个也可以工作。它还处理闰秒。

use Time::HiRes qw( );

sub uninterruptible_sleep_until {
   my ($until) = @_;
   for (;;) {
      my $length = $until - Time::HiRes::time();
      last if $length <= 0;
      Time::HiRes::sleep($length);
   }
}

sub find_next_start {
   my $time = int(time());
   for (;;) {
      ++$time;
      my $secs = (localtime($time))[0];
      last if $secs % 5 == 0 && $secs != 60;
   }
   return $time;
}

uninterruptible_sleep_until(find_next_start());

请注意，系统可能不会在您需要时提供时间片，因此您实际上可能比请求的时间晚开始。

于 2012-07-30T20:46:21.000 回答
1

您可以使用 Time::HiRes 并计算以这种方式等待多长时间：

use Time::HiRes;
my $t = time();
my $nextCallTime = int($t) / 5 * 5 + 5;
my $timeToWait = $nextCallTime - $t;
sleep($timeToWait);

我没有测试代码，当调用恰好在 5 秒边界结束时可能存在一些边界条件。但我认为它给出了正确的想法。

于 2012-07-30T19:52:41.440 回答
1

使用 Time::HiRes 中的高精度计时器对循环计时

http://perldoc.perl.org/Time/HiRes.html

将您长期运行的作业放入后台进程

my $pid = fork;
die "fork failed" unless defined $pid;
if ($pid == 0) {
    # child process goes here
    run_this();
    exit;
}
# parent process continues here

另请参阅 在 Perl 中启动非等待后台进程

于 2012-07-30T19:50:58.837 回答