2

我希望在其自己的数组中读取使用 ARGV 指定的每个（小）文件。如果我不测试$ARGV，<>将把所有文件都放在一个表中。有更好/更短/更简单的方法吗？

# invocation: ./prog.pl *.txt

@table = ();
$current = "";
while (<>)
{
  if ($ARGV ne $current)
  {
    @ar = ();
    $current = $ARGV;
    if ($current)
    {
      push @table, \@ar;
    }
  }
  push @ar;
}
4

4 回答 4

7

该eof函数可用于检测每个文件的结尾：

#!/usr/bin/env perl

use strict;
use warnings;

my @files;
my $file_ctr = 0;
while (<>) {
    chomp;
    push @{ $files[$file_ctr] }, $_;
}
continue { $file_ctr++ if eof }

相关文件：

在while (<>)循环中，eof或eof(ARGV)可用于检测每个文件的结尾，而eof()仅检测最后一个文件的结尾。

于 2012-07-30T14:15:36.900 回答
3

请始终 use strict在您的程序的顶部，并use warnings使用my.

最简单的方法是在ARGV文件句柄上测试文件结束以确定何时打开新文件。

这段代码使用状态变量$eof来记录前一个文件是否已被完全读取，以避免在到达列表@table末尾时不必要地向数组添加新元素。@ARGV

use strict;
use warnings;

my @table;
my $eof = 1;

while (<>) {
  chomp;
  push @table, [] if $eof;
  push @{$table[-1]}, $_;
  $eof = eof;
}

@Alan Haggai Alavi在文件末尾增加索引而不是设置标志的想法要好得多，因为它避免了在每个文件开头显式创建空数组的需要。

这是我对他的解决方案的看法，但这完全取决于 Alan 的帖子，他应该为此获得赞誉。

use strict;
use warnings;

my @table;
my $index = 0;

while (<>) {
  chomp;
  push @{$table[$index]}, $_;
  $index++ if eof;
}
于 2012-07-30T14:30:58.400 回答
2

文件数组引用的哈希：

my %files;
while (<>) {
  push @{$files{$ARGV}}, $_;
}
于 2012-07-30T14:08:40.000 回答
2

您可以利用 File::Slurp 来避免自己打开和关闭文件。

use strict;
use warnings;

use File::Slurp;

my @table = ();

foreach my $arg ( @ARGV ) {
   push @table, read_file( $arg, array_ref => 1 );
}
于 2012-07-30T14:16:46.020 回答