9

考虑以下代码示例：

{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE UndecidableInstances #-} -- Is there a way to avoid this?

-- A generic class with a generic function.
class Foo a where
  foo :: a -> a

-- A specific class with specific functions.
class Bar a where
  bar :: a -> a
  baz :: a -> a

-- Given the specific class functions, we can implement the generic class function.
instance Bar a => Foo a where
  foo = bar . baz

-- So if a type belongs to the specific class...
instance Bar String where
  bar = id
  baz = id

-- We can invoke the generic function on it.
main :: IO ()
main =
  putStrLn (foo "bar")

（我的实际代码要复杂得多；这是演示该模式的最小简化案例。）

我不清楚UndecidableInstances这里为什么需要 - type 参数a在 的两侧出现一次Bar a => Foo a，所以我希望事情“正常工作”。我显然在这里遗漏了一些东西。但无论如何，有没有办法在不使用的情况下做到这一点UndecidableInstances？

4

2 回答 2

8

您可以采取几种方法；我认为您没有提供足够的上下文来确定哪个是最合适的。如果您使用 GHC-7.4，您可能想尝试DefaultSignatures扩展。

{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE DefaultSignatures #-}

-- A generic class with a generic function.
class Foo a where
  foo :: a -> a
  default foo :: Bar a => a -> a
  foo = bar . baz

-- A specific class with specific functions.
class Bar a where
  bar :: a -> a
  baz :: a -> a

instance Bar String where
  bar = id
  baz = id

instance Foo String

main :: IO ()
main =
  putStrLn (foo "bar")

您仍然需要声明一个类型是 的实例Foo，但您不需要重复方法声明，因为将使用默认实现。

另一种相当轻量级的方法是使用新类型。如果您有需要Foo实例的函数，则可以将实例包装Bar在新类型中。

newtype FooBar a = FooBar { unFooBar :: a }

instance Bar a => Foo (FooBar a) where
    foo = FooBar . bar . baz . unFooBar

-- imported from a library or something...
needsFoo :: Foo a => a -> b

myFunc = needsFoo (FooBar someBar)

或者，您可以通过替换为普通函数或为实例foo制作专门版本来解决问题：Bar

-- if every `Foo` is also a `Bar`, you can just do this.  No need for `Foo` at all!
foo :: Bar a => a -> a
foo = bar . baz

-- if most `Foo`s aren't `Bar`s, you may be able to use this function when you have a `Bar`
fooBar :: Bar a => a -> a
foo = bar . baz

如果它们适合您的情况，这些可能是最好的解决方案。

另一种选择是Foo手动声明每个实例。尽管可能有很多不同的可以想象的实例，但代码库只有少数实际使用的实例是相当普遍的。如果这里是真的，那么只写出您需要的 3 或 4 个实例而不是尝试实施更通用的解决方案可能会减少工作量。

作为最后的手段，您可以使用类似于原始代码的东西，但您还需要OverlappingInstances使其工作（如果您不需要OverlappingInstances，那么您不需要Foo类）。这是允许 GHC 在有多个可用匹配项时选择“最具体的实例”的扩展。这或多或少会起作用，尽管您可能无法得到您期望的结果。

class Foo a where
  foo :: a -> a

class Bar a where
  bar :: a -> a
  baz :: a -> a

instance Bar String where
  bar = id
  baz = id

instance Bar a => Foo a where
  foo = bar . baz

instance Foo [a] where
  foo _ = []

main :: IO ()
main =
  print (foo "foo")

现在main打印一个空字符串。有两个Foo实例， fora和[a]。后者更具体，因此选择它是foo "foo"因为字符串具有 type [Char]，尽管您可能想要前者。所以现在你还需要写

instance Foo String where
  foo = bar . baz

在这一点上，您不妨完全忽略该Bar a => Foo a实例。

于 2012-07-29T09:12:52.797 回答
0

除了上面的回答。Data.Traversable图书馆模块中使用的政治base很有吸引力。简而言之，在库中提供通用实例会迫使最终用户接受您的决定，而这并不总是最好的做法。Data.Traversable包含类似 的函数foldMapDefault，提供默认实现，但具体实现的决定仍由用户决定。

于 2012-07-29T18:26:31.770 回答