windows - 我需要仅使用本机 Windows 命令匹配或替换批处理环境变量中的星号 *。这可能吗？

Question

我正在尝试从环境变量字符串中删除星号，但似乎无法做到。

我正在创建一个基于搜索字符串的 m3u 文件，例如，如果我想制作一个 m3u 文件，其中包含每首带有单词 love 的歌曲，我会输入：

m3u *Love*

m3u.bat 将创建文件：

xLovex.m3u

但是替换字符的常规方法不适用于星号。（虽然我对问号没有这个问题。）

set nam=%nam:*=x%.m3u

而是创建文件名

x.m3u

Answer 1

简单的答案是否定的。

您遇到的问题源于星号 * 在与 SET 搜索和替换方法一起使用时是一个特殊字符。它以有限但仍然有用的方式匹配多个字符。你可以在这里了解。

艰难的答案是肯定的！

我将为您提供两种解决方案。一个是不完整但优雅的解决方案，另一个是完整且不优雅的解决方案。

两种方法都将搜索 * 并将其替换为 x。
这两种方法都将搜索和修改以下字符串：

*love*

想到的第一种方法是使用“FOR /L”语句，并要求您知道环境变量的长度。

::主要编辑::

我以为我知道各种最大大小的环境变量字符串，但 dbenham 带我去学校，向我展示了一个背后的长度函数，同时完全颠覆了我对这两种解决方案的看法呈现。

除了 Windows 95/98/ME 对 256 个字符的最大环境变量大小的限制。似乎所有使用 CMD.EXE 的 Windows 版本都有 8,192 个字符的限制，远低于文档的建议。

两个版本都需要延迟环境变量扩展，但有两个不同的原因。一个是因为我在 FOR 语句中进行操作。另一个是因为你不能将一个 % 对放在另一个 % 对中，因为命令处理器将它遇到的第二个 % 匹配到它遇到的第一个，但是我们需要在另一个变量表达式中使用一个变量。（你会看到的。）

此解决方案使用 DosTips.com 中的 strLen 函数（第 3 行），可在此处找到。只需将其放入一个名为 strLen.bat 的文件中，就会对它的速度感到惊讶！

方案一：（FOR /L方案）：：首选方案：：

setlocal ENABLEDELAYEDEXPANSION
set nam=*love*
rem calling strLen
call :strLen nam len
for /l %%x in (0,1,%len%) do if not "!nam:~%%x,1!"=="" if "!nam:~%%x,1!"=="*" (
    set /a plusone=%%x+1
    for /l %%y in (!plusone!, 1, !plusone!) do (
        set nam=!nam:~0,%%x!x!nam:~%%y!
    )
)
echo %nam%
ENDLOCAL

我认为这是一个快速而优雅的解决方案它可以通过将 strLen.bat 的内容添加到例程中来加快速度，但我不想让作者感到困惑。

如果您出于某种原因不想使用 strLen，那么下一个最快的方法可能会使用 GOTO 循环。

解决方案2：（转到解决方案）

setlocal ENABLEDELAYEDEXPANSION
set nam=*love*
set num=0

:loop
    set /a plusone=%num%+1
    if "!nam:~%num%,1!"=="*" set nam=!nam:~0,%num%!x!nam:~%plusone%!
    set /a num=%num%+1
if not "!nam:~%num%,1!"=="" goto :loop

echo %nam%
EndLocal

特别感谢 dbenham 指出 strLen 函数。它的运行速度比任何基于批处理的函数都快！

Answer 2

虽然这里已经解释了一些非常好的和健壮的方法，但为了完成，我仍然想添加另一个选项。

它不如其他选项好，但我个人在某些情况下使用它，我想保持代码干净并且我知道它就足够了：

它的工作方式是使用for /f'sdelims将字符串分成两部分，然后将它们重新组合在一起，在此过程中去掉 *：

for /f "tokens=1,* delims=*" %%a in ("a*b") do (set string=%%a%%b)

>>> string=ab

显然，这样做的缺点是它只能用于删除一个 *.

要删除更多，我们可以使用更多令牌...

for /f "tokens=1-3,* delims=*" %%a in ("a*b*c*d") do (set string=%%a%%b%%c%%d)

>>> string=abcd

...或者我们可以将第一行放在for /l-loop 中：

setlocal enableDelayedExpansion
set string=a*b*c*d
for /l %%a in (1, 1, 3) do (
    for /f "tokens=1,* delims=*" %%b in ("!string!") do (set string=%%b%%c)
)

>>> string=abcd

另一件需要注意的事情是，您可以在 中定义多个字符delims，并且它们将立即被删除：

for /f "tokens=1,* delims=+-*/" %%a in ("a*-/+b") do (set string=%%a%%b)

>>> string=ab

Answer 3

所述问题的另一个解决方案是在批处理脚本中使用 PowerShell替换命令。

set var=*Love*
echo %var%>var.txt | powershell -command "((get-content var.txt) -replace '[\x2A]','x') -replace '.{1}$' | set-content var.txt"
set /p var=<var.txt
set var=%var%.m3u
echo %var%

在上面的代码中，第二行

• 将您的字符串写入文本文件
• 调用 PowerShell 命令来获取该文件的内容
• 将 * 字符替换为 null
• 用新值覆盖文本文件

完成后，您将值读回变量中。

为了进一步解释替换命令，第一个单引号是您要搜索的内容。我们使用方括号将 * 字符标识为十六进制字符（\x2A 是 * 的十六进制值）。在逗号之后，第二组单引号不包含任何值，以便删除搜索的对象。为了防止xLovex和.m3u之间出现空格，我们必须在将结果写入文本文件之前使用-replace '.{1}$' 。

完成文本文件后，输入一行以将其删除。

if exist var.txt del var.txt

Answer 4

这是一种不遍历字符串的所有字符的方法，但它使用for /F循环在每次出现某个（一个序列的）某个字符时拆分字符串。实际功能被打包到一个子例程中以便于重用，因此以下脚本的主要部分只包含一些要测试的代码：

@echo off
setlocal EnableExtensions DisableDelayedExpansion

::This is the main routine of the script holding code for test and demonstration:

rem // Definition of some sample text to test (note that `%%` becomes one literal `%`):
set "DATA=some text,"^&"&;0'@%%~#`$:wild**card*?.re<dir>=|+([{parens}])-^/equal==to=!_"

echo/
call :REPL_CHAR TEXT DATA "*" "?"
setlocal EnableDelayedExpansion
echo(In: !DATA!
echo(Out:!TEXT!
echo/
echo(In: !TEXT!
call :REPL_CHAR TEXT TEXT "=" "/"
echo(Out:!TEXT!
endlocal

endlocal
exit /B


:REPL_CHAR
    ::This function replaces in a string every occurrence of a sequence of a certain character
    ::by another character or a string. It even correctly handles the characters `*` and `=`.
    ::  USAGE:
    ::    call :REPL_CHAR ref_output_string ref_input_string val_search_char val_replace_char
    ::  PARAMETERS:
    ::    ref_output_string   reference to (name of) variable to receive the resulting string;
    ::    ref_input_string    reference to variable that holds the original string; if empty
    ::                        (`""`), the variable referenced by `ref_output_string` is used;
    ::    val_search_char     single character that is to be replaced;
    ::    val_replace_char    character or string to replace every sequence of `val_search_char`
    ::                        with; this may even be empty;
    rem // Localise environment and detect whether delayed expansion is enabled (needed later):
    setlocal & set "$NDX=!"
    setlocal DisableDelayedExpansion
    rem // Fetch arguments and verify them:
    set "#RET=%~1" & if not defined #RET endlocal & endlocal & exit /B 2
    set "#STR=%~2" & if not defined #STR set "#STR=%#RET%"
    set "CHR=%~3"
    if not defined CHR endlocal & endlocal & exit /B 1
    set "RPL=%~4"
    setlocal EnableDelayedExpansion
    rem // Initialise several auxiliary variables:
    set "TST=!%#STR%!" & set "CHR=!CHR:~,1!" & set "INS="
    if "!CHR!"=="_" (set "BUF=#" & set "WRK=!TST!#") else (set "BUF=_" & set "WRK=!TST!_")
:REPL_CHAR_LOOP
    rem // Check whether the end of the string has been reached:
    if not defined TST set "BUF=!BUF:~1,-1!" & goto :REPL_CHAR_NEXT
    rem // Split the string at the next sequence of search characters:
    for /F tokens^=1*^ delims^=^%CHR%^ eol^=^%CHR% %%S in ("!BUF!!INS!!WRK!") do (
        rem // Store the portions before and after the character sequence:
        endlocal & set "BUF=%%S" & set "TST=%%T" & set "WRK=%%T" & setlocal EnableDelayedExpansion
    )
    rem // Loop back and find the next character sequence:
    set "INS=!RPL!" & goto :REPL_CHAR_LOOP
:REPL_CHAR_NEXT
    rem // Return the resulting string with all special characters properly handled:
    if not defined $NDX if defined BUF set "BUF=!BUF:"=""!^"
    if not defined $NDX if defined BUF set "BUF=!BUF:^=^^^^!"
    if not defined $NDX if defined BUF set "BUF=%BUF:!=^^^!%" !
    if not defined $NDX if defined BUF set "BUF=!BUF:""="!^"
    for /F "delims=" %%S in (^""!BUF!"^") do endlocal & endlocal & endlocal & set "%#RET%=%%~S" !
    exit /B

这个脚本的输入和输出数据（我们称之为repl_char_demo.bat）是：

>>> repl_char_demo.bat

In: some text,"&"&;0'@%~#`$:wild**card*?.re<dir>=|+([{parens}])-^/equal==to=!_
Out:some text,"&"&;0'@%~#`$:wild?card??.re<dir>=|+([{parens}])-^/equal==to=!_

In: some text,"&"&;0'@%~#`$:wild?card??.re<dir>=|+([{parens}])-^/equal==to=!_
Out:some text,"&"&;0'@%~#`$:wild?card??.re<dir>/|+([{parens}])-^/equal/to/!_

---

这是一个脚本，它使用for /L循环遍历字符串的所有字符，根据预定义的字符检查每个字符并按指定替换它。此方法替换每个匹配的字符而不是序列。再次将功能放入子例程中（这次主要部分被关闭）：

:REPL_CHAR
    ::This function replaces in a string every occurrence of one certain character by another
    ::character or a string. It even correctly handles the characters `*` and `=`, as well as
    ::sequences of search characters so that every single one becomes replaced.
    ::  USAGE:
    ::    call :REPL_CHAR ref_output_string ref_input_string val_search_char val_replace_char
    ::  PARAMETERS:
    ::    ref_output_string   reference to (name of) variable to receive the resulting string;
    ::    ref_input_string    reference to variable that holds the original string; if empty
    ::                        (`""`), the variable referenced by `ref_output_string` is used;
    ::    val_search_char     single character that is to be replaced;
    ::    val_replace_char    character or string to replace every single `val_search_char`
    ::                        with; this may even be empty;
    rem // Localise environment and detect whether delayed expansion is enabled (needed later):
    setlocal & set "$NDX=!"
    setlocal DisableDelayedExpansion
    rem // Fetch arguments and verify them:
    set "#RET=%~1" & if not defined #RET endlocal & endlocal & exit /B 2
    set "#STR=%~2" & if not defined #STR set "#STR=%#RET%"
    set "CHR=%~3"
    if not defined CHR endlocal & endlocal & exit /B 1
    set "RPL=%~4"
    setlocal EnableDelayedExpansion
    rem // Initialise several auxiliary variables:
    set "WRK=!%#STR%!" & set "CHR=!CHR:~,1!" & set "BUF="
    rem // Loop through all characters and check for match:
    if defined WRK for /L %%J in (0,1,63) do for /L %%I in (0,1,127) do (
        set /A "POS=%%J*64+%%I" & for %%P in (!POS!) do (
            set "TST=!WRK:~%%P,1!" & if not defined TST goto :REPL_CHAR_QUIT
            rem // Store character or replacement depending on whether there is a match:
            if "!TST!"=="!CHR!" (set "BUF=!BUF!!RPL!") else (set "BUF=!BUF!!TST!")
        )
    )
:REPL_CHAR_QUIT
    rem // Return the resulting string with all special characters properly handled:
    if not defined $NDX if defined BUF set "BUF=!BUF:"=""!^"
    if not defined $NDX if defined BUF set "BUF=!BUF:^=^^^^!"
    if not defined $NDX if defined BUF set "BUF=%BUF:!=^^^!%" !
    if not defined $NDX if defined BUF set "BUF=!BUF:""="!^"
    for /F "delims=" %%S in (^""!BUF!"^") do endlocal & endlocal & endlocal & set "%#RET%=%%~S" !
    exit /B

实际上有两个嵌套for /L循环而不是一个，一旦到达字符串的末尾，这两个循环都会被破坏，使用gotocommand。打破for /L循环意味着它在后台完成了迭代，尽管它的主体不再被执行。因此，使用单个循环在被破坏后需要更多的时间来完成，而不是两个嵌套的循环。

该脚本的输入和输出数据（与上面相同的主要部分）是：

>>> repl_char_demo.bat

In: some text,"&"&;0'@%~#`$:wild**card*?.re<dir>=|+([{parens}])-^/equal==to=!_
Out:some text,"&"&;0'@%~#`$:wild??card??.re<dir>=|+([{parens}])-^/equal==to=!_

In: some text,"&"&;0'@%~#`$:wild??card??.re<dir>=|+([{parens}])-^/equal==to=!_
Out:some text,"&"&;0'@%~#`$:wild??card??.re<dir>/|+([{parens}])-^/equal//to/!_

Answer 5

请参阅此答案，并使用set-ast.bat将set-ast nam "x"您的文件放在需要的地方。

set-ast接受参数<variable-to-modify> <string-to-replace-asterisks-with>