0

大家好，我无法确定我可以使用什么脚本来替换 xml 中的部分字符串，例如这里的数据是 xml

<product>
<image>
path/to/image.jpg
</image>
<url>
http://website.com/imformation?x=[id]&y=[op]
</url>
<price>
99.99
</price>
</product>

所有这些信息都将被导入数据库，但我对如何替换 url 中的元素有点困惑我知道如何使用 xslt 和 xpath 编辑节点等，但我不确定如何替换 [id]我到处搜索，但无法为我的生活找到有关如何执行此操作的解释

4

1 回答 1

1

您可以使用 XSLT 替换所有内容。

XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <xsl:variable name="replacedURL">
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="/product/url/text()"/>
                <xsl:with-param name="replace" select="'[id]'"/>
                <xsl:with-param name="by" select="'Hello'"/>
            </xsl:call-template>
        </xsl:variable>
        <xsl:value-of select="$replacedURL"/>
    </xsl:template>
    <xsl:template name="string-replace-all">
        <xsl:param name="text"/>
        <xsl:param name="replace"/>
        <xsl:param name="by"/>
        <xsl:choose>
            <xsl:when test="contains($text, $replace)">
                <xsl:value-of select="substring-before($text,$replace)"/>
                <xsl:value-of select="$by"/>
                <xsl:call-template name="string-replace-all">
                    <xsl:with-param name="text" select="substring-after($text,$replace)"/>
                    <xsl:with-param name="replace" select="$replace"/>
                    <xsl:with-param name="by" select="$by"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$text"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

在上面的 XSLT 中，我使用了一个名为"string-replace-all"的模板。此模板会将所有匹配项替换为所需的值。

模板：

<xsl:template name="string-replace-all">
    <xsl:param name="text"/>
    <xsl:param name="replace"/>
    <xsl:param name="by"/>
    <xsl:choose>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)"/>
            <xsl:value-of select="$by"/>
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)"/>
                <xsl:with-param name="replace" select="$replace"/>
                <xsl:with-param name="by" select="$by"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

如何调用模板？

<xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="/product/url/text()"/>
    <xsl:with-param name="replace" select="'[id]'"/>
    <xsl:with-param name="by" select="'Hello'"/>
</xsl:call-template>

这里：

  • text: http://website.com/imformation?x=[id]&y=[op]
  • replace： [ID]
  • by： 你好

输出：

http://website.com/imformation?x=Hello&y=[op]

也这样做[op]。

于 2012-07-26T07:47:34.680 回答