5

我在我的 LLVM IR 中调用了一个外部 (C) 函数。IR 被 JITed 并且一切正常，但是生成的代码对性能很敏感，如果可能的话，我想删除对我的外部函数的重复调用。该功能没有副作用。是否有一个 FunctionPass 可以消除对函数的冗余调用？我必须做些什么来将该功能标记为没有副作用吗？

谢谢！

4

1 回答 1

2

根据http://llvm.org/docs/LangRef.html#function-attributes您可以为函数指定属性 readonly 或 readnone ：

declare i32 @fn(i32 %i);
declare i32 @readonly_fn(i32 %i) readonly;
declare i32 @readnone_fn(i32 %i) readnone;

readonly表示该函数不写入内存， readnone表示它甚至不读取内存（例如 sin() 可能是 readnone）

如果一个函数不写内存，它应该只根据参数返回结果，因此是一个纯函数（如果全局状态没有改变）。在 readnone 函数的情况下，甚至全局状态也可能发生变化。

llvm 优化器可以使用EarlyCSEpass 优化对 readonly 和 readnone 函数的调用（公共子表达式消除），如下例所示：

使用以下测试功能

define i32 @test_no_readonly()
{
  %1 = call i32 @fn(i32 0)
  %2 = call i32 @fn(i32 0)
  %add = add i32 %1, %2
  ret i32 %add
}
define i32 @test_readonly()
{
  %1 = call i32 @readonly_fn(i32 0)
  %2 = call i32 @readonly_fn(i32 0)
  %add = add i32 %1, %2
  ret i32 %add
}
define i32 @test_readnone()
{
  %1 = call i32 @readnone_fn(i32 0)
  %2 = call i32 @readnone_fn(i32 0)
  %add = add i32 %1, %2
  ret i32 %add
}

和 runningopt -early-cse -S readonly_fn.ll > readonly_fn_opt.ll优化了 readonly 和 readnone 函数的第二次调用，导致

define i32 @test_no_readonly() {
  %1 = call i32 @fn(i32 0)
  %2 = call i32 @fn(i32 0)
  %add = add i32 %1, %2
  ret i32 %add
}

define i32 @test_readonly() {
  %1 = call i32 @readonly_fn(i32 0)
  %add = add i32 %1, %1
  ret i32 %add
}

define i32 @test_readnone() {
  %1 = call i32 @readnone_fn(i32 0)
  %add = add i32 %1, %1
  ret i32 %add
}

readonly_fnandreadnone_fn函数只调用一次，从而消除了冗余调用。

pass 还可以将-functionattrs这些属性添加到定义的函数中

于 2015-04-20T18:56:43.520 回答