1

您好，我是 xml 新手，想使用 xsl 样式表比较一些值

`<a>
 <b>   <name>foo</name>   </b>
 <b>   <name>bar</name>   </b>
 <b>   <name>fred</name>  </b>
 <b>   <name>fred</name>  </b>
 </a>`

我想编写一个样式表来检查所有 b 节点并返回具有相同值的值，因此使用上面的简单示例，我希望输出类似于：
“您的重复字符串是 fred”

我使用了一个 for each 循环来返回所有值，但是比较名称并返回重复项让我望而却步。如果可能的话，我想通过使用 while 类型循环来实现比较。

感谢您的任何帮助。

4

3 回答 3

2

XSLT 1.0：使用键的简单解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:key name="kNameByVal" match="name" use="."/>

 <xsl:template match="/*">
  Your duplicate strings are: <xsl:text/>

  <xsl:apply-templates select=
    "b/name[generate-id() = generate-id(key('kNameByVal', .)[2])]"/>
 </xsl:template>

 <xsl:template match="name">
  <xsl:if test="position() >1">, </xsl:if>
  <xsl:value-of select="."/>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

二、XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:variable name="vSeq" select="data(/a/b/name)"/>

 <xsl:template match="/">
  Your duplicate strings are: <xsl:text/>
  <xsl:sequence select="$vSeq[index-of($vSeq,.)[2]]"/>
 </xsl:template>
</xsl:stylesheet>

三、XPath 2.0 单行

$vSeq[index-of($vSeq,.)[2]]

这将产生给定序列中的所有值，这些值具有重复项（一组重复项中的一个）。

于 2012-07-21T20:30:35.310 回答
1

基于<xsl:key>- 的解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:key name="kName" match="b/name" use="text()" />

  <xsl:template match="/">
    <xsl:for-each select="//b/name">
      <xsl:if test="count(key('kName', text())) &gt; 1">
        <xsl:value-of select="concat('Your duplicate is: ', text(), '&#xA;')" />
      </xsl:if>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

对于大型输入文档，这将比使用preceding::检查的解决方案更有效。

于 2012-07-21T19:53:46.330 回答
1

使用 while 循环是违反 XSLT 理念的，即使它可以做到。

有一些更简单的方法可以做你想做的事，例如：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method='text' />
<xsl:template match="b">
   <xsl:if test='preceding::b/name/text()=./name/text()'>
Your duplicate is: <xsl:copy-of select='./name/text()' />
   </xsl:if>
</xsl:template>

</xsl:stylesheet>

这是在寻找节点 b，并检查前面的 b 节点是否具有相同的名称 text

于 2012-07-21T19:40:04.747 回答