3

假设我正在解决一个特定问题并想出一个函数

let function parameter1 ... = 
     a lot of adding, multiplying & so on with a lot of 
     literals all over the place

现在，如果我的参数是 int 类型，这个函数就可以正常工作了。但在某个地方，我需要将它增加到 11，我需要额外推动 int64 甚至 BigInteger。那我该怎么办？我复制并粘贴函数，更改名称，然后寻找所有使编译器认为函数应该在 int 上运行的文字外观。这很糟糕。

有没有办法做到这一点：

let greatFunction param1 param2 = (param1+1)/(param2*2)

其中 param1 和 param2 可以是整数类型的任何组合？

编辑：

通过下面的 kvb 扩展了一个很棒的技巧，我想出了以下内容

module NumericLiteralG 

  let inline FromZero() = LanguagePrimitives.GenericZero
  let inline FromOne() = LanguagePrimitives.GenericOne
  let inline FromInt32 n =
    let rec loop nIn nOut = 
        if nIn>0 then loop (nIn - 1) (nOut + LanguagePrimitives.GenericOne)
        else nOut
    loop n LanguagePrimitives.GenericZero

所以使用时会变得不那么难看

let inline halfSquare num =
   let res = num / 2G
   res * res

let solve1 = halfSquare 5I 
let solve2 = halfSquare 5.0
let solve3 = halfSquare 5uy

现在的问题是我应该使用这个吗？如果不是，为什么不呢？

4

4 回答 4

5

我认为通用算术是 .NET 语言中的常见问题。有很多文章解释了不同的方法，很快我将发布另一篇解释我的文章，它与您发布的解决方案相似。

现在，如果你问我是否应该使用它，我会说：只要你明白你在做什么，为什么不呢？我在生产中部分使用它并且完全没有问题，但是因为我关心运行时性能，所以我使用重载在编译时解决所有问题。然后为了加快编译时间，我重新定义了基本的数学运算符以在相同的类型中运行，否则类型签名会变得非常复杂并且可能需要很长时间才能编译。

还有更多需要考虑的事情，但对于您的具体问题，这里有一个示例代码：

open System.Numerics

type FromInt = FromInt with
    static member ($) (FromInt, _:sbyte     ) = fun (x:int) -> sbyte      x
    static member ($) (FromInt, _:int16     ) = fun (x:int) -> int16      x
    static member ($) (FromInt, _:int32     ) = id
    static member ($) (FromInt, _:float     ) = fun (x:int) -> float      x
    static member ($) (FromInt, _:float32   ) = fun (x:int) -> float32    x
    static member ($) (FromInt, _:int64     ) = fun (x:int) -> int64      x
    static member ($) (FromInt, _:nativeint ) = fun (x:int) -> nativeint  x
    static member ($) (FromInt, _:byte      ) = fun (x:int) -> byte       x
    static member ($) (FromInt, _:uint16    ) = fun (x:int) -> uint16     x
    static member ($) (FromInt, _:char      ) = fun (x:int) -> char       x
    static member ($) (FromInt, _:uint32    ) = fun (x:int) -> uint32     x
    static member ($) (FromInt, _:uint64    ) = fun (x:int) -> uint64     x
    static member ($) (FromInt, _:unativeint) = fun (x:int) -> unativeint x
    static member ($) (FromInt, _:bigint    ) = fun (x:int) -> bigint     x
    static member ($) (FromInt, _:decimal   ) = fun (x:int) -> decimal    x
    static member ($) (FromInt, _:Complex   ) = fun (x:int) -> Complex(float x,0.0)  

let inline fromInt (a:int) : ^t = (FromInt  $  Unchecked.defaultof< ^t>) a

module NumericLiteralG =
    let inline FromZero() =LanguagePrimitives.GenericZero
    let inline FromOne() = LanguagePrimitives.GenericOne
    let inline FromInt32 (i:int)     = fromInt i


// This will reduce the number of types inferred, will reduce compile time too.
let inline (+) (a:^t) (b:^t) : ^t = a + b
let inline (-) (a:^t) (b:^t) : ^t = a - b
let inline (*) (a:^t) (b:^t) : ^t = a * b
let inline (/) (a:^t) (b:^t) : ^t = a / b
let inline (~-) (a:^t) : ^t = -a


let inline halfSquare num =
   let res = num / 2G
   res * res

let solve1 = halfSquare 5I 
let solve2 = halfSquare 5.0
let solve3 = halfSquare 5uy 

// Define more generic math functions.
于 2012-07-19T18:46:35.987 回答
3

这是一篇关于 F# 中的通用数值计算的文章。一般来说，您有两种选择：

  • 静态成员约束
  • 全局数字关联（在 F# PowerPack 中可用）

...或者您可以结合这些技术。

在您的情况下，听起来静态约束会起作用。

那篇文章中的一个简单示例：

let inline halfSquare num =
   let res = LanguagePrimitives.DivideByInt num 2
   res * res
于 2012-07-19T13:57:45.943 回答
3

一种方法是结合LanguagePrimitives模块中的inline关键字和通用位：

let inline greatFunction param1 param2 = 
    let one = LanguagePrimitives.GenericOne
    let two = one + one
    (param1+one)/(param2*two)

// Usage
let f1 = greatFunction 4 2
let f2 = greatFunction 4L 2L
let f3 = greatFunction 4I 2I
于 2012-07-19T13:59:38.780 回答
0

虽然不理想，并且有点绕过您的主要问题，但您可以添加类型注释以强制编译器处理：

let greatFunction (param1:int64) (param2:int64) : int64 = (param1+1)/(param2*2)

现在当然 F# 中没有隐式转换，因此您需要添加L到所有数字文字，但它们至少会显示为编译器错误。

于 2012-07-19T17:28:09.953 回答