1

我目前正在尝试使用 Indy 在 TCP 之上编写自定义更高级别的协议。本质上，我想通过（使用流）发送一条记录，但这条记录可以表明要遵循的 x 字节将是一个图像文件。

因此，当服务器接收到记录时，如果它的内容表明它后面有图像，则需要将记录和图像数据分开。

var
Segment: TDPPSegment;
Segment2: TDPPSegment;
Buffer: TIdBytes;
Buffer2: TIdBytes;
Mem: TMemoryStream;
begin
if (Client.Connected) then begin

Segment.NameStr := 'Adrian';
Segment2.NameStr := 'Jon';

Mem := TMemoryStream.Create;
Mem.Write(Segment, SizeOf(Segment));
Mem.Write(Segment2, SizeOf(Segment2));

//The Size of the stream is 8 bytes here!
Client.IOHandler.Write(Mem, 0, False);

结尾;

为了模拟“图像文件”，我只想连续发送两条记录；这就是目标。请注意，我一次发送整个内存流（！），而不是逐条记录。但有趣的是，服务器运行了两次 OnExecute 事件！

var
Buffer: TIdBytes;
Segment: TDPPSegment;
Mem: TMemoryStream;
begin
Mem := TMemoryStream.Create;
AContext.Connection.IOHandler.ReadStream(Mem, SizeOf(TDPPSegment), False);

//Incoming stream size is FOUR bytes but TWICE!
Mem.Position := 0;
Mem.Read(Segment, SizeOf(TDPPSegment));
Showmessage(Segment.NameStr);

我希望它执行一次，所以将来我可以先读取标题记录（已知大小），然后查看要遵循的内容/是否有任何内容并采取相应的行动..

帮助将不胜感激！

感谢阅读，阿德里安

4

1 回答 1

0

您的记录中包含非 ShortString 字符串，这一点从字符数据占用的字节数大于写入流中的字节数就可以看出——这意味着指针值 (2 x SizeOf(Pointer))正在写入流而不是实际字符。因此，您必须手动序列化您的字符串，例如发送字符串长度后跟实际字符。如果您计划支持 Delphi 2009+，则必须考虑 Unicode，因此您应该在传输之前对字符串进行编码，然后在接收端对其进行解码。

记录对于组织内存中的数据很有用，但对于通过网络传输数据通常不是很有用，除非记录仅包含 POD 类型（并且字符串不符合此条件）。

试试这个：

procedure WriteStrToIO(IO: TIdIOHandler; const S: String);
var
  Buf: TIdBytes;
  Len: Integer;
begin
  Buf := ToBytes(S, IndyUTF8Encoding);
  Len := Length(Buf);
  IO.Write(Len); 
  if Len > 0 then IO.Write(Buf); 
end;

var 
  Len: Integer;
  Buf: TIdBytes; // or whatever you want to use...
begin 
  if Client.Connected then
  begin 
    WriteStrToIO(Client.IOHandler, 'Adrian');

    Buf := ...; // secondary data
    Len := Length(Buf);
    Client.IOHandler.Write(Len);
    if Len > 0 then
      Client.IOHandler.Write(Buf);

    ...
  end;
end;

.

var 
  NameStr: String; 
  Buf: TIdBytes;
begin   
  with AContext.Connection.IOHandler do
  begin
    NameStr := ReadString(ReadInteger, IndyUTF8Encoding); 

    // read secondary data ...
    ReadBytes(Buf, ReadInteger);
  end;

  // ShowMessage() is not thread-safe!
  Windows.MessageBox(0, PChar(NameStr), 'NameStr', MB_OK); 
end;

至于OnExecute事件被多次触发，那是正常的行为。该事件根本与数据传输无关。它在连接的生命周期内连续循环调用。退出事件处理程序后，如果客户端仍处于连接状态，则会立即再次触发它。这对于像您这样的基于消息的协议很有用，其中事件被触发，读取一条消息等待数据到达，退出，再次触发以读取下一条消息等待数据到达，等等。

于 2012-07-18T17:16:31.440 回答