1

查找网络浏览器是否正在运行的最佳方法是什么？

使用 Delphi XE2 并在 Windows 上，我需要查看以下 Web 浏览器当前是否正在运行：

A) Mozilla Firefox B) Apple Safari C) Google Chrome

如果找到，该过程将终止，因为需要通过修改 Web 浏览器配置文件以编程方式更改 Web 浏览器的主页（如果在 Web 浏览器运行时这样做是不可能的，或者可能导致不可预知的结果）跑步）。

EnumWindows API 函数的输出是否包含处理上述任务所需的足够信息？如果是，那么上述每个网络浏览器的窗口类名称是否记录在任何地方？如果不是，那么哪种方法最可靠？

TIA。

4

1 回答 1

7

在没有用户许可的情况下终止进程不是好的做法，相反，您必须询问用户是否要终止应用程序（在这种情况下是 Web 浏览器）。

现在回到您的问题，您可以使用该方法检测应用程序（网络浏览器）是否正在运行检查进程名称（firefox.exe、chrome.exe、safari.exe）CreateToolhelp32Snapshot。

uses
  Windows,
  tlhelp32,
  SysUtils;

function IsProcessRunning(const ListProcess: Array of string): boolean;
var
  hSnapshot : THandle;
  lppe : TProcessEntry32;
  I : Integer;
begin
  result:=false;
  hSnapshot     := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  if hSnapshot <> INVALID_HANDLE_VALUE then
  try
    lppe.dwSize := SizeOf(lppe);
    if Process32First(hSnapshot, lppe) then
      repeat
        for I := Low(ListProcess) to High(ListProcess) do
        if  SameText(lppe.szExeFile, ListProcess[i])  then
          Exit(True);
      until not Process32Next(hSnapshot, lppe);
  finally
    CloseHandle(hSnapshot);
  end;
end;

并像这样使用

  IsProcessRunning(['firefox.exe','chrome.exe','safari.exe'])

现在如果你想要一个更可靠的方法你可以搜索窗口的类名（使用FindWindowEx方法），然后是句柄的进程所有者的PID（使用GetWindowThreadProcessId），从这里你可以使用进程的PID来解析exe的名称。

{$APPTYPE CONSOLE}

uses
  Windows,
  tlhelp32,
  SysUtils;

function GetProcessName(const th32ProcessID: DWORD): string;
var
  hSnapshot : THandle;
  lppe : TProcessEntry32;
begin
  result:='';
  hSnapshot     := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  if hSnapshot <> INVALID_HANDLE_VALUE then
  try
    lppe.dwSize := SizeOf(lppe);
    if Process32First(hSnapshot, lppe) then
      repeat
        if  lppe.th32ProcessID=th32ProcessID  then
          Exit(lppe.szExeFile);
      until not Process32Next(hSnapshot, lppe);
  finally
    CloseHandle(hSnapshot);
  end;
end;

function IsWebBrowserRunning(const ClassName, ExeName :string) : Boolean;
var
  hWindow : THandle;
  dwProcessId: DWORD;
begin
  result:=False;
  hWindow:= FindWindowEx(0, 0, PChar(ClassName), nil);
  if hWindow<>0 then
  begin
    dwProcessId:=0;
    GetWindowThreadProcessId(hWindow, dwProcessId);
    if dwProcessId>0 then
      exit(Sametext(GetProcessName(dwProcessId),ExeName));
  end;
end;


begin
  try
   if IsWebBrowserRunning('MozillaWindowClass','firefox.exe') then
    Writeln('Firefox is Running');

   if IsWebBrowserRunning('{1C03B488-D53B-4a81-97F8-754559640193}','safari.exe') then
    Writeln('Safari is Running');

   if IsWebBrowserRunning('Chrome_WidgetWin_1','chrome.exe') then
    Writeln('Chrome is Running');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  readln;
end.
于 2012-07-17T04:39:59.077 回答