javascript - 通过 javascript 更改 QML GridView 模型

Question

我有一个 ListView 和一个 GridView。想象一下：第一个视图显示类别，第二个视图显示每个类别中的文章。当ListView的当前索引通过javascript更改时，我想动态更改GridView的数据模型。我们如何做到这一点？

Answer 1

您只需要分配一个新模型。这是一个基于 ListModel 文档的示例。这个模型在左边的ListView中展示了模型中的果实。单击委托时，它将右侧的 GridView 模型设置为attributes角色定义的列表。

import QtQuick 1.0

Item {
    width: 600; height: 400

    ListView {
        width: 300; height: 400
        model: fruitModel
        delegate: Text {
            font.pixelSize: 20
            text: name
            width: 300
            MouseArea {
                anchors.fill: parent
                onClicked: grid.model = attributes
            }
        }
    }

    GridView {
        id: grid
        x: 300; width: 300; height: 400
        delegate: Text {
            text: description
            font.pixelSize: 20
        }
    }

    ListModel {
     id: fruitModel

     ListElement {
         name: "Apple"
         cost: 2.45
         attributes: [
             ListElement { description: "Core" },
             ListElement { description: "Deciduous" }
         ]
     }
     ListElement {
         name: "Orange"
         cost: 3.25
         attributes: [
             ListElement { description: "Citrus" }
         ]
     }
     ListElement {
         name: "Banana"
         cost: 1.95
         attributes: [
             ListElement { description: "Tropical" },
             ListElement { description: "Seedless" }
         ]
     }
    }
}

这是嵌套模型的示例，但还有其他可能性。例如，如果您从数据库中获取数据，也许您只需要更改 GridView 模型使用的查询，而不是设置不同的模型。

Answer 2

取决于你的模型。假设CategoriesModel有category角色，ArticlesModel有setCategory方法：

ListView {
    model: CategoriesModel {}
    delegate: Item {
        MouseArea {
            anchors.fill: parent
            onClicked: {
                grid_view.model.setCategory(model.category)
            }
        }
        // ...
    }
}

GridView {
    id: grid_view
    model: ArticlesModel {}
    // ...
}