gnuplot - Gnuplot 网格格式 xtics mxtics

Question

如何为主网格（xtics、ytics）定义一种格式，为次要网格（mxtics 和 mytics）定义另一种格式？

我试过了：

set style line 100 lt 1 lc rgb "gray" lw 2
set style line 101 lt 1 lc rgb "gray" lw 1
set grid xtics ytics ls 100
set grid mxtics mytics ls 101

但这需要所有网格的最后定义的 lw (1)。

Answer 1

set style line 100 lt 1 lc rgb "gray" lw 2
set style line 101 lt 0.5 lc rgb "gray" lw 1

set grid mytics ytics ls 100, ls 101
set grid mxtics xtics ls 100, ls 101

真的行 ：）。

Answer 2

gnuplot还将使用 . 在轻微抽动处绘制网格线set grid mxtics mytics。

要为主要网格线和次要网格线设置不同的线型，请使用正确的语法（用逗号分隔主要线型和次要线型）：

set style line 100 lt 1 lc rgb "blue" lw 2
set style line 101 lt 1 lc rgb "gray" lw 1
set grid mxtics mytics ls 100, ls 101

Answer 3

The minor tics mxtics and mytics are also drawn but with the same format than the main tics. And that is a problem when you want to differentiate them. Your solution with the arrows did the trick but I found it easier to first draw the minor ticks and than overwrite them with arrows for the main ones. Tanks.

set style line 100 lt 2 lc rgb "blue" lw 1
set style line 101 lt 1 lc rgb "gray" lw 1

# first draw the minor tics
set xrange [0:1]
set mxtics 10
set yrange [0:1]
set mytics 5
set grid mxtics mytics ls 101

# then the main tics
dx=0.2  #grid spacing in x
set for [i=1:5] arrow from graph i*dx,graph 0 to graph i*dx,graph 1 nohead front ls 100
dy=0.2  #grid spacing in y
set for [i=1:5] arrow from graph 0,graph i*dy to graph 1,graph i*dy nohead front ls 100

plot sin(x)

Answer 4

在 gnuplot 中，网格仅绘制在主要 tic 标记的位置，但是，如果您想要有两个不同的网格，您可以使用箭头：

set style line 101 lt 1 lc rgb "gray" lw 1
dx=.1  #grid spacing in x
set for [i=1:10] arrow from graph i*dx,graph 0 to graph i*dx,graph 1 nohead front ls 101 
set xrange [0:1]
plot sin(x)