12

所以这个问题纯粹是出于学习目的和好奇心，但是任何人都可以解释下面的函数是如何工作的吗？

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) {
    my $max = -1;
    $max < $#$_ && ( $max = $#$_ ) foreach @_;
    map {
        my $ix = $_;
        map $_->[$ix], @_;
    } 0 .. $max;
}

它来自List::MoreUtils模块。我在我的一个应用程序中使用它，我碰巧看到了源代码，这让我觉得我根本不知道 perl！谁能解释这种疯狂？：） 谢谢！

4

1 回答 1

13

我不会涵盖原型部分（暴民说他会）。

这是一个更易读的版本 - 理想情况下，它应该是不言自明的

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) {

    # Calculate the maximum number of elements in each of the array refs 
    # we were passed:

    my $maxLength = 0;
    foreach my $array_ref (@_) { # @_ is all arrey refs passed in
        if ($maxLength < @$array_ref) { 
            # we found an array longer than all previous ones 
            $maxLength = @$array_ref;
        }
    }

    # If you represent the arrays as a matrix:
    #   ARR1 = [ a1e1, a1e2, .... a1eN],
    #   ARR2 = [ a2e1, a2e2, .... a2eN],
    #    ...
    #   ARR2 = [ aMe1, aMe2, .... aMeN];
    # Then, we are simply walking through the matrix;
    # each column top to bottom then move on to next column left to right
    # (a1e1, a2e1, ... aMe1, a1e2, a2e2, ... aMeN)

    my @results;
    for (my $index = 0; $index < $maxLength; $index++) { # Iterate over columns
         foreach my $array_ref (@_) { # Iterate over per-row cells in each column
             push @results, $array_ref->[$index];
         }
    } ;
}

这是一个评论的原始版本

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) {

    # Calculate the largest index in each of the array refs
    # @_ is an array of all the input arrayrefs
    # $_ will be one of the array refs in a foreach loop
    # $#{$X} is the largest index in arrayref X; thus
    # $#$_ is the largest index in arrayref $_
    my $max = -1;
    $max < $#$_ && ( $max = $#$_ ) foreach @_;

    # Return a list, obtained by looping 
    # over every index from 0 to the maximal index of any of the arrays
    # Then, for each value of the index ($ix), push into the resulting list
    # an element with that index from each of the arrays.
    map {
        my $ix = $_;
        map $_->[$ix], @_;
    } 0 .. $max;
}

这种方法中不寻常的事情之一是function signature (prototype).

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) {

正如@mob 和@ikegami 在评论中明智地指出的那样，

...它指示 Perl 期望有 2 到 32 个命名数组，并将它们作为数组引用传递给函数（在 @_ 中）。因此，如果您调用mesh @a,@b,@c，则@_在网格中设置为(\@a,\@b,\@c)而不是一个包含@a, @b, and @c( mob )的所有单个元素的“平面”列表
......从技术上讲，它们不需要命名，只需取消引用。例如@$ref和@{[qw( foo bar )]}工作一样好@a。换句话说，它必须从@（而不是切片）开始。（池上）

换句话说，以下 2 个调用的行为相同

my @a1 = (1);
my @a2 = (2);
sub mesh_prototype(\@\@) { print "$_->[0]\n" }
sub mesh_pass_arrayref() { print "$_->[0]\n" }
mesh_prototype(@a1, @a2);
mesh_pass_arrayref(\@a1, \@a2);

这样做是为了您可以将单个数组（而不是 arrayrefs）作为参数传递给函数，这些函数的行为类似于内置函数（例如map/ sort）

要回答 Zaid 关于如果将 1 或 33 个数组列为要调用的参数会发生什么的查询mesh()，它将生成编译时错误：

Not enough arguments for main::mesh at mesh.pl line 16, near "@a1)"
Execution of mesh.pl aborted due to compilation errors.

Too many arguments for main::mesh at mesh.pl line 16, near "@a2)"
Execution of mesh.pl aborted due to compilation errors.
于 2012-07-13T16:55:23.640 回答