1

我知道我在下面描述的不是技术上的多播，但我缺乏对我正在尝试做的事情的更好描述。

我目前有一个带有 OnExecute 的 TIdTCPServer，它读取传入的消息，将响应消息生成到线程安全队列中，然后调用一个函数来单步执行队列并将消息发送回客户端。这部分代码正在工作，并允许客户端请求数据集。

当客户端更改服务器上的对象时，我希望所有客户端都通知此更改。该代码当前将通知消息添加到每个连接的每个队列中。我的问题是 OnExecute 没有循环，因此在服务器收到来自客户端的消息之前，不会调用在队列上发送消息的调用。

有没有办法让 OnExecute 循环？或者一种为我知道我已经为消息排队的连接触发 OnExecute 的方法？

我的过程 TWinSocketSession 对象具有对连接的引用，并包含传出消息队列的代码。它还有一个称为 SendMessages 的过程，它逐步遍历队列并调用 Connection.Write。下面是我的 OnExecute 过程。

procedure TWinServerSession.IdTCPServer1Execute(AThread: TIdPeerThread);
  Var
    i:           Integer;
    strMessage:  String;
  begin
    //find the Socket Session for connection
    for i := 0 to m_usClientCount do
      begin
        if m_mWinSocketSession[i]<>Nil then
          if ( m_mWinSocketSession[i].Connection = Athread.Connection ) then break;
      end;

    //read the message
    strMessage := m_mWinSocketSession[i].Connection.ReadLn(#0,25,-1);

    //parse the message and populate the Queue with outgoing messages
    m_mWinSocketSession[i].ParseInString(strMessage);

    //send all of the outgoing messages
    m_mWinSocketSession[i].SendMessages;
  end;
4

1 回答 1

3

是的，该TIdTCPServer.OnExecute事件是一个循环事件。入站消息到达时不会触发它。无论连接实际在做什么，它都会在连接的生命周期内连续循环触发。事件处理程序有责任根据需要实现阻塞行为。您的代码ReadLn()使用指定的 25 毫秒超时调用，因此它不会阻止事件处理程序及时退出，因此它可以立即重新进入。如果您的事件处理程序被阻止及时退出，那么您的代码中的其他地方就会出现死锁问题。

但是，我建议进行以下更改：

procedure TWinServerSession.IdTCPServer1Connect(AThread: TIdPeerThread); 
var
  i: Integer;
begin 
  for i := 0 to m_usClientCount do  
  begin  
    if (m_mWinSocketSession[i] = nil) then
    begin
      m_mWinSocketSession[i] := TWinSocketSession.Create;
      m_mWinSocketSession[i].Connection := AThread.Connection;

      // for easier access in the other events...
      AThread.Data := m_mWinSocketSession[i];  

      Exit;
    end;
  end;

  // cannot start a new session
  AThread.Connection.Disconnect;
end; 

procedure TWinServerSession.IdTCPServer1Disconnect(AThread: TIdPeerThread); 
var
  session: TWinSocketSession;
  i: Integer;
begin 
  session := TWinSocketSession(AThread.Data);
  AThread.Data := nil;

  if session <> nil then
  begin      
    for i := 0 to m_usClientCount do  
    begin  
      if m_mWinSocketSession[i] = session then
      begin
        m_mWinSocketSession[i] := nil;
        Break;
      end;
    end;
    session.Free;
  end;
end; 

procedure TWinServerSession.IdTCPServer1Execute(AThread: TIdPeerThread); 
var 
  session: TWinSocketSession;
  strMessage:  String; 
begin 
  session := TWinSocketSession(AThread.Data);

  //read a message  
  strMessage := AThread.Connection.ReadLn(#0, 25, -1);  
  if not AThread.Connection.ReadLnTimedOut then
  begin
    //parse the message and populate the Queue with outgoing messages  
    session.ParseInString(strMessage);  
  end;

  //send all of the outgoing messages  
  session.SendMessages;  
end;

OnConnect如果您可以完全消除 m_mWinSocketSession 列表并在事件中直接为 Connection 分配一个新队列，这会更好。当客户端断开连接时，该OnDisconnect事件可以释放队列。

procedure TWinServerSession.IdTCPServer1Connect(AThread: TIdPeerThread); 
begin
  AThread.Data := TWinSocketSession.Create;
  TWinSocketSession(AThread.Data).Connection := AThread.Connection;
end;

procedure TWinServerSession.IdTCPServer1Disconnect(AThread: TIdPeerThread); 
begin
  session := TWinSocketSession(AThread.Data);
  AThread.Data := nil;
  session.Free;
end;
于 2012-07-12T21:09:17.420 回答