2

我有以下 XML 文档：

<?xml version="1.0" encoding="UTF-8"?>
<cars>
    <car>
        <entrydata columnnumber="4" name="Colour">
            <text>Red</text>
        </entrydata>
    </car>
    <car>
        <entrydata columnnumber="4" name="Colour">
            <textlist>
                <text>Yellow</text>
                <text>Blue</text>
            </textlist>
        </entrydata>
    </car>
</cars>

以及以下 XSLT 样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com: xslt" exclude-result-prefixes="msxsl">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="/">
    <records>
      <xsl:apply-templates select="//cars"/>
    </records>
  </xsl:template>
  <!--Top level template -->
  <xsl:template match="cars">
    <!-- Loop through each document (viewentry) and apply create the rows for each one-->
    <xsl:for-each select="car">
      <record>
        <xsl:attribute name="Colour">
          <xsl:value-of select="entrydata[@name='Colour']"/>
        </xsl:attribute>
       </record>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

这会产生以下输出：

<?xml version="1.0" encoding="UTF-8"?>
<records>
    <record Colour="Red"/>
    <record Colour="YellowBlue"/>
</records>

我将如何修改 XSLT 文件以使输出变为（注意逗号分隔<textlist>）：

<?xml version="1.0" encoding="UTF-8"?>
<records>
    <record Colour="Red"/>
    <record Colour="Yellow, Blue"/>
</records>
4

3 回答 3

2

使用 XSLT 2.0，您可以使用

<record Colour="{string-join(entrydata[@name='Colour']/textlist/text, ', ')}"/>

使用 XSLT 1.0 我会做

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com: xslt" exclude-result-prefixes="msxsl">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="/">
    <records>
      <xsl:apply-templates select="//cars"/>
    </records>
  </xsl:template>
  <!--Top level template -->
  <xsl:template match="cars/car">
    <record>
        <xsl:attribute name="Colour">
          <xsl:apply-templates select="entrydata[@name='Colour']textlist/text"/>
        </xsl:attribute>
       </record>
  </xsl:template>
  <xsl:template match="textlist/text">
    <xsl:if test="position() > 1">
      <xsl:text>, </xsl:text>
    </xsl:if>
    <xsl:value-of select="."/>
  </xsl:template>
</xsl:stylesheet>
于 2012-07-10T10:19:28.143 回答
2

一个不那么冗长的纯“推送式”XSLT 1.0 解决方案，它不使用硬编码字符串作为生成属性的名称：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="cars">
     <records>
       <xsl:apply-templates/>
     </records>
 </xsl:template>
 <xsl:template match="car">
  <record>
   <xsl:apply-templates/>
  </record>
 </xsl:template>
 <xsl:template match="entrydata">
  <xsl:attribute name="{@name}">
   <xsl:apply-templates/>
  </xsl:attribute>
 </xsl:template>
 <xsl:template match="text">
  <xsl:if test="position() >1">, </xsl:if>
  <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<cars>
    <car>
        <entrydata columnnumber="4" name="Colour">
            <text>Red</text>
        </entrydata>
    </car>
    <car>
        <entrydata columnnumber="4" name="Colour">
            <textlist>
                <text>Yellow</text>
                <text>Blue</text>
            </textlist>
        </entrydata>
    </car>
</cars>

产生了想要的正确结果：

<records>
   <record Colour="Red"/>
   <record Colour="Yellow, Blue"/>
</records>

说明：

正确使用模板、模式匹配、AVTs 和position()函数。

二、更简单的 XSLT 2.0 解决方案

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="cars">
     <records>
       <xsl:apply-templates/>
     </records>
 </xsl:template>
 <xsl:template match="car">
  <record>
   <xsl:apply-templates/>
  </record>
 </xsl:template>
 <xsl:template match="entrydata">
  <xsl:attribute name="{@name}">
   <xsl:value-of select=".//text" separator=", "/>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

当将此转换应用于同一个 XML 文档（如上）时，会产生相同的正确结果：

<records>
   <record Colour="Red"/>
   <record Colour="Yellow, Blue"/>
</records>

说明：

正确使用模板、模式匹配、AVTseparator和xsl:value-of

于 2012-07-10T12:10:28.963 回答
1

这个 XSLT 1.0 样式表可以解决问题...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

  <xsl:template match="/">
    <records>
      <xsl:apply-templates select="*/*"/>
    </records>
  </xsl:template>

  <xsl:template match="car">
   <xsl:variable name="colour-list">
     <xsl:for-each select="entrydata[@name='Colour']/text |
                           entrydata[@name='Colour']/textlist/text">
       <xsl:value-of select="concat(.,', ')" />
     </xsl:for-each>  
   </xsl:variable>  
      <record Colour="{substring($colour-list,1,string-length($colour-list)-2)}"/>
  </xsl:template>
</xsl:stylesheet>

但是最简单的解决方案的赢家是这个 XSLT 2.0 样式表......

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/">
 <records>
  <xsl:apply-templates select="*/*"/>
 </records>
</xsl:template>

<xsl:template match="car">
 <record Colour="{string-join(entrydata[@name='Colour']/(text | textlist/text),', ')}"/>
</xsl:template>
</xsl:stylesheet>
于 2012-07-10T10:21:39.750 回答