10

我正在使用以下序列实现简单的 tcp 服务器：

{ok, LS} = gen_tcp:listen(Port,[{active, true}, {reuseaddr, true}, {mode, list}]),
{ok, Socket} =  gen_tcp:accept(LS),
Pid = spawn_link(M, F, [Socket]),           
gen_tcp:controlling_process(Socket, Pid)

使用选项 {active, true} 可能会导致竞争条件，即新数据包在调用“controlling_process”之前到达套接字进程，这将导致 {tcp,Socket,Data} 消息到达父进程而不是孩子。

如何避免这种情况？

4

3 回答 3

17

你说的对。在这种情况下，您肯定需要{active, false}在侦听套接字选项之间传递。考虑这段代码：

-define(TCP_OPTIONS, [binary, {active, false}, ...]).

...

start(Port) ->
    {ok, Socket} = gen_tcp:listen(Port, ?TCP_OPTIONS),
    accept(Socket).

accept(ListenSocket) ->
    case gen_tcp:accept(ListenSocket) of
        {ok, Socket} ->
            Pid = spawn(fun() ->
                io:format("Connection accepted ~n", []),
                enter_loop(Socket)
            end),
            gen_tcp:controlling_process(Socket, Pid),
            Pid ! ack,
            accept(ListenSocket);
        Error ->
            exit(Error)
    end.

enter_loop(Sock) ->
    %% make sure to acknowledge owner rights transmission finished
    receive ack -> ok end,
    loop(Sock).

loop(Sock) ->
    %% set soscket options to receive messages directly into itself
    inet:setopts(Sock, [{active, once}]),
    receive
        {tcp, Socket, Data} ->
            io:format("Got packet: ~p~n", [Data]),
            ...,
            loop(Socket);
        {tcp_closed, Socket} ->
            io:format("Socket ~p closed~n", [Socket]);
        {tcp_error, Socket, Reason} ->
            io:format("Error on socket ~p reason: ~p~n", [Socket, Reason])
    end.

controlling_process因此，在成功之前，您不会失去任何东西。已知问题已在互联网上进行了很多讨论。如果您希望使用准备就绪的解决方案，您肯定需要查看Ranch项目。

于 2012-07-10T09:24:04.157 回答
2

如果套接字是活动的，inet:tcp_controlling_process（由 调用gen_tcp:controlling_process）将套接字设置为被动，然后选择性地接收与该套接字相关的所有消息并将它们发送给新所有者，从而有效地将它们移动到新所有者的消息队列中。然后它将套接字恢复为活动状态。

所以不存在竞争条件：他们已经想到了这一点并将其修复在库中。

于 2015-11-25T16:14:08.970 回答
2

绝对有竞争条件。我今天在 OTP 21.2 中遇到了它，这就是我在这里的原因。accept数据包可以在返回时间和inet:tcp_controlling_process将套接字设置为被动时间之间到达。

我只是想指出上面@Keynslug 答案的微小简化。套接字可以从非拥有进程设置为活动的，因此ack消息传递和enter_loop是不必要的

-define(TCP_OPTIONS, [binary, {active, false}, ...]).

...

start(Port) ->
    {ok, Socket} = gen_tcp:listen(Port, ?TCP_OPTIONS),
    accept(Socket).

accept(ListenSocket) ->
    case gen_tcp:accept(ListenSocket) of
        {ok, Socket} ->
            Pid = spawn(fun() ->
                io:format("Connection accepted ~n", []),
                loop(Socket)
            end),
            gen_tcp:controlling_process(Socket, Pid),
            inet:setopts(Socket, [{active, once}]),
            accept(ListenSocket);
        Error ->
            exit(Error)
    end.

loop(Sock) ->
    %% set soscket options to receive messages directly into itself
    inet:setopts(Sock, [{active, once}]),
    receive
        {tcp, Socket, Data} ->
            io:format("Got packet: ~p~n", [Data]),
            ...,
            loop(Socket);
        {tcp_closed, Socket} ->
            io:format("Socket ~p closed~n", [Socket]);
        {tcp_error, Socket, Reason} ->
            io:format("Error on socket ~p reason: ~p~n", [Socket, Reason])
    end.
于 2020-01-05T22:18:05.620 回答