9

工作表 A具有从工作表 B收集的数据范围。工作表 A有一个宏，用于计算数据是否高于某个值，然后调用电子邮件模块向选定的用户发送电子邮件。

当在工作表 A上手动输入数据时，宏可以工作，但是当从工作表 B中提取数据时，它不会触发。

我不确定我需要在 VBA 代码中更改什么。

Private Sub Worksheet_Change(ByVal Target As Range)
    Call MailAlert(Target, "B5:M5", 4) 
    Call MailAlert(Target, "B8:M8", 7) 
    Call MailAlert(Target, "B11:M11", 6)
    Call MailAlert(Target, "B14:M14", 2) 
    Call MailAlert(Target, "B17:M17", 4) 
    Call MailAlert(Target, "B20:M20", 1) 
    Call MailAlert(Target, "B23:M23", 3) 
    Call MailAlert(Target, "B26:M26", 1) 
    Call MailAlert(Target, "B29:M29", 5) 
    Call MailAlert(Target, "B32:M32", 1) 
    Call MailAlert(Target, "B35:M35", 7) 
    Call MailAlert(Target, "B38:M38", 20) 
    Call MailAlert(Target, "B41:M41", 0) 
End Sub

Private Sub MailAlert(ByVal Target As Range, ByVal Address As String, ByVal Value As Integer)
    If Target.Cells.Count > 1 Then Exit Sub
    If Not Application.Intersect(Range(Address), Target) Is Nothing Then
        If IsNumeric(Target.Value) And Target.Value > Value Then
        Call Mail_small_Text_Outlook
        End If
        Application.EnableEvents = True
    End If
End Sub
4

2 回答 2

23

要通过公式捕获更改，您必须使用Worksheet_Calculate()事件。为了理解它是如何工作的，让我们举个例子。

  1. 创建一个新工作簿。
  2. 在 Sheet1 单元格 A1 中，输入此公式=Sheet2!A1+1

现在在一个模块中粘贴此代码

Public PrevVal As Variant

将此粘贴到工作表代码区域

Private Sub Worksheet_Calculate()
    If Range("A1").Value <> PrevVal Then
        MsgBox "Value Changed"
        PrevVal = Range("A1").Value
    End If
End Sub

最后在ThisWorkbook代码区域粘贴此代码

Private Sub Workbook_Open()
    PrevVal = Sheet1.Range("A1").Value
End Sub

关闭并保存工作簿并重新打开它。现在对 的单元格 A1 进行任何更改Sheet2。您会注意到您将收到消息框MsgBox "Value Changed"

快照

在此处输入图像描述

于 2012-07-10T08:39:19.733 回答
0

worksheet_change 事件只会在手动用户更改时触发。我认为您最好的选择是将其作为工作表 B 上的工作表更改事件来实现，我假设用户输入更改正在发生。

如果这真的不适合您，我会建议一些替代方案，但我认为这可能是迄今为止最好的选择。

编辑：根据以下评论的另一个建议

ThisWorkbook 对象有一个事件 SheetChange，只要工作簿中的任何工作表发生更改，就会触发该事件。如果您可以确定将在每张 B 表上输入数据的范围，那么您可以像在原始代码中一样使用这些范围。

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If Not Sh Is Sheets("Worksheet A") Then
        If Intersect(Sh.Range("B1:B5"), Target) Then
            'Call MailAlert as required here
        ElseIf Intersect(Sh.Range("B10:B20"), Target) Then
            'Call MailAlert as required here
        Else ' Etc...
            'Call MailAlert as required here
        End If
    End If
End Sub

让我知道情况如何。

于 2012-07-10T05:02:22.957 回答