1

我正在阅读 URL（并试图复制）但失败了......（关于 antlr 的文章也很棒）。

https://supportweb.cs.bham.ac.uk/docs/tutorials/docsystem/build/tutorials/antlr/antlr.html

在添加括号内容之前我的解决方案：

whereClause: WHERE expression -> ^(WHERE_CLAUSE expression);
expression: orExpr;
orExpr: andExpr (OR^ andExpr)*;
andExpr: primaryExpr (AND^ primaryExpr)*;
primaryExpr: parameterExpr | inExpr | compExpr;

我的解决方案由于无限递归而失败（但我认为 LPAREN^ 和 RPAREN！应该在哪里解决这个问题？？？）....

whereClause: WHERE^ (expression | orExpr);
expression: LPAREN^ orExpr RPAREN!;
orExpr: andExpr (OR^ andExpr)*;
andExpr: primaryExpr (AND^ primaryExpr)*;
primaryExpr: parameterExpr | inExpr | compExpr | expression;

注意底部的primaryExpr 后面有表达式，它有LPAREN 和RPAREN，但是WHERE 可以是orExpr 或表达式（即第一个表达式可以使用或不使用括号）。

我确信这可能是一个简单的问题，比如我一直盯着几个小时之类的错字。

4

1 回答 1

1

我正在阅读网址（并试图复制）但失败了......（关于 antlr 的文章也很棒）......

请注意，本文解释了 ANTLR v2，它的语法与 v3 有很大不同。最好在这里寻找一个体面的 ANTLR v3 教程：https ://stackoverflow.com/questions/278480/antlr-tutorials

我的解决方案由于无限递归而失败（但我认为 LPAREN^ 和 RPAREN！应该在哪里解决这个问题？？？）....

如果那是WHILE. 但是，orExpr在您的情况下是导致问题的原因（如果您删除它，该递归错误将消失）。

带括号的表达式通常具有最高优先级，因此应该放在您的primaryExpr规则中，如下所示：

grammar T;

options {
  output=AST;
}

parse       : whereClause EOF!;
whereClause : WHERE^ expression;
expression  : orExpr;
orExpr      : andExpr (OR^ andExpr)*;
andExpr     : primaryExpr (AND^ primaryExpr)*;
primaryExpr : bool | NUMBER | '('! expression ')'!;
bool        : TRUE | FALSE;

TRUE        : 'true';
FALSE       : 'false';
WHERE       : 'where';
LPAREN      : '(';
RPAREN      : ')';
OR          : '||';
AND         : '&&';
NUMBER      : '0'..'9'+ ('.' '0'..'9'*)?;
SPACE       : (' ' | '\t' | '\r' | '\n')+ {skip();};

现在输入"where true || false"和"where (true || false)"都将在以下 AST 中进行解析：

在此处输入图像描述

于 2012-07-07T05:50:55.540 回答