3

帮我翻译下面的 Haskell 代码块。run函数生成对应于抽象为 Pattern 的给定正则表达式的文本字符串。您可以在下面的 F# 代码块中看到 Pattern 类型的声明。您可以测试运行功能，例如

genex $ POr [PConcat [PEscape( DoPa 1) 'd'], PConcat [PEscape (DoPa 2) 'd']]

{-# LANGUAGE RecordWildCards, NamedFieldPuns #-}
import qualified Data.Text as T
import qualified Control.Monad.Stream as Stream
import Text.Regex.TDFA.Pattern
import Control.Monad.State
import Control.Applicative

genex = Stream.toList . run

maxRepeat :: Int
maxRepeat = 3

each = foldl1 (<|>) . map return

run :: Pattern -> Stream.Stream T.Text
run p = case p of
    PBound low high p -> do
        n <- each [low..maybe (low+maxRepeat) id high]
        fmap T.concat . sequence $ replicate n (run p) 
    PConcat ps -> fmap T.concat . Stream.suspended . sequence $ map run ps
    POr xs -> foldl1 mplus $ map run xs
    PEscape {..} -> case getPatternChar of
        'd' -> chars $ ['0'..'9']
        'w' -> chars $ ['0'..'9'] ++ '_' : ['a'..'z'] ++ ['A'..'Z']
        ch  -> isChar ch
    _      -> error $ show p
    where
    isChar = return . T.singleton
    chars = each . map T.singleton

下面我给出我糟糕的尝试。它工作但不正确。问题在以下。假设parse产生这样的Pattern

解析“\\d\\d”；；验证它：Pattern = POr [PConcat [PEscape (DoPa 1,'d'); PEscape (DoPa 2,'d')]]

和

解析“\\d{2}”；；验证它：Pattern = POr [PConcat [PBound (2,Some 2,PEscape (DoPa 1,'d'))]]

所以喂两种模式运行我希望收到seq [['2'; '2']; ['2'; '3']; ['2'; '1']; ['2'; '4']; ...]对应于seq ["22"; “23”；“21”；“24”；...]（每个字符串 2 个符号）

这在第一种情况下是有效的，

POr [PConcat [PEscape (DoPa 1,'d'); PEscape (DoPa 2,'d')]] |> 运行;; 验证它：seq = seq [['2'; '2']; ['2'; '3']; ['2'; '1']; ['2'; '4']; ...]

序列 ["22"; “23”；“21”；“24”；...]

但不是在第二个

POr [PConcat [PBound (2,Some 2,PEscape (DoPa 1,'d'))]] |> 运行;; 验证它：seq = seq [['2']; ['2']; ['2']; ['3']; ...]

序列 ["2"; “2”，“2”；“3”、“2”；“1”、“2”；"4";...]（每个字符串 1 个符号）

我使用以下子句测试了不同的变体：

| POr ps                -> Seq.concat (List.map run ps)
| PConcat ps            -> (sequence (List.map (run >> Seq.concat) ps))
| PBound (low,high,p)   ->

但一切都是徒劳的。我无法弄清楚有效的翻译。

- 也许我应该使用字符串或数组而不是字符列表。

-而且我认为 Seq 非常类似于 Control.Monad.Stream。这样对吗？

提前感谢您的帮助

open System

/// Used to track elements of the pattern that accept characters or are anchors
type DoPa = DoPa of int

/// Pattern is the type returned by the regular expression parser.
/// This is consumed by the CorePattern module and the tender leaves
/// are nibbled by the TNFA module.
type Pattern = PEmpty
             | POr     of Pattern list                  // flattened by starTrans
             | PConcat of Pattern list                  // flattened by starTrans
             | PBound  of int * (int option) * Pattern  // eliminated by starTrans
             | PEscape of DoPa * char                   // Backslashed Character

let maxRepeat = 3

let maybe deflt f opt = 
    match opt with
    | None -> deflt
    | Some v -> f v

/// Cartesian production
/// try in F# interactive: sequence [[1;2];[3;4]];;
let rec sequence = function 
  | []      -> Seq.singleton [] 
  | (l::ls) -> seq { for x in l do for xs in sequence ls do yield (x::xs) } 



let from'space'to'tilda     =  [' '..'~'] |> List.ofSeq
let numbers                 =  ['0'..'9'] |> List.ofSeq
let numbers'and'alphas      =  (['0'..'9'] @ '_' :: ['a'..'z'] @ ['A'..'Z']) |> List.ofSeq
let whites                  =  ['\009'; '\010'; '\012'; '\013'; '\032' ] |> List.ofSeq

let rec run (p:Pattern) : seq<char list> =
    let chars chs = seq { yield [for s in chs -> s] }
    match p with
    | POr ps                -> Seq.concat (List.map run ps)
    | PConcat ps            -> (sequence (List.map (run >> Seq.concat) ps))
    | PBound (low,high,p)   -> 
        let ns = seq {low .. maybe (low + maxRepeat) id high}
        Seq.concat (seq { for n in ns do yield  sequence (List.replicate n (((run >> Seq.concat)  p))) })
        // Seq.concat (seq { for n in ns do yield     ((List.replicate n (run p)) |> Seq.concat |> List.ofSeq |> sequence)})
        //((List.replicate low (run p)) |> Seq.concat |> List.ofSeq |> sequence)
        // PConcat [ for n in ns -> p] |> run
    | PEscape(_, ch)  -> 
        match ch with
        | 'd' -> chars numbers
        | 'w' -> chars numbers'and'alphas
        | ch  -> chars [ch]
    | _                     -> Seq.empty
4

1 回答 1

4

我不知道你为什么不Data.Text从 Haskell 翻译到stringF#，你只需要模仿两个函数。除此之外，我只做了一些更改以使其正常工作，这样您就可以轻松地将其与原始代码进行比较，请参阅 (* *) 之间的替换代码

open System

// Mimic Data.Text as T
module T =
    let concat (x:seq<_>) = System.String.Concat x
    let singleton (x:char) = string x


/// Used to track elements of the pattern that accept characters or are anchors
type DoPa = DoPa of int

/// Pattern is the type returned by the regular expression parser.
/// This is consumed by the CorePattern module and the tender leaves
/// are nibbled by the TNFA module.
type Pattern = PEmpty
             | POr     of Pattern list                  // flattened by starTrans
             | PConcat of Pattern list                  // flattened by starTrans
             | PBound  of int * (int option) * Pattern  // eliminated by starTrans
             | PEscape of DoPa * char                   // Backslashed Character

let maxRepeat = 3

let maybe deflt f opt = 
    match opt with
    | None -> deflt
    | Some v -> f v

/// Cartesian production
/// try in F# interactive: sequence [[1;2];[3;4]];;
let rec sequence = function 
  | []      -> Seq.singleton [] 
  | (l::ls) -> seq { for x in l do for xs in sequence ls do yield (x::xs) } 



let from'space'to'tilda     =  [' '..'~'] |> List.ofSeq
let numbers                 =  ['0'..'9'] |> List.ofSeq
let numbers'and'alphas      =  (['0'..'9'] @ '_' :: ['a'..'z'] @ ['A'..'Z']) |> List.ofSeq
let whites                  =  ['\009'; '\010'; '\012'; '\013'; '\032' ] |> List.ofSeq

let rec run (p:Pattern) (*: seq<char list> *) =
    (* let chars chs = seq { yield [for s in chs -> s] } *)
    let chars (chs:seq<char>)  = Seq.map string chs

    match p with
    | POr ps                -> Seq.concat (List.map run ps)
    | PConcat ps            -> Seq.map T.concat << sequence <| List.map run ps (* (sequence (List.map (run >> Seq.concat) ps)) *) 
    | PBound (low,high,p)   -> 
        seq {
        for n in [low..maybe (low+maxRepeat) id high] do
            yield! (  (Seq.map T.concat << sequence) (List.replicate n (run p)) )}
        (*let ns = seq {low .. maybe (low + maxRepeat) id high}
        Seq.concat (seq { for n in ns do yield  sequence (List.replicate n (((run >> Seq.concat)  p)))  *)

        // Seq.concat (seq { for n in ns do yield     ((List.replicate n (run p)) |> Seq.concat |> List.ofSeq |> sequence)})
        //((List.replicate low (run p)) |> Seq.concat |> List.ofSeq |> sequence)
        // PConcat [ for n in ns -> p] |> run
    | PEscape(_, ch)  -> 
        match ch with
        | 'd' -> chars numbers
        | 'w' -> chars numbers'and'alphas
        | ch  -> chars [ch]
    | _                     -> Seq.empty


更新

如果您要将 Haskell 代码转换为 F#，您可以尝试使用此代码来模仿许多 Haskell 函数，包括使用类型类的函数。我做了一个尽可能接近原始 Haskell 代码的测试，但使用 F# List（不是懒惰的），看起来像这样：

#load "Prelude.fs"
#load "Monad.fs"
#load "Applicative.fs"
#load "Monoid.fs"

open Prelude
open Control.Monad.Base
open Control.Applicative

module T =
    let concat (x:list<_>) = System.String.Concat x
    let singleton (x:char) = string x

type DoPa = DoPa of int

type Pattern = PEmpty
             | POr     of Pattern list
             | PConcat of Pattern list
             | PBound  of int * (int option) * Pattern
             | PEscape of DoPa * char

let maxRepeat = 3

let inline each   x = foldl1 (<|>) << map return'  <| x

let rec run p:list<_> = 
    let inline isChar x = return' << T.singleton   <| x
    let inline chars  x = each << map T.singleton  <| x
    match p with
    | PBound (low,high,p) -> do' {
        let! n = each [low..maybe (low+maxRepeat) id high]
        return! (fmap T.concat << sequence <| replicate n (run p))}
    | PConcat ps -> fmap T.concat << sequence <| map run ps
    | POr xs -> foldl1 mplus <| map run xs
    | PEscape (_, ch) -> 
        match ch with
        | 'd' -> chars <| ['0'..'9']
        | 'w' -> chars <| ['0'..'9'] @ '_' :: ['a'..'z'] @ ['A'..'Z']
        | ch  -> isChar ch
    | _  -> failwith <| string p

let genex = run
于 2012-07-05T22:50:09.603 回答