32

如何在 Windows 中批量删除数千个文件中的空格（不替换为下划线）？我可以从 DOS 命令执行此操作吗？

目前：

file one.mp3
file two.mp3

所有文件都需要变成：

fileone.mp3
filetwo.mp3
4

9 回答 9

89

这是一个可以有效地批量重命名文件的脚本，从名称中删除所有空格。

:renameNoSpace  [/R]  [FolderPath]
@echo off
setlocal disableDelayedExpansion
if /i "%~1"=="/R" (
  set "forOption=%~1 %2"
  set "inPath="
) else (
  set "forOption="
  if "%~1" neq "" (set "inPath=%~1\") else set "inPath="
)
for %forOption% %%F in ("%inPath%* *") do (
  if /i "%~f0" neq "%%~fF" (
    set "folder=%%~dpF"
    set "file=%%~nxF"
    setlocal enableDelayedExpansion
    echo ren "!folder!!file!" "!file: =!"
    ren "!folder!!file!" "!file: =!"
    endlocal
  )
)

假设脚本名为renameNoSpace.bat

renameNoSpace:（无参数）重命名当前目录中的文件

renameNoSpace /R：重命名以当前目录为根的文件夹树中的文件

renameNoSpace myFolder：重命名当前目录中的“myFolder”目录中的文件。

renameNoSpace "c:\my folder\"：重命名指定路径中的文件。使用引号是因为路径包含空格。

renameNoSpace /R c:\: 重命名 C: 驱动器上的所有文件。

于 2012-07-01T01:40:16.857 回答
24

在 Windows 中：

  1. 打开命令提示符。
  2. 使用 cd 命令转到文件夹（例如：cd "paht of your folder"）。
  3. 通过键入以下命令打开 powershell： powershell
  4. 然后输入：get-childitem *.mp3 | foreach {重命名项目 $_ $_.name.replace(" ","")}
于 2019-07-14T04:38:31.083 回答
13

创建一个 powershell 文件 -*.ps1扩展名

写下这段代码：

dir |
Where-Object { $_.name.Contains(" ") } |
Rename-Item -NewName { $_.name -replace " ","" }

保存，然后右键->用powershell运行

于 2014-04-07T12:57:28.947 回答
4

您可以编写一个简单的脚本来为一个文件/目录执行此操作，例如：

@echo off
setlocal enableextensions enabledelayedexpansion

set "ARG=%~1"
ren "%ARG%" "%ARG: =%"

...然后，如果您愿意，可以在您关心的所有文件和/或目录上运行它。例如，如果您将上述脚本创建为 myrenamingscript.cmd，您可以通过运行以下命令在当前目录中的所有非目录文件上运行它：

for %f in (*) do @myrenamingscript.cmd "%~f"
于 2012-06-30T00:29:14.157 回答
4 
@echo off
setlocal enableextensions enabledelayedexpansion

for %%f in (*.*) do (
set ARG=%%~nxf
rename "%%f" !ARG: =!
)
于 2013-02-23T02:14:17.067 回答
4

在 Windows 中打开Powershell，然后在导航到要重命名文件的文件夹后键入以下命令

get-childitem *.mp3 | foreach { rename-item $_ $_.Name.Replace(" ", "") }

我们来分析一下：

get-childitem *.mp3 这会列出所有名称以 .mp3 结尾的文件。然后使用 | 将它们传送到下一个命令。操作员。

foreach { 重命名项目 $_ $_.Name.Replace(" ", "") }

这将“”的所有实例（在这种情况下为空格 || 这是要替换的实例）替换为空，用“”表示，有效地从目录中的所有文件中擦除该单词。

您还可以将 get-childitem *.mp3 修改为 get-childitem - 这将重命名目录中的所有文件，而不仅仅是名称以 .mp3 结尾的文件。

** 笔记 **

如果您不喜欢上述方法，有一个很棒的软件，名为 Bulk Rename Utility。我个人使用过这个软件，你可以在 youtube 上了解如何使用它。

于 2021-07-18T08:46:56.393 回答
0

我面临的问题是，有可能已经有一个文件名称与您尝试赋予新文件的名称相同（例如，如果文件夹中有 2 个文件名为“file one.txt”和“file_one.txt” " 当您尝试用下划线替换空格时，一个文件将替换另一个文件）。所以我制作了这个脚本来检查新名称是否已经存在，如果存在，则在文件名的末尾放置一个数字（将数字加 1 直到没有其他具有该名称的文件）。有关更改内容的说明位于顶部（已注释掉的行）。如果使用 *.* 选项，请勿将批处理文件存储在要重命名文件的同一文件夹中。我希望这有帮助。

@echo off

REM Instructions
REM This script repaces spaces from file names with underscores. 
REM If you want to just remove the spaces uncomment lines 30 and 52 and comment out the lines 29 and 51. 
REM set the following parameters. 
REM pb is the folder containing the files we want to rename (fullpath)
REM tm is a temporary folder that will be created and deleted. Just put a folder that does not exist and is not used by anything else (fullpath).
REM all is the file type you want to raname. E.g. *.* for every file, *.txt for TXTs, *.pdf for PDFs etc 
REM you don't have to change anything else

set pb=<folder containing the files to rename>
set tm=<a temp folder that does not exist>
set all=*.*

set pa=%pb%%all%

setlocal EnableDelayedExpansion

cd /d %pa%

set /a count=1

if not exist %tm% mkdir %tm%

for /f %%F in (%pa%) do (

    set name=%%~nF
    set name2=!name: =_!
    REM set name2=!name: =!
    set name3=!name2!%%~xF

    if !name2! == %%~nF ( 
        move /y %%~dpF\!name3! %tm%\ >nul
    ) else (
            if not exist %%~dpF\!name3! ( 
                if not exist %tm%\!name3! (
                    ren "%%F" "!name3!" 
                    move /y %%~dpF\!name3! %tm%\ >nul
                )
        )   
    ) 

)

:rename

for /f %%F in (%pa%) do (

    set name=%%~nF
    set name2=!name: =_!
    REM set name2=!name: =!
    set name4=!name2!%count%
    set name3=!name4!%%~xF

    if !name2! == %%~nF ( 
        move /y %%~dpF\!name3! %tm%\ >nul
    ) else (
            if not exist %%~dpF\!name3! ( 
                if not exist %tm%\!name3! (
                    ren "%%F" "!name3!" 
                    move /y %%~dpF\!name3! %tm%\ >nul
                )
        )   
    ) 

)

set /a count = %count% + 1

set /a loop = 0

for %%F in (%pa%) do (set /a loop = 1)

if %loop% equ 1 goto rename

move /y %tm%\%all% %pb% >nul

rmdir /s /q %tm%
于 2017-06-13T07:59:23.833 回答
0

由于以编程方式重命名文件是有风险的（如果你弄错了可能会造成破坏），我会使用专门为批量重命名而构建的具有空运行模式的工具，例如renamer。

此命令从当前目录中的所有文件中删除空格：

$ renamer --find "/\s/g" --dry-run *

Dry run

✔︎ file one.mp3 → fileone.mp3
✔︎ file two.mp3 → filetwo.mp3

Rename complete: 2 of 2 files renamed.

这里有更多的重命名器用法示例。

于 2021-05-04T08:28:14.353 回答
0

只需将其复制粘贴到批处理文件并另存为c:\myfolder\r.bat

setlocal EnableDelayedExpansion
@echo off &cls
set p=%*
set p=!p: =!
set p=!p:^(=!
set p=!p:^)=!
set p=!p:^[=!
set p=!p:^]=!
set p=!p:^$=!
set p=!p:^&=!
set p=!p:^@=!
set p=!p:^;=!
set p=!p:^:=!
set p=!p:^,=!
set p=!p:^#=!
set p=!p:^_=!
set p=!p:^-=!
set e=%p:~-4%
ren "%*" %time:~6,2%%time:~9,2%%e%
exit

在以下位置添加注册表

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\*\shell\#myRENAME]
@=""

[HKEY_CLASSES_ROOT\*\shell\#myRENAME\command]
@="c:\myfolder\r.bat \"%1\""

完成，现在选择文件并只需右键单击选择myRENAME 所有文件将立即重命名。

于 2021-11-05T13:37:40.487 回答