batch-file - 如何在批处理/cmd中“注释掉”（添加注释）？

Question

我有一个批处理文件，它运行几个执行表修改的 python 脚本。

我想让用户注释掉他们不想运行的 1-2 个 python 脚本，而不是从批处理文件中删除它们（所以下一个用户知道这些脚本作为选项存在！）
我还想添加注释以特别提醒他们在运行批处理文件之前需要在批处理文件中更新的变量。我看到我可以使用REM. 但它看起来更像是在用户运行后更新用户的进度。

是否有更恰当地添加评论的语法？

score 1102 · Accepted Answer

使用`::`或`REM`

::   commenttttttttttt
REM  commenttttttttttt

但是（正如人们所说）：

::不能内联工作；添加&字符：
your commands here & :: commenttttttttttt
内部嵌套部分（IF/ELSE，FOR循环等...）::应跟在正常行之后，否则会出错（REM在此处使用）。
::也可能在内部失败setlocal ENABLEDELAYEDEXPANSION

score 968 · Accepted Answer

该rem命令确实用于评论。运行脚本后，它本质上不会更新任何人。不过，一些脚本作者可能会以这种方式使用它而不是echo，因为默认情况下，批处理解释器会在处理每个命令之前打印出它。由于rem命令不执行任何操作，因此可以安全地打印它们而不会产生副作用。要避免打印命令，请为其添加前缀@，或者，要在整个程序中应用该设置，请运行@echo off. （这是echo off为了避免打印更多命令；这是为了避免在回显设置生效之前@打印该命令。）

所以，在你的批处理文件中，你可以使用这个：

@echo off
REM To skip the following Python commands, put "REM" before them:
python foo.py
python bar.py

score 54 · Accepted Answer

不，普通的旧批处理文件REM用作注释。 ECHO是在屏幕上打印某些内容的命令。

要“注释掉”文件的部分，您可以使用GOTO. 所有这些命令/技术的示例：

REM it starts here the section below can be safely erased once the file is customised
ECHO Hey you need to edit this file before running it!  Check the instructions inside
ECHO Now press ctrl-c to interrupt execution or enter to continue
PAUSE
REM erase the section above once you have customised the file
python executed1.py
ECHO Skipping some stuff now
GOTO End
python skipped1.py
python skipped2.py
:END
python executed2.py

我能说什么？批处理文件是很久以前的遗物，它们笨重且丑陋。

您可以在此网站上阅读更多内容。

编辑：稍微修改了示例以使其包含您显然正在寻找的元素。

score 34 · Accepted Answer

在计算机不是很快的日子里，最好使用 :: 而不是 REM。REM'ed 行被读取，然后被忽略。::'ed 行一直被忽略。这可以在“过去”加速您的代码。此外，在 REM 之后你需要一个空格，在 :: 你不需要之后。

正如第一条评论中所说：您可以将信息添加到您认为需要的任何行

SET DATETIME=%DTS:~0,8%-%DTS:~8,6% ::Makes YYYYMMDD-HHMMSS

至于跳过部分。将 REM 放在每行前面可能相当耗时。如前所述，使用 GOTO 跳过部分是跳过大段代码的简单方法。请务必在您希望代码继续运行的位置设置 :LABEL。

SOME CODE

GOTO LABEL  ::REM OUT THIS LINE TO EXECUTE THE CODE BETWEEN THIS GOTO AND :LABEL

SOME CODE TO SKIP
.
LAST LINE OF CODE TO SKIP

:LABEL
CODE TO EXECUTE

score 31 · Accepted Answer

多行注释

如果您要注释掉大量行，那么最好进行多行注释而不是注释掉每一行。

请参阅Rob van der Woude 在评论区发表的这篇文章：

批处理语言没有注释块，尽管有一些方法可以实现效果。
GOTO EndComment1
This line is comment.
And so is this line.
And this one...
:EndComment1
您可以使用GOTOLabel 和 :Label 进行块注释。

或者，如果注释块出现在批处理文件的末尾，您可以EXIT在代码末尾写上任意数量的注释以供您理解。
@ECHO OFF
REM Do something
  •
  •
REM End of code; use GOTO:EOF instead of EXIT for Windows NT and later
EXIT

Start of comment block at end of batch file
This line is comment.
And so is this line.
And this one...

score 14 · Accepted Answer

将注释与命令放在同一行：使用`& :: comment`

color C          & :: set red font color
echo IMPORTANT INFORMATION
color            & :: reset the color to default

解释：

&分隔两个命令，所以在这种情况下color C是第一个命令，:: set red font color是第二个。

重要的：

这个带有注释的语句在直觉上看起来是正确的：

goto error1         :: handling the error

但这不是评论的有效使用。它之所以有效，只是因为goto忽略了第一个参数之后的所有参数。证明很简单，这goto也不会失败：

goto error1 handling the error

但类似的尝试

color 17            :: grey on blue

由于命令未知的 4 个参数，执行命令失败color：::, grey, on, blue.

它只能作为：

color 17     &      :: grey on blue

所以&符号是不可避免的。

score 9 · Accepted Answer

::您可以使用or注释掉某些内容REM：

your commands here
:: commenttttttttttt

或者

your commands here
REM  commenttttttttttt

要在与命令相同的行上执行此操作，您必须添加一个 & 符号：

your commands here      & ::  commenttttttttttt

或者

your commands here      & REM  commenttttttttttt

笔记：

:: 在嵌套逻辑（IF-ELSE、FOR循环等）中使用会导致错误。在这些情况下，请REM改用。

score 2 · Accepted Answer

您可以使用以下语法将注释添加到批处理文件的末尾：

@echo off
:: Start of code
...
:: End of code

(I am a comment
So I am!
This can be only at the end of batch files

只要确保你从不使用右括号。

署名：Leo Guttirez Ramirez 在https://www.robvanderwoude.com/comments.php

score 1 · Accepted Answer

这是一个老话题，我想在这里补充一下我的理解，以扩展这个有趣话题的知识。

REM 和 :: 之间的主要区别是：

REM 本身就是一个命令，而 :: 不是。

我们可以将 :: 视为一个标记，一旦 CMD 解析器遇到一行中的第一个非空格是这个 :: 标记，它就会跳过整行并读取下一行。这就是为什么 REM 后面至少应该有一个空格才能作为该行的注释，而 :: 后面不需要任何空格。

REM 本身就是一个命令，可以从下面的FOR语法中得到最好的理解

基本的 FOR 语法如下

FOR %v in (set) DO <Command> [command param]

这里<Command>可以是任何有效的命令所以我们可以编写以下有效的命令行作为rem命令

FOR %i in (1,2,3) DO rem echo %i

但是，我们不能编写以下行，因为::它不是命令

FOR %i in (1,2,3) DO :: echo %i

score 1 · Accepted Answer

您可以使用::或rem进行评论。

评论时，使用::速度快 3 倍。此处显示了一个示例

仅当注释在if, 中时才使用rem，因为冒号可能会出错，因为它们是标签。

score 1 · Accepted Answer

评论一行

对于注释行，使用REM 或 ::虽然:: 可能会在括号内失败

在以开头的延迟扩展行内!<delimiter>将被忽略，因此可用于注释：

@echo off

setlocal enableDelayedExpansion

echo delayed expansion activated
!;delayed expansion commented line
echo end of the demonstration

在行尾注释

对于行尾的注释，您可以再次使用rem并::结合&：

echo --- &:: comment (should not be the last line in the script)
echo --- &rem comment

在文件末尾评论

注意将在exit命令后解析，您可以使用它在文件末尾添加注释：

@echo off

echo commands

exit /b 

-------------------
commnts at the end 
of the file
------------------

内联评论

不存在的变量的扩展被替换为什么都没有，并且由于=很难设置变量，您可以将其用于内联注释：

@echo off

echo long command %= this is a comment =% with an inline comment

多行注释

可以使用多行注释GOTO（用于外括号）和REM条件执行（用于内括号）。更多细节在这里：

@echo off

echo starting script

goto :end_comments
 comented line 
 one more commented line
:end_comments

echo continue with the script

(
    echo demonstration off
    rem/||(
      lines with
      comments
    )
    echo multiline comment inside
    echo brackets
)

使用宏美化了相同的技术：

@echo off

::GOTO comment macro
set "[:=goto :]%%"
::brackets comment macros
set "[=rem/||(" & set "]=)"

::testing
echo not commented 1

%[:%
  multi 
  line
  comment outside of brackets
%:]%

echo not commented 2

%[:%
  second multi 
  line
  comment outside of brackets
%:]%

::GOTO macro cannot be used inside for
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %[%
        multi line
        comment
    %]%
    echo second not commented line of the %%a execution
)

score 1 · Accepted Answer

我更喜欢使用：

REM 征求意见
&REM 用于内联注释

例子：

@echo off
set parameter1=%1%
REM test if the parameter 1 was received
if defined parameter1 echo The parameter 1 is %parameter1% &REM Display the parameter

batch-file - 如何在批处理/cmd中“注释掉”（添加注释）？

12 回答 12

使用::或REM

但是（正如人们所说）：

多行注释

将注释与命令放在同一行：使用& :: comment

重要的：

笔记：

评论一行

在行尾注释

在文件末尾评论

内联评论

多行注释

Related

Reference

使用`::`或`REM`

将注释与命令放在同一行：使用`& :: comment`