sed - 使用 awk sed 进行文件列操作

Question

我有 2 个文件要组合如下。文件1：

AAA 
1234 
BBB
2341

文件2：

AAA
9876
67 89 01
BBB
4567
23 45 23

需要最终文件

AAA 1234 9876 67 89 01
BBB 2341 4567 23 45 23

我如何在 awk 或 sed 或两者中实现这一点？

Answer 1

纯awk：

/^[A-Z]/ {
    token=$1
}
/^[0-9]/{
    for (i=1; i<=NF; i++) {
        C[token]=C[token] " " $i
    }
}
END {
    for (i in C) {
        print i, C[i]
    }
}

输出：

$ awk -f f.awk f1 f2
AAA  1234 9876 67 89 01
BBB  2341 4567 23 45 23

可以缩短为 3 线：

/^[A-Z]/ { token=$1 }
/^[0-9]/ { C[token]=C[token] " " $0 }
END { for (i in C) { print i, C[i] } }

Answer 2

你可以试试这个（也许它是一个大的解决方案，但它有效）：

a.awk：

function print_stuff( start_string, end_string, file2 )
{
    printf "%s ", start_string

    getline 

    while ( $0 != end_string )
    {
        for ( i = 1; i < NF + 1; i++ )
        {
            printf "%s ", $i    
        }

        if ( getline <= 0 )
        {
            break    
        }
    }

    while ( $0 != start_string )
    {
        if ( ( getline < file2 ) <= 0 )
        {
            break    
        }
    }

    getline < file2

    while ( $0 != end_string )
    {
        for ( i = 1; i < NF + 1; i++ )
        {
            printf "%s ", $i    
        }

        if ( ( getline < file2 ) <= 0 )
        {
            break    
        }
    }

    printf "\n"

    close( file2 )
}


BEGIN { file2 = "file2"; aaa = "AAA"; bbb = "BBB" }

aaa { print_stuff( aaa, bbb, file2 ) }
bbb { print_stuff( bbb, "",  file2 ) }

运行：awk -f a.awk file1

输出：

AAA 1234 9876 67 89 01 
BBB 2341 4567 23 45 23

Answer 3

变换.awk

{key=($1 ~/[A-Z]+/)}

key==1 {
if(NR>1) {printf "\n"}
printf "%s",$1}

key==0 {printf " %s",$0}

END {printf "\n"}

这将在不假设固定数量的条目的情况下转换文件，而是将键确认为由第一行中的正则表达式给出的特定模式。在这种情况下，一段大写字母。

join <(awk -F transform.awk file1) <(awk -F transform.awk file2)