2

如何将所有LF字符转换为<br />标签并在 HTML 页面上显示？

我有以下示例 XML 文件：

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="data.xslt"?>
<data>
<lines>
Line 1
Line 2
Line 3
Line 4
Line 5
Line 6
</lines>
</data>

我想在 HTML 页面上显示所有行。为此，我使用以下 XSLT 转换：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" version="1.0" encoding="utf-8" indent="yes"/>
    <xsl:template match="/">
        <html>
            <head>
                <meta http-equiv="Content-Type" content="text/html; charset=utf-8"/>
            </head>
            <body>
                <xsl:variable name="filtered">
                    <xsl:call-template name="replace">
                        <xsl:with-param name="string" select="./data/lines"/>
                        <xsl:with-param name="search" select="'&#xA;'"/>
                        <xsl:with-param name="new"><br /></xsl:with-param>
                    </xsl:call-template>
                </xsl:variable>
                <td align="left">
                    <xsl:value-of select="$filtered" disable-output-escaping="yes"/>
                </td>
            </body>
        </html>
    </xsl:template>
    <xsl:template name="replace">
        <xsl:param name="string"/>
        <xsl:param name="search"/>
        <xsl:param name="new"/>
        <xsl:choose>
            <xsl:when test="contains($string, $search)">
                <xsl:value-of select="substring-before($string, $search)"/>
                <xsl:value-of select="$new"/>
                <xsl:call-template name="replace">
                    <xsl:with-param name="string" select="substring-after($string, $search)"/>
                    <xsl:with-param name="search" select="$search"/>
                    <xsl:with-param name="new" select="$new"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$string"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>


当我在 Firefox 中打开该 XML 文件时（我使用浏览器显示 XSLT 转换），我将看到该结果：

Line 1Line 2Line 3Line 4Line 5Line 6

如您所见，LF字符没有被<br />标签替换。


但是当我使用其他字符串时，例如EOL：

<xsl:with-param name="new">EOL</xsl:with-param>

我会看到预期的结果：

EOLLine 1EOLLine 2EOLLine 3EOLLine 4EOLLine 5EOLLine 6EOL


问题在于转换/显示<br />标签。

4

5 回答 5

3

您可以像使用 一样将节点片段作为参数值传递<xsl:with-param name="new"><br /></xsl:with-param>，但是要将其作为模板中的元素输出，br您需要使用<xsl:copy-of select="$new"/>，而不是xsl:value-of。

[编辑] 这是一个例子：http ://home.arcor.de/martin.honnen/xslt/test2012062801.xml 。样式表位于http://home.arcor.de/martin.honnen/xslt/test2012062801.xsl，我还将在下面包含它：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" version="4.01" encoding="utf-8" indent="yes"/>
    <xsl:template match="/">
        <html>
            <head>
              <title>Example</title>
            </head>
            <body>
                <xsl:variable name="filtered">
                    <xsl:call-template name="replace">
                        <xsl:with-param name="string" select="data/lines"/>
                        <xsl:with-param name="search" select="'&#xA;'"/>
                        <xsl:with-param name="new"><br /></xsl:with-param>
                    </xsl:call-template>
                </xsl:variable>
                <div>
                    <xsl:copy-of select="$filtered"/>
                </div>
            </body>
        </html>
    </xsl:template>
    <xsl:template name="replace">
        <xsl:param name="string"/>
        <xsl:param name="search"/>
        <xsl:param name="new"/>
        <xsl:choose>
            <xsl:when test="contains($string, $search)">
                <xsl:value-of select="substring-before($string, $search)"/>
                <xsl:copy-of select="$new"/>
                <xsl:call-template name="replace">
                    <xsl:with-param name="string" select="substring-after($string, $search)"/>
                    <xsl:with-param name="search" select="$search"/>
                    <xsl:with-param name="new" select="$new"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$string"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>
于 2012-06-27T10:50:45.160 回答
1

您的参数值中有额外的引号。换线试试...

<xsl:with-param name="search" select="'&#xA;'"/>

到...

<xsl:with-param name="search" select="&#xA;"/>

更新

正如 OP 所指出的，上述内容不正确，将导致 XSLT 转换错误。
我相信@banana 的答案是正确的。

于 2012-06-27T09:05:49.850 回答
1

恕我直言，xsl:anaylze-string 非常适合这个问题。这个 XSLT 2.0 样式表在 Saxon 下运行...

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:so="http://stackoverflow.com/questions/11222334"
  xmlns:x="http://www.w3.org/1999/xhtml"
  xmlns="http://www.w3.org/1999/xhtml"
  exclude-result-prefixes="xsl fn xs so x">

<xsl:output method="xhtml" encoding="utf-8" indent="yes"
            doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"
            doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN"
            omit-xml-declaration="yes" />

<xsl:template match="/">
 <html>
  <head><meta http-equiv="Content-Type" content="text/html; charset=utf-8"/></head>
  <body>
   <xsl:apply-templates select="data/lines"/>
  </body>
 </html> 
</xsl:template>

<xsl:template match="lines">
    <xsl:analyze-string select="." regex="\n">
        <xsl:matching-substring>
          <br />
          <xsl:value-of select="'&#x0A;'" />
        </xsl:matching-substring>
        <xsl:non-matching-substring>
          <xsl:value-of select="."/>
        </xsl:non-matching-substring>
      </xsl:analyze-string>
</xsl:template>

</xsl:stylesheet>

...应用于此输入文档时...

<?xml version="1.0" encoding="utf-8"?>
<data>
<lines>
Line 1
Line 2
Line 3
Line 4
Line 5
Line 6
</lines>
</data>

...将产生这个html页面...

<!DOCTYPE html
  PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
   <head>
      <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
   </head>
   <body><br />
      Line 1<br />
      Line 2<br />
      Line 3<br />
      Line 4<br />
      Line 5<br />
      Line 6<br />

   </body>
</html>
于 2012-06-27T10:05:44.663 回答
0

尝试替换：

<xsl:with-param name="new"><br /></xsl:with-param>

和：

<xsl:with-param name="new">&lt;br /&gt;</xsl:with-param>
于 2012-06-27T09:11:30.357 回答
0

这将写入当前节点值替换 \n 与 <br/>

<xsl:value-of select="replace(., '\n', '&lt;br/&gt;')"/>
于 2012-06-27T09:14:34.430 回答