1

我无法在 SmallTalk 中获取消息的发件人。我想要完成的是从第一个方法（A）调用的另一个方法（B）修改方法（A）的返回值。再次... A 调用 B，我希望 B 从 A 的上下文中返回一个值。

示例代码：

这将是 A：

A

| aResult aPartialResult |

aPartialResult := self B.

"do things with aPartialResult"

^aResult.

这将是 B：

B

| aResult |

[ aResult := "do something" ]
                        on: Exception
                        do: ["make A return something"].
^aResult.

问题是我希望 B 中可能引发的异常也可以在 B 中处理。这就是为什么我不只是在 B 中引发异常以在 A 中处理它并轻松地从那里返回。

我以为我可以使用 thisContext 来做到这一点，但发件人是零。得到一个关于为什么会这样的答案也没有什么坏处......

提前致谢！

4

4 回答 4

3

Guillermo，异常处理可以无缝地替换这里的一些坏主意：

  1. 使用 thisContext （这几乎没有必要，通常是个坏主意）
  2. 传递字符串，例如 '1|'、UserInterface invalidCartIdErrorMessage
  3. 使用 return: 与这些字符串一起传递错误

此外，retrieveCart:onErrorReturnFrom: 做得太多了。使用所有错误处理程序，实际的逻辑会丢失。

所以，我要做的第一件事是创建 Error 子类来表示您的域概念，例如 AddBookError、CartExpiredError、InvalidCartError

然后你只需设置错误消息，可能像：

CartExpiredError>>initialize

    super initialize.
    self messageText: '1|', UserInterface cartHasExpiredErrorMessage.

接下来的事情（实际上是两个步骤）是用私有访问器替换原始字典方法，它可以使用您的新错误类，如下所示：

timestampFor: aCartId

    ^ cartCreationDateAndTime at: aCartId ifAbsent: [ InvalidCartError signal ].

和

cartNumber: aCartId 

     ^ carts at: aCartId ifAbsent: [ InvalidCartError signal ].

Cart>>add: aQuantity booksWithISBN: aBookISBN

    fail ifTrue: [ AddBookError signal ].

现在，retrieveCart:onErrorReturnFrom: 可以变成：

retrieveCart: aCartId

    | aCartCreationDateAndTime |
    aCartCreationDateAndTime := self timestampFor: aCartId.
    Time now > (aCartCreationDateAndTime + 30 minutes) ifTrue:  [ CartExpiredError signal ].
    ^ self cartNumber: aCartId.

最后，大大简化的 A 变为：

add: aQuantity booksWithISBN: aBookISBN toCart: aCartId

     | aCart |
    [aCart := self retrieveCart: aCartId.
    aCart add: aQuantity booksWithISBN: aBookISBN]
        on: Error
        do: [ :e |  ^ e messageText ].
    ^ '0|OK'.

这仍然可以被清除（例如，为所有在 messageText 前面加上 '1|' 的错误类创建一个超类），显然你必须将这个简化版本应用到你的实际项目中，但是你可以开始看看异常是如何发生的吗？让你的生活更轻松？

这是代码的工作模型，在 github 上通过了测试

nb 我注意到的另一件事是aCartCreationDateAndTime。将其作为购物车的属性似乎更自然，但在实际应用中这可能没有意义......

于 2012-06-27T16:44:02.020 回答
1

一种简单的方法是 A 将一个带有内部返回的 Block 传递给 B，例如：

A
   | aResult aPartialResult |
   aPartialResult := self BonSpecialConditionDo: [:partial | ^partial].
   ...snip...

然后

BonSpecialConditionDo: aBlock
    | partialResult |
    partialResult := self doSomethingPartial.
    ^[self doSomething]
        on: SomeException
        do: [:exc | aBlock value: partialResult]

当心，捕捉异常被认为是危险的（你捕捉到太多东西）。

编辑：我刚刚在处理程序中删除了一个不必要的 return ^

编辑：用超能力做（但不要用锤子杀死苍蝇）

B
    | partialResult |
    partialResult := self doSomethingPartial.
    ^[self doSomething]
        on: SomeException
        do: [:exc | thisContext home sender home return: partialResult ]

我以为您可以通过 Exception exc 访问 thisContext（这是实例变量 handlerContext），但是似乎没有任何方便的消息可以访问此内部状态...

于 2012-06-27T10:15:47.073 回答
0

知道了！

这是一个：

A

| aResult aPartialResult |

aPartialResult := self BOnErrorReturnFrom: thisContext.

"do things with aPartialResult"

^aResult.

这将是 B：

BOnErrorReturnFrom: aContext

| aResult |

[ aResult := "do something" ]
                        on: Exception
                        do: [aContext return: "whatever you want :)"].
^aResult.

当我意识到关键字“thisContext”在 BlockClosure 中使用时，它不会返回声明块的 ContextPart，而是返回其他内容（但仍然不确定它是什么），这并不难。

回应肖恩：

我试图做的是避免重复代码。实现 A 和 B 的对象是 REST 接口的内部（模型端）部分，所以我希望它返回一个字符串并且只返回一个字符串（我不希望异常或与字符串对象不同的任何东西通过） . 在我的具体问题中，A（很抱歉打破了 Smalltalk 消息命名约定，但我认为现在更改它会导致进一步的混乱......）收到一个购物车 ID，并将对该购物车做一些事情。A 必须使用该 ID 检索购物车，对购物车进行一些验证，并在出现错误时返回临时消息（始终作为字符串）。此检索和验证代码将在必须检索购物车的每条消息中重复。

这是我最终得到的正确代码：

这是A：（不要注意#try 消息。它只是确保在没有被转换为字符串的情况下不会出现异常。如果有人知道如何以更好的方式做到这一点，请告诉我如何！）

add: aQuantity booksWithISBN: aBookISBN toCart: aCartId

    | aCart aContext |

    aContext := thisContext.

    ^self try: [

        aCart := self retrieveCart: aCartId onErrorReturnFrom: aContext.

        [aCart add: aQuantity booksWithISBN: aBookISBN]
                                                    on: Error
                                                    do: [ :anError | ^'1|', (self formatAsResponse: anError messageText) ].

        ^'0|OK'.
    ].

这是乙：

retrieveCart: aCartId onErrorReturnFrom: aContext

    | aCartCreationDateAndTime aCart |

    [aCartCreationDateAndTime := cartCreationDateAndTime at: aCartId asInteger.]
                                                                                    on: KeyNotFound 
                                                                                    do: [ aContext return: ('1|', (UserInterface invalidCartIdErrorMessage)).].

    (systemClock now > (aCartCreationDateAndTime + 30 minutes)) 
                                                            ifTrue:  [aContext return: ('1|', (UserInterface cartHasExpiredErrorMessage))].

    [aCart := carts at: aCartId asInteger.]
                                    on: KeyNotFound
                                    do: [ aContext return: ('1|', (UserInterface invalidCartIdErrorMessage))].

    ^aCart.
于 2012-06-27T14:28:40.537 回答
0

一个

| aResult aPartialResult |

aPartialResult := 自我 B.

“用部分结果做事”

^a结果。

乙

| 结果 |

[ aResult := "do something" ] on: Exception do: ["make A return something"]。^a结果。

我会把它写成

一个

| aResult aPartialResult |

aPartialResult := 自我 B. aPartialResult ifNotNil:[

“用 aPartialResult 做事”]。

^a结果。

乙

| 结果 |

[ aResult := "do something" ] on: 例外 do: [:e|^nil]。^a结果。

好吧，那就是我！！！

于 2012-06-27T19:56:02.013 回答