5

我想知道是否可以在 Apache Pig 中一次性旋转表格。

输入：

Id    Column1 Column2 Column3
1      Row11    Row12   Row13
2      Row21    Row22   Row23

输出：

Id    Name     Value
1     Column1  Row11
1     Column2  Row12
1     Column3  Row13
2     Column1  Row21
2     Column2  Row22
2     Column3  Row23

真实数据有几十列。

我可以用 awk 一次性完成，然后用 Hadoop Streaming 运行它。但是我的大部分代码是 Apache Pig，所以我想知道是否可以在 Pig 中有效地完成它。

4

2 回答 2

7

您可以通过两种方式做到这一点： 1. 编写一个返回一袋元组的 UDF。这将是最灵活的解决方案，但需要 Java 代码；2. 像这样写一个死板的脚本：

inpt = load '/pig_fun/input/pivot.txt' as (Id, Column1, Column2, Column3);
bagged = foreach inpt generate Id, TOBAG(TOTUPLE('Column1', Column1), TOTUPLE('Column2', Column2), TOTUPLE('Column3', Column3)) as toPivot;
pivoted_1 = foreach bagged generate Id, FLATTEN(toPivot) as t_value;
pivoted = foreach pivoted_1 generate Id, FLATTEN(t_value);
dump pivoted;

运行这个脚本让我得到以下结果：

(1,Column1,11)
(1,Column2,12)
(1,Column3,13)
(2,Column1,21)
(2,Column2,22)
(2,Column3,23)
(3,Column1,31)
(3,Column2,32)
(3,Column3,33)
于 2012-06-27T14:27:59.480 回答
3

我从 id 1 中删除 col3 以显示如何处理可选（NULL）数据

Id 名称 值 1 Column1 Row11 1 Column2 Row12 2 Column1 Row21 2 Column2 Row22 2 Column3 Row23

--pigscript.pig

data1       = load 'data.txt' using PigStorage() as (id:int, key:chararray, value:chararray);
grped       = group data1 by id;
pvt         = foreach grped {
    col1        = filter data1 by key =='Column1';
    col2        =filter data1  by key =='Column2';
    col3        =filter data1  by key =='Column3';
    generate flatten(group) as id,
        flatten(col1.value) as col1, 
        flatten(col2.value) as col2, 
        flatten((IsEmpty(col3.value) ? {('NULL')} : col3.value)) as col3; --HANDLE NULL
};
dump pvt;

结果：

(1,Row11,Row12,NULL)

(2,Row21,Row22,Row23)

于 2012-12-06T20:40:38.237 回答