2

我希望我不会因为提到 Filemaker 而失去任何人。我正在尝试将它的 XML 导出转换为 SSIS 可用的东西。FM 的原生 XML 导出在同一 XML 文件的不同部分中具有字段名称和数据。这列出了我需要它做什么，我目前做了什么，以及底部的原始 FM 导出以供参考。今天早上之前我还没有看到过 XML 翻译，所以请耐心等待：D。我可以根据需要发布更多信息。

<!-- What we actually want example -->
<?xml version="1.0" encoding="UTF-8"?>

<PRODUCTRECS>
<PRODUCT>
    <name>Dr. Zim</name>
    <address>1234 Internet Way</address>
    <city/><state/><zip/>
</PRODUCT>
...
</PRODUCTRECS>

XSLt 有没有办法在我们翻译时读取顶部的字段名称并将字段名称放在实际数据周围？目前，我只是用这样的 IF 语句来选择位置（它有效，但非常依赖和混乱）：

<!-- Current nightmare code, check for each individually and print it out -->
<xsl:template match="fmp:FMPXMLRESULT">
<PRODUCTRECS>
<xsl:for-each select="fmp:RESULTSET/fmp:ROW">
    <PRODUCT>
<xsl:for-each select="fmp:COL">
<xsl:if test="position()=1">
    <name><xsl:value-of select="fmp:DATA"/></name>
</xsl:if>
...
</xsl:for-each>
    </PRODUCT>
</xsl:for-each>
</PRODUCTRECS>
</xsl:template>

这是 Filemaker 默认输出的内容：

<?xml version="1.0" encoding="UTF-8" ?>
<FMPXMLRESULT xmlns="http://www.filemaker.com/fmpxmlresult">
<ERRORCODE>0</ERRORCODE>
<PRODUCT BUILD="01-01-2009" NAME="FileMaker Pro" VERSION="10.0v3"/>
<DATABASE DATEFORMAT="M/d/yyyy" LAYOUT="" NAME="filename.fp7" RECORDS="10" TIMEFORMAT="h:mm:ss a"/>
<METADATA>
  <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="name" TYPE="TEXT"/>
  <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="address" TYPE="TEXT"/>
  <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="city" TYPE="TEXT"/>
  <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="state" TYPE="TEXT"/>
  <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="zip" TYPE="TEXT"/>
</METADATA>
<RESULTSET FOUND="10">
<ROW MODID="0" RECORDID="1">
  <COL><DATA>Dr. Zim</DATA></COL>
  <COL><DATA>1234 Internet Way</DATA></COL>
  <COL><DATA></DATA></COL>
  <COL><DATA></DATA></COL>
  <COL><DATA></DATA></COL>
  ...
</ROW>
...
</RESULTSET>
</FMPXMLRESULT>

期待那里的大师 XSLTers。:) 我遇到的另一个问题是，当原件以 9.99 美元的货币存储为 XML 中的文本 (00009.99000000) 时，如何格式化数字价格，但我可以处理这个问题。

4

3 回答 3

6

解决此问题的一种优雅方法是：

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fmp="http://www.filemaker.com/fmpxmlresult"
  exclude-result-prefixes="fmp"
>

  <!-- the key indexes the METADATA fields by their position -->
  <xsl:key 
    name="kMetaData" 
    match="fmp:METADATA/fmp:FIELD" 
    use="count(preceding-sibling::fmp:FIELD) + 1" 
  />

  <!-- separate templates increase readability -->
  <xsl:template match="/fmp:FMPXMLRESULT">
    <PRODUCTRECS>
      <xsl:apply-templates select="fmp:RESULTSET/fmp:ROW" />
    </PRODUCTRECS>
  </xsl:template>

  <xsl:template match="fmp:ROW">
    <PRODUCT>
      <xsl:apply-templates select="fmp:COL" />
    </PRODUCT>
  </xsl:template>

  <xsl:template match="fmp:COL">
    <!-- column name lookup is high-speed because of the key -->
    <xsl:element name="{string(key('kMetaData', position())/@NAME)}">
      <xsl:value-of select="fmp:DATA" />
    </xsl:element>
  </xsl:template>

</xsl:stylesheet>

我的系统上的哪些输出：

<PRODUCTRECS>
  <PRODUCT>
    <name>Dr. Zim</name>
    <address>1234 Internet Way</address>
    <city></city>
    <state></state>
    <zip></zip>
  </PRODUCT>
</PRODUCTRECS>

但是，请注意，XML 元素名称比 FileMaker 列名称要遵守更严格的规则。如果您的列名违反这些规则，上述内容将崩溃并烧毁。

样式表的显着特点是：

  • 用于<xsl:key>快速查找节点 - 对于较大的输入，这应该变得明显
  • exclude-result-prefixes防止fmp在结果中声明命名空间
  • <xsl:element>创建具有动态名称的元素
  • 使用preceding-siblingXPath 轴作为确定节点位置的一种方式（因为该函数在sposition()中不起作用<xsl:key>

继续询问是否有任何不清楚的地方。

您的其他问题（数字格式）在这里有答案： XSL: Formatting numbers, exclude trailing zeros。

于 2009-07-13T18:43:12.473 回答
1

您可以跳回根目录，使用/ ie开始 xpath 查询/fmp:FMPXMLRESULT/fmp:METADATA/fmp:FIELD

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
        xmlns:fmp="http://www.filemaker.com/fmpxmlresult"
    >
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/fmp:FMPXMLRESULT">
        <PRODUCTRECS>
            <xsl:apply-templates select="fmp:RESULTSET/fmp:ROW" />
        </PRODUCTRECS>
    </xsl:template>

    <xsl:template match="fmp:RESULTSET/fmp:ROW">
        <PRODUCT>
            <xsl:apply-templates select="fmp:COL" />
        </PRODUCT>
    </xsl:template>

    <xsl:template match="fmp:COL">
        <xsl:variable name="currentPosition" select="position()" />
        <xsl:element name="{/fmp:FMPXMLRESULT/fmp:METADATA/fmp:FIELD[position() = $currentPosition]/@NAME}">
            <xsl:value-of select="fmp:DATA"/>
        </xsl:element>
    </xsl:template>


</xsl:stylesheet>
于 2009-07-13T18:27:39.353 回答
1

这应该让你开始：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:fm="http://www.filemaker.com/fmpxmlresult">
    <xsl:template match="/fm:FMPXMLRESULT">
        <PRODUCTRECS>
            <xsl:apply-templates select="fm:RESULTSET/fm:ROW"/>
        </PRODUCTRECS>
    </xsl:template>

    <xsl:template match="fm:ROW">
        <PRODUCT>
        <!--
            Use this if the element containing the NAME="FileMaker Pro" attribute is the one you want to use
            for each row name.
            <xsl:element name="{name(/fm:FMPXMLRESULT/*[@NAME='FileMaker Pro'])}">-->
            <xsl:for-each select="fm:COL/fm:DATA">
                <xsl:variable name="currentPos" select="position()"/>
                <xsl:element name="{/fm:FMPXMLRESULT/fm:METADATA/fm:FIELD[position()=$currentPos]/@NAME}">
                    <xsl:value-of select="."/>
                </xsl:element>
            </xsl:for-each>
        <!--</xsl:element>-->
        </PRODUCT>
    </xsl:template>
</xsl:stylesheet>

另外，请查看xsl:number的另一部分或可能只是number() 函数。

于 2009-07-13T18:34:07.653 回答