我想将 Windows 批处理文件中的日期设置为从今天起 7 天前。我想按以下格式执行此操作。
set today=%date:~10,4%-%date:~4,2%-%date:~-7,2%
有什么想法可以在这里减去 7 天的时间增量吗？
问问题
27387 次
6 回答
19
我前段时间在某个网站上发布了以下描述：
以下批处理文件将日期转换为儒略日数，反之亦然：
DATETOJULIAN.BAT：
@ECHO OFF
REM CONVERT DATE TO JULIAN DAY NUMBER
REM ANTONIO PEREZ AYALA
REM GET MONTH, DAY, YEAR VALUES
FOR /F "TOKENS=1-3 DELIMS=/" %%A IN ("%1") DO SET MM=%%A& SET DD=%%B& SET YY=%%C
REM ELIMINATE LEFT ZEROS
SET /A DD=10%DD% %% 100, MM=10%MM% %% 100
REM CALCULATE JULIAN DAY NUMBER
IF %MM% LSS 3 SET /A MM+=12, YY-=1
SET /A A=YY/100, B=A/4, C=2-A+B, E=36525*(YY+4716)/100, F=306*(MM+1)/10, JDN=C+DD+E+F-1524
朱利安托日期.BAT：
REM CONVERT JULIAN DAY NUMBER TO MONTH, DAY, YEAR
REM ANTONIO PEREZ AYALA
SET /A W=(%1*100-186721625)/3652425, X=W/4, A=%1+1+W-X, B=A+1524, C=(B*100-12210)/36525, D=36525*C/100, E=(B-D)*10000/306001, F=306001*E/10000, DD=B-D-F, MM=E-1, YY=C-4716
IF %MM% GTR 12 SET /A MM-=12, YY+=1
REM INSERT LEFT ZEROS, IF NEEDED
IF %DD% LSS 10 SET DD=0%DD%
IF %MM% LSS 10 SET MM=0%MM%
REM SHOW THE DATE
ECHO %MM%/%DD%/%YY%
这样，要在日期中添加/减去天数，请使用以下行：
CALL DATETOJULIAN %DATE%
SET /A NEWDATE=JDN+DAYS
CALL JULIANTODATE %NEWDATE%
问候...
参考：http: //quasar.as.utexas.edu/BillInfo/JulianDatesG.html
如果不是 MM/DD/YYYY，您只需调整日期格式。
于 2012-06-26T17:52:09.713 回答
0
AdamEstrada 询问有关减去日期的问题。由于 Julian 函数中的 SETLOCAL，我很难减去两个 Julian 日期。我通过调用一个函数来做到这一点。
呼叫：sub_Julian ！朱利安！%今天_朱利安%
:sub_Julians
设置 /a delta_dates=%~1-%~2
...
goto:eof ::end:age_of_EPSdate
于 2014-07-01T23:42:05.353 回答
0
我从http://www.robvanderwoude.com/datetimentmath.php稍微重构了JDateand子程序的代码。GDate
使用示例：
Enter ISO date:
Enter number of days to add: 7
2017-01-01 + 7 days = 2017-01-08
Enter ISO date:
Enter number of days to add:
2017-01-08 + 7 days = 2017-01-15
Enter ISO date:
Enter number of days to add:
2017-01-15 + 7 days = 2017-01-22
Enter ISO date:
Enter number of days to add:
2017-01-22 + 7 days = 2017-01-29
Enter ISO date:
Enter number of days to add:
2017-01-29 + 7 days = 2017-02-05
Enter ISO date: 2017-02-12
Enter number of days to add: -7
2017-02-12 + -7 days = 2017-02-05
代码：
“日期数学.bat”：
@echo off
call :main %*
goto :eof
:main
setlocal
call :initialize "2017-01-01" "1"
endlocal
goto :eof
:initialize
setlocal
set "previousDate=%~1"
set /a "numberOfDays=%~2"
set /p "previousDate=Enter ISO date: "
set /p "numberOfDays=Enter number of days to add: "
set "currentDate="
call :addIsoDateDays "%previousDate%" "%numberOfDays%" currentDate
echo %previousDate% + %numberOfDays% days = %currentDate%
echo.
call :initialize "%currentDate%" "%numberOfDays%"
endlocal
goto :eof
:stripLeadingZero
setlocal
set "number=%~1"
if %number:~0,1% equ 0 (
set "number=%number:~1%"
)
(
endlocal
set "%~2=%number%"
)
goto :eof
:addLeadingZero
setlocal
set "number=%~1"
if %number% lss 10 (
set "number=0%number%"
)
(
endlocal
set "%~2=%number%"
)
goto :eof
:gregorianToJulianDate
setlocal
set "gregorianYear=%~1"
set "gregorianMonth=%~2"
set "gregorianDay=%~3"
call :stripLeadingZero "%gregorianMonth%" gregorianMonth
call :stripLeadingZero "%gregorianDay%" gregorianDay
set /a "julianYear=(%gregorianYear% + 4800)"
set /a "julianMonth=((%gregorianMonth% - 14) / 12)"
set /a "julianDate=((1461 * (%julianYear% + %julianMonth%) / 4) + (367 * (%gregorianMonth% - 2 - (12 * %julianMonth%)) / 12) - ((3 * ((%julianYear% + %julianMonth% + 100) / 100)) / 4) + (%gregorianDay% - 32075))"
(
endlocal
set "%~4=%julianDate%"
)
goto :eof
:isoToJulianDate
setlocal
set "date=%~1"
set "year="
set "month="
set "day="
for /f "tokens=1-3 delims=-" %%a in ("%date%") do (
set "year=%%a"
set "month=%%b"
set "day=%%c"
)
set /a "julianDate=0"
call :gregorianToJulianDate "%year%" "%month%" "%day%" julianDate
(
endlocal
set "%~2=%julianDate%"
)
goto :eof
:julianToGregorianDate
setlocal
set /a "julianDate=%~1"
set /a "p=(%julianDate% + 68569)"
set /a "q=(4 * %p% / 146097)"
set /a "r=(%p% - ((146097 * %q%) + 3) / 4)"
set /a "s=(4000 * (%r% + 1) / 1461001)"
set /a "t=(%r% - ((1461 * %s%) / 4) + 31)"
set /a "u=(80 * %t% / 2447)"
set /a "v=(%u% / 11)"
set /a "gregorianYear=((100 * (%q% - 49)) + %s% + %v%)"
set /a "gregorianMonth=(%u% + 2 - (12 * %v%))"
set /a "gregorianDay=(%t% - (2447 * %u% / 80))"
call :addLeadingZero "%gregorianMonth%" gregorianMonth
call :addLeadingZero "%gregorianDay%" gregorianDay
(
endlocal
set "%~2=%gregorianYear%"
set "%~3=%gregorianMonth%"
set "%~4=%gregorianDay%"
)
goto :eof
:julianToIsoDate
setlocal
set /a "julianDate=%~1"
set "year="
set "month="
set "day="
call :julianToGregorianDate "%julianDate%" year month day
set "isoDate=%year%-%month%-%day%"
(
endlocal
set "%~2=%isoDate%"
)
goto :eof
:addIsoDateDays
setlocal
set "previousIsoDate=%~1"
set /a "numberOfDays=%~2"
set /a "previousJulianDate=0"
call :isoToJulianDate "%previousIsoDate%" previousJulianDate
set /a "currentJulianDate=(%previousJulianDate% + %numberOfDays%)"
set "currentIsoDate="
call :julianToIsoDate "%currentJulianDate%" currentIsoDate
(
endlocal
set "%~3=%currentIsoDate%"
)
goto :eof
于 2017-02-13T03:30:35.333 回答
0
调用powershell有一个答案。虽然仍然有机器在没有安装 powershell 的情况下运行（在撰写本文时，XP、Vista、Windows7、Windows2003 和 Windows2008 仍然有下降的操作系统份额，并且没有安装 powershell）
其他选项将在 bat 脚本中使用 jscript
这是dayAdder.bat只接受一个参数的 - 您要添加到当前日期并打印结果的天数：
@if (@X) == (@Y) @end /* JScript comment
@echo off
cscript //E:JScript //nologo "%~f0" %*
exit /b %errorlevel%
@if (@X)==(@Y) @end JScript comment */
var days=parseInt(WScript.Arguments.Item(0));
Date.prototype.addDays = function(days) {
var date = new Date(this.valueOf());
date.setDate(date.getDate() + days);
return date;
}
var date = new Date();
WScript.Echo(date.addDays(5));
WScript.Echo("Year: " + date.getFullYear());
WScript.Echo("Month: " + date.getMonth());
WScript.Echo("DayOfTeWEek: " + date.getDay());
用法和输出：
E:\scripts>call dayAdder.bat 7
Sun Nov 8 16:27:48 UTC+0200 2020
Year: 2020
Month: 10
DayOfTeWEek: 2
DayOfTheMonth: 3
您可以以适合您的方式对其进行修改。
于 2020-11-04T10:01:24.623 回答
0
好的，我需要一个批处理文件来显示 DoD 运营中心的当前 JDAY。您可以双击该文件，它将显示在 CMD 窗口中。然后，按任意键退出。
这是我想出的：
@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"
:: Call the day ordinal number subroutine
call :JDdayNumber %DD% %MM% %YYYY% DayOrdinalNumber
:: Display the result
echo.
echo Today is JDay %DayOrdinalNumber%
echo.
pause,
endlocal & goto :EOF
:: set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%"
:: set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
:: echo datestamp: "%datestamp%"
:: echo timestamp: "%timestamp%"
:: echo fullstamp: "%fullstamp%"
:: ============================================================
:: Subroutine: Calculate a day's ordinal number within the year
::JDdayNumber day month year return_
setlocal enableextensions enabledelayedexpansion
if %2 LEQ 2 (
set /a f=%1-1+31*^(%2-1^)
) else (
set /a a=%3
set /a b=!a!/4-!a!/100+!a!/400
set /a c=^(!a!-1^)/4-^(!a!-1^)/100+^(!a!-1^)/400
set /a s=!b!-!c!
set /a f=%1+^(153*^(%2-3^)+2^)/5+58+!s!
)
set /a return_=%f%+1
endlocal & set "%4=%return_%" & goto :EOF
于 2016-03-31T17:32:37.453 回答
-1
一个更简单的选择是从批处理脚本中调用 PowerShell 命令来操作日期。批处理脚本可以用一行将日期设置为过去 7 天。
powershell -command "((Get-date).AddDays(-7)).ToString('yyyy-MM-dd')">captureVar && set /p Today=<captureVar
该行首先指示 cmd 行对双引号中包含的命令使用 PowerShell。
powershell -command "the powershell command(s)"
接下来，它使用 PowerShell cmdlet Get-Date，并使用AddDays更改当前值的日期。负数将减去，正数将相加。默认格式看起来像
Friday, December 20, 2019 6:18:29 PM
要更改格式，您必须将日期更改为带有格式说明的字符串
.ToString('dddd MM/dd/yyyy HH:mm:ss.ffff K')
PowerShell 命令的输出被重定向到名为 captureVar 的文件中。另一种选择是让 PowerShell 将其写入文件。
powershell -command "((Get-date).AddDays(-7)).ToString('yyyy-MM-dd') | set-content 'captureVar'" && set /p Today=<captureVar
我用 && 使它成为一个单衬里。但是您可以在将值写入文件后随时设置 var。
set /p Today=<captureVar
您应该使用您最熟悉的任何脚本语言编写。但请记住，您在编写批处理脚本时的选择不仅仅是批处理命令。Windows 使得在批处理脚本中随时调用 PowerShell 命令变得非常容易。您通常可以使用 PowerShell 找到给定障碍的简单解决方案，将该命令插入到您的脚本中，然后像往常一样继续完成您的批处理脚本。
在批处理脚本中调用 PowerShell 时需要记住以下几点：
Batch 将双引号中的所有内容视为 PowerShell 命令。如果您发现使用 PowerShell 编写的解决方案在命令中使用双引号，则必须用单引号替换这些解决方案。要转义字符，请遵循批处理脚本规则。可以在 PowerShell 命令中以与批处理 (%var%) 相同的方式读取批处理变量。但是必须重定向在 PowerShell 中创建的值，以便稍后在批处理脚本中使用。一旦结束引号关闭 PowerShell 会话，在 PowerShell 命令中创建的任何 $var 都会丢失。
于 2019-12-28T00:39:09.980 回答