0

我在块中获得了我需要的 xml 元素。但同时，我也放置了块来捕获其他 xml 元素。但这对我不起作用......

这是 XML 文档

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<w:document xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main">
<w:body>
    <w:p>
        <w:pPr>
        </w:pPr>
        <w:r>
            <w:t>Text1-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
            <w:pStyle w:val="Heading1" /> 
        </w:pPr>
        <w:r>
            <w:t>Text2-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
        </w:pPr>
        <w:r>
            <w:t>Text3-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
        </w:pPr>
        <w:r>
            <w:t>Text4-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
            <w:pStyle w:val="Heading1" /> 
        </w:pPr>
        <w:r>
            <w:t>Text5-</w:t>
        </w:r>  
    </w:p>

</w:body>
</w:document>

这是 XSLT 文件

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main"
 exclude-result-prefixes="w">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/">
    <Document>

      <xsl:variable name="headingName" select="(//w:body/w:p/w:pPr/w:pStyle[starts-with(@w:val, 'Heading')])[1]/@w:val"/>
      <xsl:variable name="topLevelHeadings" select = "//w:body/w:p[w:pPr/w:pStyle/@w:val = $headingName]"/>

      <xsl:choose>

        <xsl:when test="$topLevelHeadings">
          <Heading>
          <xsl:apply-templates select="$topLevelHeadings">
          </xsl:apply-templates>
          </Heading>
        </xsl:when>

        <xsl:otherwise>
             <xsl:apply-templates select="w:p">
             </xsl:apply-templates>
        </xsl:otherwise>

      </xsl:choose>   

    </Document>
  </xsl:template>  

  <xsl:template match="w:p">
    <Paragraph>
      <xsl:apply-templates />
    </Paragraph>
  </xsl:template>

  <xsl:template match="w:r/w:t">
    <xsl:value-of select="." />
  </xsl:template>

</xsl:stylesheet>

我生成的输出是：

<Document>
  <Heading>
  <Paragraph>Text2-</Paragraph> 
  <Paragraph>Text5-</Paragraph> 
  </Heading>
</Document>

但我需要的输出是：

<Document>
      <Paragraph>Text1-</Paragraph> 
      <Heading>
           <Paragraph>Text2-</Paragraph> 
      </Heading>
      <Paragraph>Text3-</Paragraph> 
      <Paragraph>Text4-</Paragraph> 
      <Heading>
           <Paragraph>Text5-</Paragraph> 
      </Heading>
</Document>

我想，我对 Block 有一些问题。所以，请指导我摆脱这个问题......

4

2 回答 2

2

您的xsl:choose问题在于它只使用一次，并且仅检查是否至少有一个带有标题的w:p元素。因此，您只会得到一个标题元素输出。为了你xsl:choose工作，你真的需要在w:p模板中使用它

<xsl:template match="w:p">
   <xsl:choose>
      <xsl:when test="w:pPr/w:pStyle[starts-with(@w:val, 'Heading')]">
         <Heading>
            <Paragraph>
               <xsl:apply-templates/>
            </Paragraph>
         </Heading>
      </xsl:when>
      <xsl:otherwise>
         <Paragraph>
            <xsl:apply-templates/>
         </Paragraph>
      </xsl:otherwise>
   </xsl:choose>
</xsl:template>

但是，您在这里并不需要xsl:choose。您可能只需要一个特定的模板来匹配具有匹配w:pPr元素的w:p元素就可以逃脱

<xsl:template match="w:p[w:pPr/w:pStyle[starts-with(@w:val, 'Heading')]]">

然后，您可以在此模板中输出标题元素。然后，您将有一个单独的模板来匹配所有其他w:p元素以输出段落，如果您给它一个名称，您也可以从以前的模板中调用它来共享代码

<xsl:template match="w:p" name="para">

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main" exclude-result-prefixes="w">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
      <Document>
         <xsl:apply-templates/>
      </Document>
   </xsl:template>

   <xsl:template match="w:p[w:pPr/w:pStyle[starts-with(@w:val, 'Heading')]]">
      <Heading>
         <xsl:call-template name="para"/>
      </Heading>
   </xsl:template>

   <xsl:template match="w:p" name="para">
      <Paragraph>
         <xsl:apply-templates/>
      </Paragraph>
   </xsl:template>

   <xsl:template match="w:r/w:t">
      <xsl:value-of select="."/>
   </xsl:template>
</xsl:stylesheet>

当应用于您的输入 XML 时，将输出以下内容

<Document>
   <Paragraph>Text1-</Paragraph>
   <Heading>
      <Paragraph>Text2-</Paragraph>
   </Heading>
   <Paragraph>Text3-</Paragraph>
   <Paragraph>Text4-</Paragraph>
   <Heading>
      <Paragraph>Text5-</Paragraph>
   </Heading>
</Document>

实际上，最终的模板<xsl:template match="w:r/w:t">并不是必需的，因为当 XSLT 匹配一个没有特定模板的元素时，它的默认行为是无论如何都输出文本。

于 2012-06-22T06:36:19.573 回答
0

作为错误的一个非常简单的说明，您的 xsl:otherwise 块确实<xsl:apply-templates select="w:p">. 当时的上下文节点是根节点（/），所以这是处理作为根节点子节点的 w:p 元素，并且没有这样的元素，所以它什么也不做。

您在这里处理一些非常复杂的 XML，而 XSLT 方面的经验很少。首先解决一些更简单的问题可能会更好 - 花一些时间阅读 XSLT 教科书或教程，然后研究示例。

于 2012-06-22T09:05:24.083 回答