10

我是 PowerPC 组装的新手。我正在使用 MPC8245（是的，老派）。这是 603e 系列处理器。

我想知道如何创建立即 16 位值为“无符号”的加载立即指令。

示例：li r3,0xFC10

我正在使用的 gcc 交叉编译器 4.4.5 不允许此指令，因为该值不是有符号常量。

是的，我可以使用减去 2-s 补码，但这会使阅读和记录代码变得更加困难。在为设备寄存器加载位域时，在指令中具有准确的位域更容易阅读。

4

2 回答 2

19

li是一个伪操作码，实际上翻译为addi指令。

addi rD, rA, SIMM将带符号的立即数添加SIMM到rA，将结果放在 中rD，除非该rA字段为 0，在这种情况下，它指定文字 0 而不是r0. li rD, SIMM是真的addi rD, 0, SIMM。

这适用于将值从0-0x7fff和0xffff8000-加载0xffffffff到寄存器中，但不适用于其他值。

立即位操作操作码（ori等）确实将 16 位立即数字段解释为无符号值。然而他们没有“r0意思是字面意思0”的行为addi。

您将需要使用两条指令将常量加载0xfc10到寄存器中：使用 0 加载寄存器li（或者lis，就像加载任意 32 位常量的上半部分一样），然后在无符号 16 位中进行 OR与 的价值ori。

这正是gcc在这种情况下所做的：

$ cat test.c
unsigned int test(void)
{
    return 0xfc10;
}
$ gcc -O2 -c test.c
$ objdump -d test.o

test.o:     file format elf32-powerpc

Disassembly of section .text:

00000000 <test>:
   0:   38 60 00 00     li      r3,0
   4:   60 63 fc 10     ori     r3,r3,64528
   8:   4e 80 00 20     blr
   c:   60 00 00 00     nop
$

我认为GNU 汇编器在为 PowerPC 汇编时没有任何方法可以自动生成两条指令以从单个源指令加载这样的值。但是，您可以使用@hand@l后缀来提取常量的（无符号）高和低 16 位一半，例如：

lis r3, 0x12345678@h            /* => li  r3, 0x1234     */
ori r3, r3, 0x12345678@l        /* => ori r3, r3, 0x5678 */

您可以使用它来编写自己的宏以进行任意常量加载...

$ cat test2.s
        .macro  load_const rD, const
        .if (\const >= -0x8000) && (\const <= 0x7fff)
        li      \rD, \const
        .else
        lis     \rD, \const@h
        ori     \rD, \rD, \const@l
        .endif
        .endm

        load_const r3, 0
        load_const r4, 1
        load_const r5, -1
        load_const r6, 0x7fff
        load_const r7, 0x8000
        load_const r8, -32767
        load_const r9, -32768
        load_const r10, -32769
        load_const r11, 0xfc10

$ as -mregnames -o test2.o test2.s
$ objdump -d test2.o

test2.o:     file format elf32-powerpc

Disassembly of section .text:

00000000 <.text>:
   0:   38 60 00 00     li      r3,0
   4:   38 80 00 01     li      r4,1
   8:   38 a0 ff ff     li      r5,-1
   c:   38 c0 7f ff     li      r6,32767
  10:   3c e0 00 00     lis     r7,0
  14:   60 e7 80 00     ori     r7,r7,32768
  18:   39 00 80 01     li      r8,-32767
  1c:   39 20 80 00     li      r9,-32768
  20:   3d 40 ff ff     lis     r10,-1
  24:   61 4a 7f ff     ori     r10,r10,32767
  28:   3d 60 00 00     lis     r11,0
  2c:   61 6b fc 10     ori     r11,r11,64528
$
于 2012-06-21T22:01:21.770 回答
1

您还可以使用 operator 加载无符号的 16 位立即数ori，但请务必在之前清除您的寄存器：

xor r3, r3, r3
ori r3, r3, 0xFC10
于 2015-09-22T13:08:24.517 回答