1

使用 XSL 1.0，我发现了一个不错的标记化函数。现在我需要对生成的令牌进行 for-each 。我对 XSL 很陌生。

我需要的php等价物：

$in = 'a,b,c,d';
$tokens = explode (',', $in);
foreach ($tokens as $token) {
  echo $token;
}

这是我到目前为止所拥有的。此行将输出 'a,b,c,d'-

<xsl:value-of select="@CommaSeparated" />

这将通过 tokenize 函数运行该字符串-

  <xsl:call-template name="tokenize">
    <xsl:with-param name="pText" select="@CommaSeparated"/>
  </xsl:call-template>

以及标记化功能。我了解这是做什么的，只是不了解它吐出的数据格式-

<xsl:template name="tokenize">
  <xsl:param name="pText"/>

  <xsl:if test="string-length($pText)">
    <tag>
      <xsl:value-of select=
       "substring-before($pText, ',')"/>
    </tag>

    <xsl:call-template name="tokenize">
      <xsl:with-param name="pText" select=
       "substring-after($pText, ',')"/>
    </xsl:call-template>
  </xsl:if>
</xsl:template>
4

2 回答 2

3

首先，使用的 tokenize 函数实际上并不正确。理论上，它应该像这样吐出一个标签元素列表（严格来说是“结果树片段”）

<tag>a</tag>
<tag>b</tag>
<tag>c</tag>
<tag>d</tag>

但它实际上错过了最后一个元素

<tag>a</tag>
<tag>b</tag>
<tag>c</tag>
<tag></tag>

你最好在这里找到另一个标记化函数（在 StackOverflow 中肯定有工作的）。

但是，在回答您关于在此之上使用 xsl:for-each 的问题时，您可能会想要做这样的事情......

  <xsl:variable name="tags">
    <xsl:call-template name="tokenize">
       <xsl:with-param name="pText" select="@CommaSeparated"/>
     </xsl:call-template> 
  </xsl:variable>

  <xsl:for-each select="$tags/tag">
     <xsl:copy-of select="." />
  </xsl:for-each>

也就是说，将标签列表存储在一个变量中，然后循环遍历它们。但是，如果您在 XSLT1.0 中尝试此操作，则会收到错误消息“表达式必须计算为节点集。”。为了解决这个问题，您需要使用扩展功能。EXSLT 可能是最常见的。您可以像这样在 XSLT 中声明它

<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:exsl="http://exslt.org/common" 
    exclude-result-prefixes="exsl">

你可以简单地改变xsl:for-each如下：

<xsl:for-each select="exsl:node-set($tags)/tag">

因此，给定以下 XML

<a CommaSeparated="a,b,c,d"></a>

以及以下 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:exsl="http://exslt.org/common" exclude-result-prefixes="exsl">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/a">
        <xsl:variable name="tags">
            <xsl:call-template name="tokenize">
                <xsl:with-param name="pText" select="@CommaSeparated"/>
            </xsl:call-template>
        </xsl:variable>
        <xsl:for-each select="exsl:node-set($tags)/tag">
            <xsl:copy-of select="."/>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="tokenize">
        <xsl:param name="pText"/>
        <xsl:if test="string-length($pText)">
            <tag>
                <xsl:value-of select="substring-before($pText, ',')"/>
            </tag>
            <xsl:call-template name="tokenize">
                <xsl:with-param name="pText" select="substring-after($pText, ',')"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

以下是输出（由于您使用的错误标记化功能，最后一个标签为空白）

<tag>a</tag>
<tag>b</tag>
<tag>c</tag>
<tag></tag>
于 2012-06-21T16:19:17.563 回答
0

检查此代码：

<xsl:variable name="val">
       <xsl:value-of select="@CommaSeparated"/><xsl:text disable-output-escaping="yes"><![CDATA[ ]]></xsl:text>
</xsl:variable>

<xsl:template match="/a">
    <xsl:variable name="tags">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="pText" select="$val"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:for-each select="exsl:node-set($tags)/tag">
        <xsl:copy-of select="."/>
    </xsl:for-each>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="pText"/>
    <xsl:if test="string-length($pText)">
        <tag>
            <xsl:value-of select="substring-before($pText, ',')"/>
        </tag>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="pText" select="substring-after($pText, ',')"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

于 2014-01-30T12:16:28.187 回答