1

网上有很多文章，如何在outlook邮件中通过excel范围。所以我使用以下代码：

Set OutApp = GetObject(, "Outlook.Application")
If OutApp Is Nothing Then Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
Set rng = Sheets("Report").Range("A3:F" & ThisWorkbook.Worksheets("Report").UsedRange.Rows.Count)

With OutMail
    .HTMLBody = RangetoHTML(rng)   
    .Display
End With

在我的范围内，我有超链接表。我希望它们在电子邮件正文中是可点击的。但他们不是。我理解这一点，因为 BodyFormat 属性是 olFormatHTML。如果我将 BodyFormat 更改为 Plain 或 RichText，超链接将变为可点击，但所有格式都会崩溃。如何保存所有格式并同时使超链接可点击？

谢谢你的帮助！

4

1 回答 1

0

我相信你正在使用 Ron 的RangetoHTML

如果是，那么您必须向其中添加一些额外的代码，以便它保留超链接。

我已经添加了代码，你可以看到相同的

'~~~~~~~~~~~~~~~~~~~~  ADDED THIS ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

这是修改后的代码。

Function RangetoHTML(rng As Range)
    ' Changed by Ron de Bruin 28-Oct-2006
    ' Working in Office 2000-2010
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    '~~~~~~~~~~~~~~~~~~~~  ADDED THIS ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
    Dim HyperL As Hyperlink
    For Each HyperL In rng.Hyperlinks
        TempWB.Sheets(1).Hyperlinks.Add _
        Anchor:=TempWB.Sheets(1).Range(HyperL.Range.Address), _
        Address:=HyperL.Address, _
        TextToDisplay:=HyperL.TextToDisplay
    Next HyperL
    '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

跟进

快照

在此处输入图像描述

于 2012-06-21T11:47:20.790 回答