excel - 如何限制单元格只输入数字

Question

我有一个 excel 文件，验证一列仅输入数字，但它的格式设置为数字小于 18，将添加前导零。但是现在第 15 位之后的数字将转换为 0 例如：“002130021300020789”，九位更改为 0。将列转换为文本后，它接受但我无法添加前导零并且无法限制输入 onlu 数字。

感谢任何帮助..提前谢谢。

Answer 1

MS 文章：Excel 遵循关于如何存储和计算浮点数的IEEE 754 规范。因此，Excel 仅在数字中存储 15 位有效数字，并将第 15 位之后的数字更改为零。

要获取您的数字格式并确保用户只输入数字，您可以这样做。我假设您正在验证 Range A1 中的文本。请酌情修改。

Private Sub Worksheet_Change(ByVal Target As Range)
    On Error GoTo Whoa

    Application.EnableEvents = False

    If Not Intersect(Target, Range("A1")) Is Nothing Then
        '~~> If entered text is not a number then erase input
        If Not IsNumeric(Range("A1").Value) Then
            MsgBox "invalid Input"
            Application.Undo
            GoTo LetsContinue
        End If

        Range("A1").Value = "'" & Format(Range("A1").Value, "000000000000000000")
    End If

LetsContinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub

跟进

如果您要复制和粘贴，则必须先手动将 Range G11:G65536 格式化为 TEXT，然后使用此代码

SNAPSHOT（粘贴数值时）

SNAPSHOT（粘贴非数字值时）

代码

Private Sub Worksheet_Change(ByVal Target As Range)
    On Error GoTo Whoa

    Dim cl As Range

    Application.EnableEvents = False

    If Not Intersect(Target, Range("G11:G" & Rows.Count)) Is Nothing Then
        For Each cl In Target.Cells
            '~~> If entered text is not a number then erase input
            If Not IsNumeric(cl.Value) Then
                MsgBox "invalid Input"
                Application.Undo
                GoTo LetsContinue
            End If

            cl.Value = "'" & Format(cl.Value, "000000000000000000")
        Next
    End If

LetsContinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub

Answer 2

首先，您可以将单元格的格式更改为文本

Range("A1").NumberFormat = "@"

然后你可以添加零

cellvalue2 = Format(cellvalue1, "000000000000000")  // for numeric fields

                   or 
             = TEXT(cellvalue1,"000000000000000")    // for textfields