0

我想调用一个控制器未知的子流。它在参数中传递给 beginFlow，我将其保存在流范围内。在 goToForm 中，我想调用保存在 flow.theController 中的控制器。

def beginFlow = {
    enter {
        action {
            if (params?.redirectTo != null) {
                String flow.theController = params.redirectTo
            }

            if ( flow.theController() ) { 
                success()
            }
        }
        on("success").to("beginPage")
    }
    beginPage {
        on('next').to('goToForm')
    }       
    goToForm {
                    // I'd like this:
                    // subflow(controller: flow.theController, action:'start'

                    // this subflow works, but won't work for all cases
        subflow(controller: 'AZ_A4', action:'start')
        on('done').to('showResults')
        on('notDone').to('beginPage')
    }

    showResults {
        redirect(action: 'results')
    }
}
4

1 回答 1

0

正如用户列表中所讨论的，这似乎无法直接实现，因为在构建流结构时（在应用程序启动时）必须知道子流名称。但是由于流定义 DSL 是 Groovy 代码，您可以执行以下操作：

beginPage {
    on('next').to('selectSubflow')
}
selectSubflow {
    action {
        return "subflow_${flow.theController}"()
    }
    for(subController in listOfControllers) {
        on("subflow_${subController}").to("subflow_${subController}")
    }
}
for(subController in listOfControllers) {
    "subflow_${subController}" {
        subflow(controller:subController, action:'start')
        on('done').to('showResults')
        on('notDone').to('beginPage')
    }
}

listOfControllers 可以在某处是静态的，或者您可以在流定义的顶部执行类似的操作

def beginFlow = {
    def listOfControllers = grailsApplication.controllerClasses.findAll {
        it.flows.containsKey('start')
    }.collect { it.logicalPropertyName }
    enter {
        // ...

枚举应用程序中定义 startFlow 的所有控制器。你的课堂上可能需要一个def grailsApplication，我总是忘记 Grails 中的哪些地方默认提供它，而哪些地方没有......

于 2012-06-23T11:05:48.617 回答