4

我正在编写一个批处理脚本，我需要 unix 时间。在linux下很容易，但我不知道如何在windows中做到这一点。

4

3 回答 3

12

这是一个本机批处理解决方案，应该适用于任何语言环境。它使用 WMIC 以独立于区域设置的方式获取当前本地时间。其他一切都是字符串解析和基本数学的“简单”问题。

:UnixTime  [ReturnVar]  [TimeStamp]
::
:: Computes the Unix time from the current local time as reported by the
:: operating system. The Unix time is the number of seconds that have elapsed
:: since midnight Coordinated Universal Time (UTC), January 1, 1970, not
:: counting leap seconds.
::
:: The result is returned in variable ReturnVar,
:: or the result is echoed if ReturnVar is not specified
::
:: If the TimeStamp is provided in the 2nd parameter, then the Unix time for
:: the TimeStamp is computed, rather then for the current time.
::
:: The TimeStamp must have the same format as used by WMIC:
::
::   YYYYMMDDhhmmss.ffffffSzzz
::
:: where:
::
::   YYYY   = gregorian year
::   MM     = month
::   DD     = day
::   hh     = hour in 24 hour format
::   mm     = minute
::   ss     = seconds
::   ffffff = fractional seconds (microseconds)
::   S      = timezone sign: + or -
::   zzz    = timezone: minutes difference from GMT
::
:: Each component must be zero prefixed as needed to maintain the proper width.
::
:: The ReturnVar parameter must be provided in order to use the TimeStamp.
:: A ReturnVar of "" will function the same as no ReturnVar. This enables the
:: specification of a TimeStamp without an actual ReturnVar.
::
@echo off
setlocal
set "ts=%~2"
if not defined ts for /f "skip=1 delims=" %%A in ('wmic os get localdatetime') do if not defined ts set "ts=%%A"
set /a "yy=10000%ts:~0,4% %% 10000, mm=100%ts:~4,2% %% 100, dd=100%ts:~6,2% %% 100"
set /a "dd=dd-2472663+1461*(yy+4800+(mm-14)/12)/4+367*(mm-2-(mm-14)/12*12)/12-3*((yy+4900+(mm-14)/12)/100)/4"
set /a ss=(((1%ts:~8,2%*60)+1%ts:~10,2%)*60)+1%ts:~12,2%-366100-%ts:~21,1%((1%ts:~22,3%*60)-60000)
set /a ss+=dd*86400
endlocal & if "%~1" neq "" (set %~1=%ss%) else echo %ss%
exit /b


请注意，此解决方案的使用寿命有限。当 Unix 时间超过有符号 32 位整数的最大值时，它将在 2038-01-19 停止工作。

编辑- 代码已被编辑以支持在命令行上转换时间戳字符串而不是当前本地时间。支持的精确时间范围是 1901-12-13 20:45:52.000000 到 2038-01-19 03:14:07.999999 GMT。1970-01-01 00:00:00.000000 之前的时间将产生负值。

于 2012-06-20T21:48:14.103 回答
3

如果“unix 时间”是指纪元秒，那么 Windows 不包含生成该时间的工具。相反，您可以安装第三方工具。例如：

  • 安装Cygwin。
  • 找到date二进制文件（在C:\Cygwin\你安装它的下面或任何地方）
  • 像在 Linux 中一样使用它。

或者，根据对此答案的精彩评论，您可以安装还包含命令的GNU Coreutilsdate。它包括许多您可能不需要的其他工具，但是 Cygwin 也是如此。

于 2012-06-20T17:16:12.807 回答
3

您可以在 windows 中使用 vbscript，解释器在您的系统上可用。

'--------------------epoch.vbs----------------------- 
option explicit
dim s,o,z
for each o in GetObject("winmgmts:").InstancesOf ("Win32_OperatingSystem")
z=o.CurrentTimeZone
next
s=DateDiff("s", "01/01/1970 00:00:00", Now())-(60*z)
wscript.echo(s)
wscript.quit
于 2012-06-20T17:54:59.997 回答