1

我只是想检查是否有任何方法可以避免在 xslt1.0 中像下面这样的冗长编码，其中我们有多个检查条件，输出元素要根据某些条件进行复制。如果条件不成立，则元素本身将不存在于输出中。我问的原因是，我们在 xsl 文件中有很多元素。

我的 xslt

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    >
  <xsl:output omit-xml-declaration="yes" indent="yes" />
  <xsl:strip-space elements="*" />
  <xsl:template match="/">
    <Root>
    <xsl:if test="Root/a/text() = '1'">
      <first>present</first>   
    </xsl:if>
    <xsl:if test="Root/b/text() = '1'">
      <second>present</second>
    </xsl:if>
    <xsl:if test="Root/c/text() = '1'">
      <third>present</third>
    </xsl:if>
    <xsl:if test="Root/d/text() = '1'">
      <fourth>present</fourth>
    </xsl:if>
    </Root>
  </xsl:template>
</xsl:stylesheet>

我的输入xml

<Root>
  <a>1</a>
  <b>1</b>
  <c>0</c>
  <d>1</d>  
</Root>

我的输出

<Root>
  <first>present</first>
  <second>present</second>
  <fourth>present</fourth>
</Root>
4

2 回答 2

2 
<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <my:ord>
   <first>first</first>
   <second>second</second>
   <third>third</third>
   <fourth>fourth</fourth>
 </my:ord>

 <xsl:variable name="vOrds" select="document('')/*/my:ord/*"/>

 <xsl:template match="Root/*[. = 1]">
  <xsl:variable name="vPos" select="position()"/>

  <xsl:element name="{$vOrds[position()=$vPos]}">present</xsl:element>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<Root>
  <a>1</a>
  <b>1</b>
  <c>0</c>
  <d>1</d>  
</Root>

产生了想要的正确结果：

<Root>
  <first>present</first>
  <second>present</second>
  <fourth>present</fourth>
</Root>
于 2012-06-19T14:37:45.890 回答
1

一种方法是在 output-template.xml 中为输出创建一个模板：

<Root>
  <first>present</first>
  <second>present</second>
  <third>present</third>
  <fourth>present</fourth>
</Root>

然后处理这个：

<xsl:variable name="input" select="/"/>

<xsl:template match="Root/*">
  <xsl:variable name="p" select="position()"/>
  <xsl:if test="$input/Root/*[$p] = '1'">
    <xsl:copy-of select="."/>
  </xsl:if>
</xsl:template>

<xsl:template match="/">
  <Root>
    <xsl:apply-templates select="document('output-template.xml')/Root/*"/>
  </Root>
</xsl:template>
于 2012-06-19T14:37:45.997 回答