4

我有一个包含一堆简单函数的 Groovy 文件，如下所示：

// useful functions
def myFunc1(String arg) {
    println("Hello " + arg)
}

def myFunc2(String arg) {
    println("Goodbye " + arg)
}

我想从中获得：

  • 方法名称
  • 论据
  • 函数的主体代码

（所有都是简单的字符串，我还不需要运行任何东西。）

我正要求助于一些正则表达式，但由于我使用的是 JVM 语言（Scala），我想我也许可以使用一些 Groovy 编译器的东西来以一种“更好”的方式来做这件事。

似乎有很多关于动态加载 Groovy 代码并运行它的信息，但关于自省源代码的信息却不多。有任何想法吗？

（如果以“不错”的方式失败，我还将接受一些 Scala-foo 以简洁的方式解析信息。）

4

1 回答 1

6

这有效，并演示了在 AST 中查找每个重要节点所需的令牌类型。希望这是有道理的...通过使用大量的 Groovy 动态，我希望我没有让移植到 Scala 变得太难:-(

import org.codehaus.groovy.antlr.*
import org.codehaus.groovy.antlr.parser.*
import static org.codehaus.groovy.antlr.parser.GroovyTokenTypes.*

def code = '''
// useful functions
def myFunc1(String arg) {
    println("Hello " + arg)
}

def myFunc2(arg, int arg2) {
    println("Goodbye " + arg)
}

public String stringify( int a ) {
  "$a"
}
'''

def lines = code.split( '\n' )

// Generate a GroovyRecognizer, compile an AST and assign it to 'ast'
def ast = new SourceBuffer().with { buff ->
  new UnicodeEscapingReader( new StringReader( code ), buff ).with { read ->
    read.lexer = new GroovyLexer( read )
    GroovyRecognizer.make( read.lexer ).with { parser ->
      parser.sourceBuffer = buff
      parser.compilationUnit()
      parser.AST
    }
  }
}

// Walks the ast looking for types
def findByPath( ast, types, multiple=false ) {
  [types.take( 1 )[ 0 ],types.drop(1)].with { head, tail ->
    if( tail ) {
      findByPath( ast*.childrenOfType( head ).flatten(), tail, multiple )
    }
    else {
      ast*.childrenOfType( head ).with { ret ->
        multiple ? ret[ 0 ] : ret.head()[0]
      }
    }
  }
}

// Walk through the returned ast
while( ast ) {
  def methodModifier = findByPath( ast, [ MODIFIERS   ] ).firstChild?.toStringTree() ?: 'public'
  def returnType     = findByPath( ast, [ TYPE, IDENT ] ) ?: 'Object'
  def methodName     = findByPath( ast, [ IDENT       ] )
  def body           = findByPath( ast, [ SLIST ] )
  def parameters     = findByPath( ast, [ PARAMETERS, PARAMETER_DEF ], true ).collect { param ->
    [ type: findByPath( param, [ TYPE ] ).firstChild?.toStringTree() ?: 'Object',
      name: findByPath( param, [ IDENT ] ) ]
  }

  def (y1,y2,x1,x2) = [ body.line - 1, body.lineLast - 1, body.column - 1, body.columnLast ]
  // Grab the text from the original string
  def snip = [  lines[ y1 ].drop( x1 ),                // First line prefix stripped
               *lines[ (y1+1)..<y2 ],                  // Mid lines
                lines[ y2 ].take( x2 ) ].join( '\n' )  // End line suffix stripped

  println '------------------------------'
  println "modifier: $methodModifier"
  println "returns:  $returnType"
  println "name:     $methodName"
  println "params:   $parameters"
  println "$snip\n"

  // Step to next branch and repeat
  ast = ast.nextSibling
}

它打印出来：

------------------------------
modifier: public
returns:  Object
name:     myFunc1
params:   [[type:String, name:arg]]
{
    println("Hello " + arg)
}

------------------------------
modifier: public
returns:  Object
name:     myFunc2
params:   [[type:Object, name:arg], [type:int, name:arg2]]
{
    println("Goodbye " + arg)
}

------------------------------
modifier: public
returns:  String
name:     stringify
params:   [[type:int, name:a]]
{
  "$a"
}

希望它有所帮助，或者为您指明正确的方向:-)

于 2012-06-18T23:24:43.197 回答