7

当您在基类中定义类构造函数（即设置一些静态类变量）时，是否可以在派生类中覆盖该类构造函数并从其继承的层次父级调用构造函数？

例子：

TBaseclass = class(TObject)
public
   class constructor ClassCreate; virtual;
end;

TOtherClass = class(TBaseClass)
public
  class constructor ClassCreate; override;
end;

**implementation**

class constructor TBaseClass.ClassCreate;
begin
  //do some baseclass stuff
end;

class constructor TotherClass.ClassCreate;
begin
  inherited;
  //do some other stuff
end;
4

2 回答 2

17

类构造函数没有理由是虚拟的，因为它们不能被多态调用。你不能直接打电话给他们；编译器会根据程序中使用的类自动插入对它们的调用。虚方法用于运行时多态性，但由于编译器在编译时确切知道它正在调用哪些类构造函数，因此不需要对类构造函数或析构函数进行动态调度。

但是，继承不需要虚拟方法，因此inherited在类构造函数或类析构函数中使用应该没有问题。不过，正如大卫的回答所指出的那样，编译器会忽略调用，inherited因为多次初始化一个类通常是不明智的，如果你真的设法调用继承的类构造函数，你就会这样做。如果有些事情你需要发生两次，你需要找到一种不同的方式来实现它。

于 2012-06-18T14:38:54.897 回答
10

首先，由于类构造函数不能是虚拟的（它们是虚拟的没有意义），您需要删除virtualandoverride关键字才能使您的代码编译。

类构造函数通常用于初始化类变量。类变量通常只需要初始化一次。如果您可以inherited按照您在问题中建议的方式调用，那么TBaseClass.ClassCreate将被调用多次，而实际上它只需要调用一次。

虽然您可以编写inherited类构造函数，并且代码将编译，但编译器只是忽略它。

program ClassConstructors;

{$APPTYPE CONSOLE}

uses
  SysUtils;

var
  Count: Integer;

type
  TBaseclass = class
  public
    class constructor ClassCreate;
  end;

  TOtherClass = class(TBaseClass)
  public
    class constructor ClassCreate;
  end;

class constructor TBaseClass.ClassCreate;
begin
  inc(Count);
end;

class constructor TotherClass.ClassCreate;
begin
  inherited;
end;

begin
  TBaseClass.Create.Free;
  TOtherClass.Create.Free;
  Writeln(Count);//outputs 1
  Readln;
end.

请注意，当然，两个类构造函数都运行。

于 2012-06-18T14:39:02.100 回答