2

我一直在处理评估两个文件日期的批处理文件中的一些代码。如果一个日期大于另一个日期，则它运行另一个 bat 文件。我想要做的是将两个日期格式化为 YYYYMMDD 以便我可以使用GTR（大于）。

代码在下面，但是如果我使用==( equal ) 它可以工作，因为它正在评估字符串。我只想知道一个文件日期是否大于另一个文件日期。

我不是要求有人修改下面的代码，但如果你能告诉我如何格式化日期，我将不胜感激。

set Fileone=File1.txt
set FileTwo=File2.txt

pushd "D:\Board\Broadcast\FA_Report8_A"
FOR %%f IN (%FileOne%) DO SET filedatetime=%%~tf
FOR %%f IN (%FileTwo%) DO SET filedatetime2=%%~tf
SET filedatetime2=%year%%month%%day%
IF %filedatetime:~0, 10% GTR %filedatetime2:~0, 10% ( 
echo FileOne Greater - run bat
timeout /t 20 /nobreak
goto Finish
) else (
echo FileOne not Greater - Finish
goto Finish
)
:Finish
echo finished 
pause
4

3 回答 3

10

它不能在具有不同日期格式的机器之间移植，但最简单的方法是使用子字符串：%var:~STARTPOS,LENGTH%

set filedatetime=14/06/2012 12:26
set filedatetime=%filedatetime:~6,4%%filedatetime:~3,2%%filedatetime:~0,2%
echo "%filedatetime%"

"20120614"
于 2012-06-18T13:12:05.477 回答
2

您可以使用 FOR /F 命令分隔日期的各个部分：

set filedatetime=14/06/2012 12:26
for /F "tokens=1-3 delims=/ " %%a in ("%filedatetime%") do (
   set filedatetime=%%c%%b%%a
)

这种形式可以防止你弄错每个子串的位置或大小，并且很容易改变部分的顺序。例如，如果您的日期是 MM/DD/YYYY：

set filedatetime=%%c%%a%%b

输入 FOR /? 了解更多详情。

于 2012-06-19T04:05:37.373 回答
1

系统中日期变量字符串的布局可以通过用户设置、区域和/或语言来假设，因此，日期不是 100% 可预测的布局。

尝试使用wmic OS Get localdatetime /value，因为结果是 100% 可预测的：

LocalDateTime=20190609123708.733000-180

所以，如果你在 for 循环中使用，添加 2 个分隔符，如=., （等于和点），你会得到这个字符串输出：

20190609123708.

此命令的布局是可预测的，并且独立于区域设置、用户设置或系统语言工作，因此，该命令将始终返回：

set _date=20190609123708
rem :: %_date:~0,4%_%_date:~4,2%_%_date:~6,2%
rem ::   year:2019 |  month:06  | day:09

在 bat 文件中：

 @echo off & for /f "tokens=2delims==." %%i in ('wmic OS Get localdatetime /value ^|findstr /r [0-9]')do set "_date=%%i" & echo/%_date:~0,4%%_date:~4,2%%_date:~6,2%

在命令行中：

for /f "tokens=2delims==." %i in ('wmic OS Get localdatetime /value ^|findstr /r [0-9]')do set "_data=%i" & mkdir %_date:~0,4%_%_date:~4,2%_%_date:~6,2%

此命令结果::

    20190609

我还可以建议：

wmic Path Win32_LocalTime Get Day,Month,Year

在循环中：

@echo off & setlocal enabledelayedexpansion & set "_do=wmic Path Win32_LocalTime Get Day^,Month^,Year" 
for /f "tokens=1-3delims= " %%a in ('!_do!^|findstr /r [0-9]')do set "y=%%c" & set "d=0%%a" & set "m=0%%b"
echo/!y!!m:~-2!!d:~-2! >nul

结果：

Day  Month  Year
 9   6      2019 
%%a  %%b    %%c

月/日小于等于 9 的数字不为零，因此，在这种情况下，您可以使用此 bat 放置前导零：

@echo off & setlocal enabledelayedexpansion & set "_do=wmic Path Win32_LocalTime Get Day^,Month^,Year" 
for /f "tokens=1-3delims= " %%a in ('!_do!^|findstr /r [0-9]')do set "y=%%c" & set "d=0%%a" & set "m=0%%b"
echo/!y!!m:~-2!!d:~-2!

YearMonthDay 中的结果：

20190609

观察：在PowerShell中，可以通过以下方式简单地自定义布局：

ToString("yyyyMMdd")

可以使用设置字符串ToString。

样本： yyyy-MM-dd, dd-MM-yyyy, MM-dd-yyyy, MM_dd_yyyy, yyyy_MM_dd, etc..

Powershell 命令：

$(Get-Date).ToString("yyyyMMdd")

结果：

2010609

在此处查看有关批量日期变量布局输出的更多信息：

批量获取当前日期月份和年份的安全方法

在批处理文件和区域设置/区域设置中解析日期

更新- 如何在你的蝙蝠中应用上面的评论/观察，所以，如果我理解你在这个问题中的代码：

@echo off & setlocal enabledelayedexpansion 

set "Fileone=File1.txt" &  set "FileTwo=File2.txt"

set "_both=!FileOne!-!FileTwo!" & rem cd /d "D:\Board\Broadcast\FA_Report8_A"

set "_path_back=%__CD__%" & rem :: you can use this "%__CD__%" or pushd "D:\Board\Broadcast\FA_Report8_A" 

for /f "tokens=2delims==." %%i in ('wmic OS Get localdatetime /value ^|findstr /r [0-9]')do set "_date=%%i"

set _now=!_date:~0,4!!_date:~4,2!!_date:~6,2! & for /f "tokens=1*delims=-" %%i in ('echo/!_both!')do (

     call :compare "%%~fi" & call :compare "%%~fj" & if !_dt_file_2! gtr !_dt_file_2! ( 
     
         echo/ FileOne Greater - run bat & timeout /t 20 /nobreak & goto :run_bat
         
         ) else (echo/ FileOne not Greater - Finish & goto Finish) 

    )
    
:compare
set "_file="  & set "_file=%~1" 

for /f "tokens=1delims=. " %%d in ('wmic datafile where name^='!_file:\=\\!' get LastModified ^|findstr /v "LastModified"')do (
    
    if "!_dt_file_1!./" == "./" (set _dt_file_2=%%d) else (set _dt_file_2=%%d)
    
    ) & exit /b

:run_bat 
call the_bat_to_run.cmd 

:Finish
echo/Finished

对不起，我的 英语有限...

于 2019-06-10T01:57:45.263 回答