gnuplot - gnuplot条形图中不同颜色的条形图？

Question

我有一个非常简单的数据集：

Critical 2
High 18
Medium 5
Low 14

用这个数据集在 gnuplot 中创建一个条形图很容易，但是所有的条形图都是相同的颜色。我想要它，以便关键是黑色，高是红色等，但似乎几乎没有任何在线教程可以做到这一点。

谁能指出我正确的方向？

Answer 1

set xrange [-.5:3.5]
set yrange [0:]
set style fill solid
plot "<sed 'G;G' test.dat" i 0 u (column(-2)):2:xtic(1) w boxes ti "Critical" lc rgb "black",\
     "<sed 'G;G' test.dat" i 1 u (column(-2)):2:xtic(1) w boxes ti "High" lc rgb "red" ,\
     "<sed 'G;G' test.dat" i 2 u (column(-2)):2:xtic(1) w boxes ti "Medium" lc rgb "green",\
     "<sed 'G;G' test.dat" i 3 u (column(-2)):2:xtic(1) w boxes ti "Low" lc rgb "blue"

这会占用sed您的文件的三倍空间，以便 gnuplot 将每一行视为不同的数据集（或“索引”）。您可以像我所做的那样使用index <number>或简称分别绘制每个索引。i <number>此外，索引号是可用的，column(-2)这就是我们如何让盒子正确间隔的方式。

可能更干净（仅限 gnuplot）的解决方案是使用过滤器：

set xrange [-.5:3.5]
set yrange [0:]
set style fill solid
CRITROW(x,y)=(x eq "Critical") ? y:1/0
HIGHROW(x,y)=(x eq "High") ? y:1/0
MIDROW(x,y) =(x eq "Medium") ? y:1/0
LOWROW(x,y) =(x eq "Low") ? y:1/0
plot 'test.dat' u ($0):(CRITROW(stringcolumn(1),$2)):xtic(1) w boxes lc rgb "black" ti "Critical" ,\
     '' u ($0):(HIGHROW(stringcolumn(1),$2)):xtic(1) w boxes lc rgb "red" ti "High" ,\
     '' u ($0):(MIDROW(stringcolumn(1),$2)):xtic(1) w boxes lc rgb "green" ti "Medium" ,\
     '' u ($0):(LOWROW(stringcolumn(1),$2)):xtic(1) w boxes lc rgb "blue" ti "Low"

此解决方案也不依赖于数据文件中的任何特定顺序（这就是为什么我更喜欢它而不是其他解决方案。我们在这里使用column(0)（或$0）完成间距，它是数据集中的记录号（在这种情况下，电话号码）。

Answer 2

这是使用该linecolor variable选项执行此操作的方法。

如果您知道这些行始终处于相同的已知顺序，则可以使用行号（第零列，$0）作为线型索引：

set style fill solid noborder
set linetype 1 lc rgb 'black'
set linetype 2 lc rgb 'red'
set linetype 3 lc rgb 'yellow'
set linetype 4 lc rgb 'green'

set yrange [0:*]
unset key
plot 'alerts.txt' using 0:2:($0+1):xtic(1) with boxes linecolor variable

如果顺序可能不同，您可以使用 gnuplot 样式的索引函数，该函数从以空格分隔的单词的字符串中确定警告级别的索引：

alerts = 'Critical High Medium Low'
index(s) = words(substr(alerts, 0, strstrt(alerts, s)-1)) + 1

set style fill solid noborder
set linetype 1 lc rgb 'black'
set linetype 2 lc rgb 'red'
set linetype 3 lc rgb 'yellow'
set linetype 4 lc rgb 'green'

set yrange [0:*]
unset key
plot 'alerts.txt' using 0:2:(index(strcol(1))):xtic(1) with boxes linecolor variable